Refresh a Supercontrol embedded XDialog

[Ronald Anusiewicz]

I have a main menu form with an embedded Xdialog. This form opens when the application is run. This form never closes while the application is running.

If changes are made to the database from which the embedded Xdialog is getting it�s data, how do I update the embedded Xdialog to reflect those changes? It seems that I have to close the form and reopen the form to refresh the embedded XDialog.

Thanks,

Ron

[MikeC]

Re: Refresh a Supercontrol embedded XDialog

Hi Ron,
Sorry, but no solution from me yet....I have run into the same issue. Have tried the only two functions I am aware of (refresh_xdialog... and refresh_targeted....--unsure of exact function names) with no avail.

So am also interested if a solution can be given for this.

[Ted Giles]

Re: Refresh a Supercontrol embedded XDialog

{AUTO_EXTERNAL_REFRESH}

This doesn't work/do it?

[Keith Hubert]

Re: Refresh a Supercontrol embedded XDialog

Have you tried OnActivate?

[Ronald Anusiewicz]

Re: Refresh a Supercontrol embedded XDialog

Thanks for your replies.

In the design of the xdialog, I have an event handler

DIM SHARED vcDueItems as C
dim text1 as C
text1 = "Item" + space(89) + "Model" + space(15) + "S/N" + space(42) + "Due Date" + space(10) + "Status"
auto_list_vcDueItems = table.external_record_content_get("equipment",\
"Item+'%%'+Model+'%%'+Sn+'%%'+format_data(Date_Due,'6-')+'%%'+status",\
"Item+Model+Sn",\
"dtoc(date_due,'1-')<>'' .and. date_due <= date()")

temp_count = w_count(auto_list_vcDueItems,crlf())
DELETE a_vcDueItems
DIM a_vcDueItems[temp_count] as c
a_vcDueItems.initialize(auto_list_vcDueItems)

L1 = auto_list_vcDueItems
L1=*for_each(tag," "+alltrim(word(tag,1,"%%"))+"{T=4}"+alltrim(word(tag,2,"%%"))+"{T=5}"+alltrim(word(tag,3,"%%"))+"{T=7}"+alltrim(word(tag,4,"%%"))+"{T=8}"+alltrim(word(tag,5,"%%",99)),L1)
    
'IMPORTANT: Do not change the dialog title.
ui_modeless_dlg_box(dlgTitle,<<%dlg%
{background=<Transparent>}
{font=arial,10,b}

{region}
{text=168,1text1};;;
{font=arial,10}
[%O={@@}%.174,16vP1^#L1!x];
{endregion};

%dlg%,<<%code%

'Place code here for your event handlers...
IF a_dlg_button = "x" THEN
    auto_list_vcDueItems = table.external_record_content_get("equipment",\
    "Item+'%%'+Model+'%%'+Sn+'%%'+format_data(Date_Due,'6-')+'%%'+status",\
    "Item+Model+Sn",\
    "dtoc(date_due,'1-')<>'' .and. date_due <= date()")
    DELETE a_vcDueItems
    DIM a_vcDueItems[temp_count] as c
    a_vcDueItems.initialize(auto_list_vcDueItems)
    
    L1 = auto_list_vcDueItems
    L1=*for_each(tag," "+alltrim(word(tag,1,"%%"))+"{T=4}"+alltrim(word(tag,2,"%%"))+"{T=5}"+alltrim(word(tag,3,"%%"))+"{T=7}"+alltrim(word(tag,4,"%%"))+"{T=8}"+alltrim(word(tag,5,"%%",99)),L1)
    
    a_dlg_button = ""
END IF

%code%)

I guess what I need is a way to trigger (?) this event handler when the a change is made in the second form, this one is hidden from view, or when the second form is closed and the form with the xdialog is now in view.

Remember, I'm not closing the first form but simply opened the second form full screen effectively hiding the first form.
I'm opening the second form using the event 'OnMouseDoubleClick' in a browse which filters the records in the second form. So when the second form closes, I'm still on the first form as before opening the second form. I hope this makes sense.

Ron

[Ted Giles]

Re: Refresh a Supercontrol embedded XDialog

If you hide the form, why not close and open it again when the next process is complete?
What about putting an "on change" event in the susidiary form and doing a behind the scene close and open?

[Ronald Anusiewicz]

Re: Refresh a Supercontrol embedded XDialog

Hi Ted,

I been leaning toward that direction.

The down side is that I will need to write to variables the form's state, what records are selected, what has focus so that when the user returns to that form, nothing has changed except the XDialog.

In this case, I think it will not be too bad.

Ron

[MikeC]

Re: Refresh a Supercontrol embedded XDialog

The {auto_external_refresh} does not work for my scenario--help indicates it is only for some controls such as buttons. In my case I delete an external file which is chosen from a checkbox list xdialog....disappears only on a close and reopen.

Nice to know about this function though--usually use modal xdialogs and was not familiar with it.

[MoGrace]

Re: Refresh a Supercontrol embedded XDialog

For a button event that is set with a global variable that can be changed outside the xdialog. But how you are going to get a static list to refresh on an embedded xdialog automatically is a challenge. Could a 'refresh' button on the supercontrol be used to redefine the list? Seems in a regular xdialog it can...going to check it out...

[Tim Kiebert]

Re: Refresh a Supercontrol embedded XDialog

Use the function ui_dlg_event().
This function takes a dialog title and the event you want to send.
The dialog title for an xdialog embedded on a form is the ":" plus the form name plus the control name that holds the xdialog.
You can also find this by checking in the view->object explorer menu and looking through the xdialog control properties.(forget which one exactly.)(while the form is in run mode not design mode)
So in your case something like ui_dlg_event(":YourFormName:XDIALOG1","x")

This will cause an event in that dialog and cause a_dlg_button to contain "x" thereby triggering your event code.

You can also play some cool games with this by passing in extra info to the xdialog by including extra values in the event name such as "x_somevalue"

Then in the xdialog you can check for

if left(a_dlg_button,2) = "x_" then
    If substr(a_dlg_button,3) = "somevalue" then
        'do something
    End If
End If

You can also use the {watch} command. Check the help on this as it describes close to what you want to do.
Don't forget to also look at a5.transaction_counter()

[MikeC]

Re: Refresh a Supercontrol embedded XDialog

a5.transaction_counter()...another obscure function (to me!!) that I had not run across. :-) Thanks Tim!

