How to use an script keyboard in multiple field?

[CarverRon]

I have an script that calls for a keyboard to be used to fill a field.
I can add a line at the end of the script to fill that field.
I will need as many scripts as fields.

I tried to assign the value via a global but that does not work.
I could add an update upon departure event, but that is sloppy.

Is there a way to re-use the script, so I only need one keyboard script?

Attached is a sample.

[csda1]

Re: How to use an script keyboard in multiple field?

Hi Ron,

Is there a way to re-use the script, so I only need one keyboard script?

While you can use scripts and pass parameters to specify the fieldname or value to process, any time you want to reuse code, a UDF (User-Defined function ) is always the better choice. See my Alpha Five Tips page

Looking at your code, I made some improvements. Create a New function (not a script) called Key_PadGen, and replace it with the code below. You will also have to change the form event code per the instructions in the code below. No guarantees that it handles all issues (such as whether the form is modal or modeless), but it should give you a better start.

FUNCTION Key_PadGen AS C (OriginalValue="" as C,DialogTitle="" as c)
'DESCRIPTION: Use soft keyboard to enter characters into form fields

' Example of usage in a form's onArrive event for a character field.  
' Because fieldname is not valid in ONARRIVE event, place the name of the field's object name
' (not the name of the underlying field) in the text below
' By using .text attribute, it doesn't matter the type
'		dim pa as c
'		pa=parentform.name()+":"+"FirstName"+".text"
'		eval(pa)=Key_PadGen(eval(pa))

' Get Dialog Title to use
dim dlgtit as c
dlgtit=DialogTitle
IF dlgtit==""
	' If null string, then use "vn" as dialog title
	dlgtit="vn"
END IF

' Get Original value
dim vn as c
vn=trim(OriginalValue)

' Set default return
dim result as c
result=""

' Prompt for new value
result=ui_dlg_box("vn",<<%dlg%
{position= +1,+3 }
{xmargin=2}
{ymargin=1}
{nocaption}
{font=a,10,b}
{color=white on white}
{'PRESS OK When Done  }

{font=a,25,b}
[.65 vn];

{font=a,28,b}
{background=dark blue}
{color=red on white}
{style}
	$Button {
		font:Arial,15,b;
		border-shape:SMALL-rounded;
		line-style:single;
		line-width:1;
		line-color:light blue;
		fill-style:Gradient Horizontal Top;
		fill-color:pale blue;
		fill-accent-color:white;
		}
	$Button:hover,$Button:focused {
		font:Arial,18,B;
		border-shape:small-rounded;
		line-style:single;
		line-width:1;
		line-color:blue;
		fill-style:Gradient horizontal;
		fill-color:Green;
		fill-accent-color:White;}
		}

	$frame {
		fill-style:Gradient horizontal;
		fill-color:White;
		fill-accent-color:light Blue;
		}
	{endstyle};




<12,3 A!A><12,3 B!B><12,3 C!C><12,3 D!D><12,3 E!E><12,3 F!F><12,3 G!G><12,3 H!H><12,3 I!I><12,3 J!J><12,3 K!K> ;
<12,3 L!L><12,3 M!M><12,3 N!N><12,3 O!O><12,3 P!P><12,3 Q!Q><12,3 R!R><12,3 S!S><12,3 T!T><12,3 U!U><12,3 W!W> ;
<12,3 V!V><12,3 X!X><12,3 Y!Y><12,3 Z!Z><12,3 .!.><12,3 -!-><12,3 #!#><12,3 @!@><12,3 +!+><12,3 &&!&&><12,3 �!� > ;
<12,3 1!1><12,3 2!2><12,3 3!3><12,3 4!4><12,3 5!5><12,3 6!6><12,3 7!7><12,3 8!8><12,3 9!9><12,3 0!0><12,3  ! > ;



{font=a,15,b}
             <14,4 OK !OK>     <14,4 Clear!clear>     <15,4 Cancel  !Cancel>     <14,4 Reset !reset>;			
%dlg%,<<%code%
select
	case a_dlg_button="cancel"
		vn=trim(OriginalValue)
		a_dlg_button=""
		ui_modeless_dlg_close("vn")
		END
	case a_dlg_button="Clear"
		vn=left(vn,len(vn)-1)
	case a_dlg_button="reset"
		vn=""
    case a_dlg_button="&&"
		' Process the && keys
	    vn=vn+"&"
    case wordat(a_dlg_button,"1,2,3,4,5,6,7,8,9,0,.,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z, ,_,#,@,+,�,",",")>0
		' Process the regular keys that need no translation
	    vn=vn+a_dlg_button
    case a_dlg_button="ok"
	    ui_modeless_dlg_close("vn")
		END
end select
a_dlg_button=""
END
%code%)   

' Return Value
Key_PadGen=vn

END FUNCTION

[CarverRon]

Re: How to use an script keyboard in multiple field?

Excellent!!!.
I was able to add the keyboard to all the fields needed.
The functionalityty is great. I did test it with number fields and it works with them too.
I have posted a revised version fully functional.
Very impressive description and education visiting your tips page
Thanks.