a5ws_Save_User_Values Required Data Missing

[moiola]

Dear experts,

I've read tons of posts here about the adding users to alpha websecurity tables, but still did not find an answer for my problem :(
I'm trying to add users to alpha websecurity tables using a5ws_Save_User_Values function on a5w page. I followed the help file carefully, but never the less the "Required Data Missing" is returned by a5ws_Save_User_Values.

Here is my code:

function saveSecurityValues as c (newLogin as C, newPassword as C, newSecurityGroup as c, ulink as c)
	saveSecurityValues="OK"
	'define request variables
	dim request.variables.guid as c
	dim request.variables.userid as c
	dim request.variables.password as c
	dim request.variables.ulink as c
	dim request.variables.email as c
	dim request.variables.groups as c
	'define output variables
	dim output as p
	dim output.controls as p
	dim output.controls.guid.value as c
	dim output.controls.password.value as c
	dim output.controls.userid.value as c
	dim output.controls.ulink.value as c
	dim output.controls.groups.value as c
	'define result variable
 	dim result as p
 	dim newUserGuid as c
 	newUserGuid=""
	
	request.variables.ulink=ulink
	request.variables.guid=API_UUIDCREATE() 'i'm not sure i need to do this, but without this row the error is the same - Required Data Missing
	request.variables.userid=newLogin
	request.variables.password=newPassword
	request.variables.groups=newSecurityGroup
	request.variables.email=newLogin+"@fc.com" 'i'm not sure i need to do this, but without this row the error is the same - Required Data Missing

	?"<br>We are in saveSecurityValues function<br>"
	?"ulink="+request.variables.ulink+"<br>"
	?"userid="+request.variables.userid+"<br>"
	?"password="+request.variables.password+"<br><br>"
	?a5ws_User_File_Field_List()
	?"<br>"
	
	'new user will be created
	result = a5ws_Save_User_Values(output,request)
	if result.errors = .T. then
		saveSecurityValues = "Can not save user password and group: "+result.error_text
		?saveSecurityValues
		return
	else
		newUserGuid = output.controls.guid.value
		?"new user guid="+newUserGuid
		'saveSecurityValues=saveGroup(newUserGuid, newSecurityGroup)
	end if
end function

Another thing that seems important for me is that ?a5ws_User_File_Field_List() returns me only {Guid Password Userid } and that's all, ulink field is missing. Can that be a reason? If yes, how can I enable ulink to be in this list?
Currently ulink is enabled in application security settings (screen attached).

Any clues will be highly appreciated!

Thank you,
Olga

[moiola]

Re: a5ws_Save_User_Values Required Data Missing

Many thanks to Jerry Brightbill, who helped me so much to identify the problem. Just in case somebody will go across the same issue, I post the solution here.

In case a5ws_Save_WebUser_Values() or a5ws_Save_User_Values() functions are used inside of a body of another function, they do not have an access to the request variable. That's why it is important to pass this variable to the "parent" function. In my case it was saveSecurityValues().

So I rewrote the definition of my function as follows:

function saveSecurityValues as c (newLogin as C, newPassword as C, newSecurityGroup as c, ulink as c, request as p)

Calling of the function now looks:

dim res as c
res = saveSecurityValues(newLogin, newPassword, newSecurityGroup, ulink, request)

where request is a global variable, so there is no need to declare/initialize it anywhere before in the code.

Hope it can be helpful,
Olga