But apparently still nothing except the actual close and reopen that will refresh the list in the xdialog for me. I have also tried to regenerate the list and have it apply with no luck.

Ron seems to be ok with the work-around he can use though which is a good thing!

[Ronald Anusiewicz]

Re: Refresh a Supercontrol embedded XDialog

Hi Tim,

I know I've said this before, but your a genius!!

I added the following to my save script on the second form and it works perfectly.

''  update the xdialog on the 'defaults Entry' form
ui_dlg_event(":Defaults_Entry:xdialog1","x")

Thank you! Thank you! Thank you!

Ron

[MoGrace]

Re: Refresh a Supercontrol embedded XDialog

Ron,
What did you do with this part that is on the main form?

if left(a_dlg_button,2) = "x_" then
If substr(a_dlg_button,3) = "somevalue" then
'do something
End If
End If

[Ronald Anusiewicz]

Re: Refresh a Supercontrol embedded XDialog

As I understand it, this function when run acts as if it pushes a button on the xdialog and returns the results that you define. If you have an event handler in the xdialog that traps the button push, the event handler is fired.

In my case, I do have an event handler which is looking for: a_dlg_button = "x".

'Place code here for your event handlers...
IF a_dlg_button = "x" THEN
    auto_list_vcDueItems = table.external_record_content_get("equipment",\
    "Item+'%%'+Model+'%%'+Sn+'%%'+format_data(Date_Due,'6-')+'%%'+status",\
    "Item+Model+Sn",\
    "dtoc(date_due,'1-')<>'' .and. date_due <= date()")
    DELETE a_vcDueItems
    DIM a_vcDueItems[temp_count] as c
    a_vcDueItems.initialize(auto_list_vcDueItems)
    
    L1 = auto_list_vcDueItems
    L1=*for_each(tag," "+alltrim(word(tag,1,"%%"))+"{T=4}"+alltrim(word(tag,2,"%%"))+"{T=5}"+alltrim(word(tag,3,"%%"))+"{T=7}"+alltrim(word(tag,4,"%%"))+"{T=8}"+alltrim(word(tag,5,"%%",99)),L1)
    
    a_dlg_button = ""
END IF

%code%)

So in my sictuation, I didn�t have to make any changes to the main form. On the second form, I have a custom save button. The OnPush event contains scripting that does numerous actions when pushed. At the end of the script I added the following code:

''  update the xdialog on the 'defaults Entry' form
ui_dlg_event(":Defaults_Entry:xdialog1","x")

This was a very simple solution to my problem. I hope this helps.

Ron