Xdialog a_dlg_button

[MoGrace]

Re: Xdialog a_dlg_button

In Finian's example #9, what needs to change if instead of embedding the functions in the script, these were global functions instead? I am trying to learn to code my modeless xdialogs like this example below (*) where local variables can be used in a global UDF called from a button script that passes values from the form to local variables instead of global or shared. Is the pointer to the local_variables() all that is needed in the script and the UDF to make it work like this embedded example? I am trying to get these lengthy xdialog definitions out of my button scripts...

*varC_Result = ui_modeless_dlg_box(dlg_title,dlg_body,dlg_event)

[CALocklin]

Re: Xdialog a_dlg_button

Robin,

I don't think that using "local_variables()" in a global function makes much sense. Oops, as I typed that I just realized you said "global" which is not necessarily "generic". If you want to use it as a generic function then I really would not attempt to use "local_variables()" at all. In fact, I seldom use "local_variables()" because it usually becomes much too difficult to remember all my local variables - especially after working on something else then coming back to debug/update my function. When creating functions (with one exception in the past and I'm not sure I'd do it if starting over today) I just pass all necessary variables as arguments to the function.

Oops again! Just as I was ready to post this I realized you were wanting to use a modeless xdialog. Oh well, most of what I did would still be applicable to a modeless xdialog. Only minor modifications would be required to make this example modeless.

Here's how I would create it as a generic function (with lots of internal comments):

FUNCTION Color_select as C ( color_list as C, not_allowed_list as C )

	'FYI: Personally I HATE the use of varC_Result. It's the result from the xdialog so I use 
	'dlg_result.
	'I  already know that the result from an xdialog will always be a character string and 
	'don't need a reminder. Besides, if you are running this check: IF some_var = "Fred", then 
	'you can be pretty sure that some_var should be a character string. Using varC_some_var 
	'adds nothing to that as far as I'm concerned.
	DIM dlg_result as C
	'The color list should be a crlf() list. Assume any commas need to be changed to a crlf()
	color_list = stritran( color_list, ",", crlf() )
	'Sort the list JIC.
	color_list = sortsubstr( color_list, crlf() )
	'Remove any leading or trailing blanks JIC.
	'FYI: If it helps, consider the "line" variable here to be "line_in_color_list".
	color_list = *for_each( line, alltrim( line ), color_list )
	'FYI: Don't need to create an array - just use the list.
	'FYI: Don't need to define a label name variable for buttons. Just put the name in the button definition.
	'FYI: Regions are WAAAY overused. In most cases, they are only necessary to maintain 
	'alignment of columns on multiple rows. This dialog has no such issue so all regions were removed.
	'FYI: Added background color just to make it look better.
	'FYI: I replaced {line=1,0} with {sp} only because I've been told it looks more modern to 
	'eliminate the line. Also changed ysize to .3 rather than using multiple semicolons.
	'FYI: I added an 'OK' button because some users prefer to select an item then click the OK 
	'button rather than double clicking. (In this case I also reduced the size of the buttons 
	'for aesthetic purposes only.)
	dlg_code = <<%dlg%
{ysize=.3}{background=#220,235,245}
Double click on a color:;
[.26,10Color_selected^#color_list!colors_*];
{sp};
<10OK> <10Cancel>
%dlg%

	event_code = <<%code%
IF left( a_dlg_button, 6 ) = "colors"	'FYI: The "THEN" is not needed. So I leave them off.
	IF a_dlg_button = "Colors_dblclick"
		'FYI: Removed the 'selected' message that was really only useful for the developer.
		'FYI: Since the user double clicked, that should be the same as selecting a color then 
		'clicking 'OK' so set a_dlg_button to OK and we'll do more checking later.
		a_dlg_button = "OK"
	ELSE
		a_dlg_button = ""
		'FYI: Setting color_select to blank is not necessary.
	END IF
	'FYI: I prefer using ELSEIF *unless* it's absolutely necessary to use a separate IF 
	'statement. That way (1) it's easier to tell where the whole thing ends and (2) if I see a 
	'new IF then I know that something (probably a_dlg_button in the case of xdialogs) could 
	'have been changed in one of the previous statements - as above - and needs separate handling.
'ELSEIF a_dlg_button = "Close"	'FYI: This whole ELSEIF section is no longer needed.
'	Color_select = ""
END IF
'Once a color has been selected, verify that it's not on the 'not allowed' list.
IF a_dlg_button = "OK"
	IF is_one_of( color_selected, not_allowed_list )
		msg = "The color " + color_selected + " is not permitted in this case." + crlf(2)
		msg = msg + "Please select another color or press 'Cancel' to quit."
		ui_msg_box( "SELECTION ERROR", msg, ui_attention_symbol )
		a_dlg_button = ""
	END IF
END IF
%code%

	dlg_result = ui_dlg_box( "Select Color", dlg_code, event_code )
	IF dlg_result = "OK"
		Color_select = color_selected
	ELSE
		Color_select = ""	'FYI: This ELSE really isn't required. Just added it for clarification.
	END IF

END FUNCTION	'Color_select

ui_msg_box( "RESULT", Color_select( "Red , Blue ,Green", "Green" ) )

Take all the "FYI" stuff out - and the one ELSEIF section - and you will have a much shorter script and it would include all the comments I would normally include.

If you have any questions about why I did something, post them and I'll do my best to explain my reasoning.

By the way, to see it with "my" colors, check out the attached screen shot. I will be happy to send a color file (.a5t) to anyone that wants to use those colors.

[MoGrace]

Re: Xdialog a_dlg_button

Hi Cal,
I have several lookup scripts that create xd's and all they need do is return a value for finding a record, so they seem to be good candidates for functions instead. In the script version I was dimming all variables used by the xd as shared, but in the function I set the arguments as Finian did so the script I call the function from, only needs to set
dim lv as p = local_variables() for it to work.

I like the idea of using dlg_result since it makes sense to use that with the dlg_title, dlg_body and dlg_event variables. Once I get the hang of writing my xd's this way it should be easier to convert the genie generated scripts.

I am curious for the need to have so many empty regions, I usually just remove them.