mailto - selected addresses

[CALocklin]

I have no problem setting up a normal mailto link. However, I want the user to be able to select from a list of members then open an e-mail addressed to those selected members.

The page as it exists now is shown in the attachment in case that will help people understand what I'm trying to do. (Everything works except for actually sending the "selected" e-mail.)

I want A5 to get the list of selected recipients when the "Email Selected" button is pushed and then open the user's e-mail client with those address already entered.

This may require JavaScript if there are any JS experts out there. (And I'm willing to pay for your services.)

The only other solution I can think of is a two-part solution: (1) The user clicks the Email Selected button and (2) the page is re-created with a new mailto link that the user has to click.

However, a two-part solution isn't very user friendly.

Anybody know how to accomplish this?

[Pat Bremkamp]

Re: mailto - selected addresses

Cal,

I know Alpha loves their grids, but if this is your actual list and it is this short, then I would convert it to a dialog and make the list a multiselect dropdown. Then, you could also put the message on the same form and in the after validate either send with all names in the to, or loop through and send them individually.

Pat

[CALocklin]

Re: mailto - selected addresses

The final list is actually over 80 members. And, at this point in time, the page is all hard-coded so all 80 can be shown at once. (I'm not sure if 80 at once works well in today's web components but I know it used to be really slow with that many. It's almost instant when hard-coded. Even 5000 lines doesn't take more than about 12-15 seconds on-line and that's only because it's a 700,000 byte download!)

From what I found in the W3 Schools info, you can't send e-mail with JavaScript. So, I guess I'll have to pop up another form with the mailto link and then let them just close that when done sending the e-mail.

On the other hand, if you (any "you") are certain this can be done as a single action with web components then I'll consider changing it.

I'm also not sure a multi-select drop-down would be appropriate in this case unless I make the page a "two-parter" - one with the full list and a multi-select drop-down for sending group e-mails. The current list serves as an "info list" and a "send an e-mail to this person" list as well as a "send an e-mail to multiple people" list. (Of course, sending an e-mail to one person is the same as "send an e-mail to multiple people" except you would only select one.)

[Pat Bremkamp]

Re: mailto - selected addresses

Cal,

Maybe this will help.

Attached is a picture of a dialog I use to update lists. In this case, everyone shows in the left pane and the right pane can be used to add or drop people from the list.

In this case, my 1 gig VPS shows this component in about 2 seconds (there are over 1000 people in the full list)

You could add a message section at the bottom and use the submit button (which this component doesn't have) to email the list built.

Pat

[CALocklin]

Re: mailto - selected addresses

That list and selection method looks pretty slick.

But....

You could add a message section at the bottom and use the submit button (which this component doesn't have) to email the list built.

That's the part I can't figure out.

IF I want to mail out a specific, preformatted letter *without* opening the user's default e-mail program first, no problem.

What I can't figure out without adding an intermediate step is how to put some type of "link"/button on the same page as your list that will open the user's e-mail program with those selected names already in the "TO" field.

[Pat Bremkamp]

Re: mailto - selected addresses

If you add a text area at the bottom for the message and a submit button, then you can put the code in the aftervalidate event.

The dropdown gives a list of values, so you can use a *for_each to go through the list and lookup the emails, then send the email.

Here's some code I use. In this case, I've already created lists for the To, the cc, and the bcc, and I'm sending the email based on those:

 
dim tbl as P
Dim vMessage as P
Dim tbl1 as P
'====If a To List was selected get pe_id's, names, and emails in the list
vListId=alltrim(CurrentForm.Controls.vTo_List.value)
if vListId="" .or. vListId="< select >"
 'no list selected
else
 '==== build a filter based on the people in the TO list
 vToIdList=table.external_record_content_get("[PathAlias.ADB_Path]\Li2pe","Pe_Id","Pe_Id","Li_Id="+quote(vListId))
 vFilter = *for_each(x,"Pe_Id = " + quote(x),vToIdList)
 vFilter = strtran(alltrim(vFilter), crlf()," .or. ")
 vToEmails=table.external_record_content_get("[PathAlias.ADB_Path]\people","Pe_Email","",vFilter)
 vToNames=table.external_record_content_get("[PathAlias.ADB_Path]\people","Pe_Dear","",vFilter)
 vMessage.To=CRLF_TO_COMMA(vToEmails)
end if
vCCListId=alltrim(CurrentForm.Controls.vCC_List.value)
if vCCListId="" .or. vCCListId="< select >"
 'no list selected
else
 '==== build a filter based on the people in the CC list
 vCCIdList=table.external_record_content_get("[PathAlias.ADB_Path]\Li2pe","Pe_Id","Pe_Id","Li_Id="+quote(vCCListId))
 vFilter = *for_each(x,"Pe_Id = " + quote(x),vCCIdList)
 vFilter = strtran(alltrim(vFilter), crlf()," .or. ")
 vCCEmails=table.external_record_content_get("[PathAlias.ADB_Path]\people","Pe_Email","",vFilter)
 vCCNames=table.external_record_content_get("[PathAlias.ADB_Path]\people","Pe_Dear","",vFilter)
 vMessage.CC=CRLF_TO_COMMA(vCCEmails)
end if
vBCCListId=alltrim(CurrentForm.Controls.vBCC_List.value)
if vBCCListId="" .or. vBCCListId="< select >"
 'no list selected
else
 '==== build a filter based on the people in the BCC list
 vBCCIdList=table.external_record_content_get("[PathAlias.ADB_Path]\Li2pe","Pe_Id","Pe_Id","Li_Id="+quote(vBCCListId))
 vFilter = *for_each(x,"Pe_Id = " + quote(x),vBCCIdList)
 vFilter = strtran(alltrim(vFilter), crlf()," .or. ")
 vBCCEmails=table.external_record_content_get("[PathAlias_ADB_Path]\people","Pe_Email","",vFilter)
 vBCCNames=table.external_record_content_get("[PathAlias.ADB_Path]\people","Pe_Dear","",vFilter)
 vMessage.BCC=CRLF_TO_COMMA(vBCCEmails)
end if
vMessage.From=alltrim(CurrentForm.Controls.vSndr_Email.value)
vMessage.From_Alias=alltrim(CurrentForm.Controls.vSndr_Name.value)
vMessage.Subject=alltrim(CurrentForm.Controls.vSubject.value)
vMessage.Message=CurrentForm.Controls.vText.value
vMessage.Html_Message=CurrentForm.Controls.vHtml.value
vMessage.Lrelated=.t.
vResult=email_send2(vMessage,"WSAHQ",.F.,.F.)
if vResult=.f.
 CurrentForm.Has_Error = .t. 
 Currentform.Error_Message = "There was an error sending the email."
 end
end if
tbl1=table.open("[PathAlias.ADB_Path]\emails")
tbl1.enter_begin()
tbl1.From_email=alltrim(CurrentForm.Controls.vSndr_Email.value)
tbl1.From_Name=alltrim(CurrentForm.Controls.vSndr_Name.value)
tbl1.To_Name=vListId
tbl1.Cc_Name=vCcListId
tbl1.Bcc_Name=vBccListId
tbl1.Subject=alltrim(CurrentForm.Controls.vSubject.value)
tbl1.Body=CurrentForm.Controls.vText.value
tbl1.Body_Html=CurrentForm.Controls.vHtml.value
tbl1.Sent_date=date()
tbl1.Sent_time=time("am")
'tbl1.SUCCESS=vMessages.Success
'tbl1.FAILURES=vMessages.Failure
tbl1.enter_end()
tbl1.close() 
vSndr_Email=""
vSndr_Name=""
vTo_List="< select >"
vCc_List="< select >"
vBcc_List="< select >"
Currentform.RedirectTarget="Em_Compose.a5w"

The form used is shown in the picture
Pat