Events Tab Disappeared

[EJR]

OK, I must be missing something. How do I get the 'Events' tab to display in the Trace Window? I have 'User', 'Error', 'hook errors', and 'c:\dlgstack.log' tabs, but the 'Events' tab has disappeared.

The only way I can trace events is via trace.writeln() calls, which doesn't always get me what I need.

Does anyone know the "magic command" to get the 'Events' tab back?

Thanks

[Ton Spies]

Re: Events Tab Disappeared

I suppose that there are no eventsmessages to display.
As soon as they are there, a tab will be available.

Starting A5 cold with Alphasports the tab 'c:\dlgstack.log' is missing for me.

Ton

[EJR]

Re: Events Tab Disappeared

Ton, you are right... but here's something I learned. I was testing xdialog boxes, and apparently xdialog events aren't automatically sent to the Trace window the same as form events. When I loaded AlphaSports as you did, it all worked fine and reported all the events, and then the Events tab stayed in the Trace window. But when I switched back to the xdialog box, no events were reported even with the 'Trace events...' checked and the Events tab highlighted.

Just something to remember and work around. This appears to be by design and is not a bug. Thanks for your help.

[Ton Spies]

Re: Events Tab Disappeared

It's hard to test XDialog. Then you indeed need the tracewindow as the debugger causes events to. sometimes in and endless loop.

For the expected results it is important to know that there is a difference between XDialog events and all other events.
The events Alpha allows you to use are reported and the events you create in XD not. Then you have to send your own output to the trace window.

Ton

[EJR]

Re: Events Tab Disappeared

I'm learning more and more how to debug xdialog. I've made a lot of progress since I finally realized that, as you mentioned, Ton, xdialog events are not the same as form events.

I start out with a trace.writeln(a_dlg_button) as the first statement in the code section; that helps tremendously because it shows me every event being handled. Then I'll put a checkbox on the xdialog that can turn debugging on/off as I wish (and I have to make sure I place debug(1) statements in the code judiciously). I'm creating some classes to manage date, time, and formatted-numeric input on the xdialog, and I'm feeling more and more at home with it the more I use it.

[Ton Spies]

Re: Events Tab Disappeared

Then I'll put a checkbox on the xdialog that can turn debugging on/off as I wish (and I have to make sure I place debug(1) statements in the code judiciously).

Hi Eric,

Will you please explain/demonstrate how you insert that in a XDialog? Curious how you manage that.

Ton

[EJR]

Re: Events Tab Disappeared

Ton, Here's a sample dialog. Copy it and run it. When you check the Debug box, if you place the cursor in the first or second field, the Setfocus event fires and the debugger opens. If instead you place the cursor in the third field, it doesn't fire until you enter a digit (it traps only the Change event).

Hope this helps!

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Xdialog - demonstrate how to turn debugging on/off when running Xdialog

cTitle = "Xdialog Demo"
dim cVar1 as c
dim cVar2 as c
dim nVar3 as n
dim n1 as n = 1
dim n2 as n = 2

dim lDebug as L = .f.			'Make sure this starts as false

dim dlgtext as c = <<%dlg%
{lf=1};
{wrap=60}
{frame=1,1:Here's the demo...}
{region}
	{lf=2};
	Run this Xdialog.  When you want to start the debugger, click the check box and then move the cursor to any field to give it focus.;
	{lf=1};
	{sp=3}(lDebug) Check this to turn debugger on;
	{lf=3};
	{region}
		First field: | [.25cVar1!c1_*] | Track all events;
		Second field: | [.25cVar2!c2_*] | Track all events;
		Third field: | [.15nVar3!nVar3] | Track only change event;
		Display n1: | {text=n1}
		Debug: | {text=lDebug}
		{lf=2};
	{endregion};
	{lf=4};
	{region}
		{justify=center,center}
		<25,2Button 1!But1> <25,2Finished!Finished>
	{endregion};
{endregion};
%dlg%

dim dlgcode as c = <<%code%
trace.writeln("Debug:"+lDebug+", a_dlg_button:"+a_dlg_button)
if left(a_dlg_button,3) = "c1_"
	trace.writeln("c1 event")	
	'Use this IF statement to conditionally debug your code
	if lDebug
		'come here when lDebug is True
		debug(1)
		n1 = 5
		n2 = n1*6 + 78
		n1 = 34
		lDebug = .f.		'Turn debugger off so you can Run again
	end if
	a_dlg_button = ""
end if
if left(a_dlg_button,3) = "c2_"
	trace.writeln("c1 event")
	if lDebug
		'come here when lDebug is True
		debug(1)
		n1 = 34
		n2 = n1/3 + 3
		n1 = 34
	end if
	a_dlg_button = ""
end if
if a_dlg_button = "nVar3"
	trace.writeln("c1 event")
	if lDebug
		'come here when lDebug is True
		debug(1)
		n1 = 1
		n2 = n1
	end if
	a_dlg_button = ""
end if
%code%

dim cResult as c
cResult = ui_dlg_box(cTitle,dlgtext,dlgcode)
end
''''''''''''''''''''''''''''''''''''''''''''''''''''''''

[Ton Spies]

Re: Events Tab Disappeared

Hi Eric,

This is a very nice example.
I would recommend you to copy it and show it in a new thread in the Code Archive.
That's the place for good stuff like this.

Anyway my thanks

Ton

[EJR]

Re: Events Tab Disappeared

Great idea -- done!