Announcement

**Stan Mathews** · 10-29-2014, 01:22 PM

Re: xdialog - one works, the other don't

Looks to me like there's nothing to keep the second xdialog open? I think the second example works/runs but closes immediately.

This stays open.

ok_button_label = "&OK"
cancel_button_label = "&Cancel"
xBox = ui_dlg_box("Employees",<<%dlg%
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{text=25:vName};
[%dk%.96,41 index^"Emp ID:13|Last Name:25|First Name:20|Badge No:18|Status:17"vEmps!empSelect_*];
%dlg%)

**Peter.Greulich** · 10-29-2014, 01:37 PM

Re: xdialog - one works, the other don't

I guess I don't understand what you mean by "there's nothing to keep the second xdialog open"?

Why does this stay open?

Code:

xBox = ui_dlg_box("Employees",<<%dlg%
{text=25:vName};
%dlg%)

And, yes, the other examples does open and immediately closes.

**Stan Mathews** · 10-29-2014, 01:59 PM

Re: xdialog - one works, the other don't

I don't know enough xdialog to discern what

[%dk%.96,41

does so I can't say for sure but it appears that Alpha knows to wait for the red x to close the xdialog when the text control immediately preceeds the end of the dialog code. When the dk control is last Alpha doesn't.

**Stan Mathews** · 10-29-2014, 02:35 PM

Re: xdialog - one works, the other don't

This seems to work. Don't know why the a_dlg_button variable was acquiring a value without the code section.

Code:

xBox = ui_dlg_box("Employees",<<%dlg%
{text=25:vName};
[%dk%.96,41 index^"Emp ID:13|Last Name:25|First Name:20|Badge No:18|Status:17"vEmps!empSelect_*];
%dlg%,<<%code%
a_dlg_button = ""
%code%)

**Peter.Greulich** · 10-29-2014, 03:01 PM

Re: xdialog - one works, the other don't

Interesting. Thx

**Peter.Greulich** · 10-29-2014, 03:52 PM

Re: xdialog - one works, the other don't

But on second thought, that's not a solution since no events will then fire.

**Peter.Greulich** · 10-29-2014, 03:57 PM

Re: xdialog - one works, the other don't

Okay, so lets go to the real world example.

This works:

Code:

[COLOR="#FF0000"]ui_modeless_dlg_box[/COLOR]("Employees",<<%dlg%
{Xmargin=2}
{background=pale_blue_1}
{Can_Exit=Close}
{lf};

{region1}
	{region2}
		{font=arial, 12, b}
		Employee: {sp=2} {text=75:vName};
		{font=arial, 11}
		[%dk%.96,41 index^"Emp ID:13|Last Name:25|First Name:20|Badge No:18|Status:17"vEmps!empSelect_*] ;;;
		
		{font=arial, 10, B}
		{sp=1} (vStatus:Active!status_change) {sp=2} (vStatus:Inactive!status_change) 
	{endregion2}
	 | 
	{font=arial, 12, b}
	{Ysize=1.5}
	{font=arial, 10, b}

 | 

{frame=1,1}
{region}
{Ysize=2}
	{region}{lf};
		Emp_Id: | {text=10:vEmp_Id} |{sp=5} Badge #: | [.15vBadge_No] ;
		Payroll #  | [.15vvPayroll_No] |{sp=5} Status: | [%v%.20vEmpStatus^=StatList];
	{Ysize=1}
	{endregion};;

{Ysize=2}	
	{region}
		| First Name: {sp=13} Middle Name: {sp=7} Last Name:;
		| [.25vFirst_Name]  [.25vMiddle_Name] [.25vLast_Name];
		Suffix: | [.25vSuffix] Initials: [.10vInitials];
		Title: | [.50vTitle]
		{lf};
		Home Address 1: | [.75vHome_Add1];
		Home Address 2: | [.75vHome_Add2];
		City: | [.25vCity] State: [.6vState] Zip: [.12vZip];
	{lf};
		
	Home Phone: | [.20vHome_Phone];
	Mobile Phone: | [.20vMobile_Phone];
	Email: | [.75vEmail];
	{lf};
	
	DOH: | {text=14:vDOH} ;
	Terminated: | {text=14:vTerminated];
	{endregion};
{endregion};

{lf};

{color=Black on White} 

	{lf=13} ;
	{justify=top,right}
	{color=Red on White} 
	{font=arial, 10, B}
	<%I=$a5_close;O={I=1}  {J+C}Close; %15,1.1Close>
{endregion1}

%dlg%)

This doesn't work:

Code:

[COLOR="#FF0000"]ui_dlg_box[/COLOR]("Employees",<<%dlg%
{Xmargin=2}
{background=pale_blue_1}
{Can_Exit=Close}
{lf};

{region1}
	{region2}
		{font=arial, 12, b}
		Employee: {sp=2} {text=75:vName};
		{font=arial, 11}
		[%dk%.96,41 index^"Emp ID:13|Last Name:25|First Name:20|Badge No:18|Status:17"vEmps!empSelect_*] ;;;
		
		{font=arial, 10, B}
		{sp=1} (vStatus:Active!status_change) {sp=2} (vStatus:Inactive!status_change) 
	{endregion2}
	 | 
	{font=arial, 12, b}
	{Ysize=1.5}
	{font=arial, 10, b}

 | 

{frame=1,1}
{region}
{Ysize=2}
	{region}{lf};
		Emp_Id: | {text=10:vEmp_Id} |{sp=5} Badge #: | [.15vBadge_No] ;
		Payroll #  | [.15vvPayroll_No] |{sp=5} Status: | [%v%.20vEmpStatus^=StatList];
	{Ysize=1}
	{endregion};;

{Ysize=2}	
	{region}
		| First Name: {sp=13} Middle Name: {sp=7} Last Name:;
		| [.25vFirst_Name]  [.25vMiddle_Name] [.25vLast_Name];
		Suffix: | [.25vSuffix] Initials: [.10vInitials];
		Title: | [.50vTitle]
		{lf};
		Home Address 1: | [.75vHome_Add1];
		Home Address 2: | [.75vHome_Add2];
		City: | [.25vCity] State: [.6vState] Zip: [.12vZip];
	{lf};
		
	Home Phone: | [.20vHome_Phone];
	Mobile Phone: | [.20vMobile_Phone];
	Email: | [.75vEmail];
	{lf};
	
	DOH: | {text=14:vDOH} ;
	Terminated: | {text=14:vTerminated];
	{endregion};
{endregion};

{lf};

{color=Black on White} 

	{lf=13} ;
	{justify=top,right}
	{color=Red on White} 
	{font=arial, 10, B}
	<%I=$a5_close;O={I=1}  {J+C}Close; %15,1.1Close>
{endregion1}

%dlg%)

**Stan Mathews** · 10-29-2014, 04:09 PM

Re: xdialog - one works, the other don't

And tacking this on the end makes it work. I have a feeling you'rd rather know why than just find a fix.

Code:

,<<%code%
if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else
    a_dlg_button = ""
end if
%code%)

**Peter.Greulich** · 10-29-2014, 04:20 PM

Re: xdialog - one works, the other don't

Well, yes, that solves it. And yes, why?

**Stan Mathews** · 10-29-2014, 04:30 PM

Re: xdialog - one works, the other don't

Ok, answer is, I think, you have an event defined for the vemps variable.

[%dk%.96,41 index^"Emp ID:13|Last Name:25|First Name:20|Badge No:18|Status:17"vEmps!empSelect_*] ;;;

In a normal modal xdialog anything that sets a_dlg_button to a value other than "" closes the xdialog. As soon as the vemps variable receives focus the empselect_setfocus event fires and that is placed in a_dlg_button. Since the event is not handled that closes the xdialog.

Change to

Code:

,<<%code%
if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else
    msgbox(a_dlg_button)
    a_dlg_button = ""
end if
%code%)

to observe.

**Al Buchholz** · 10-29-2014, 04:35 PM

Re: xdialog - one works, the other don't

Originally posted by Peter.Greulich View Post

Well, yes, that solves it. And yes, why?

Because the field (vEmps) has the

!empSelect_*

which generates the events for the field making a_dlg_button <> "" thereby closing a ui_dlg_box.

But that leaves open a ui_modeless_dlg_box by definition is modeless and needs to be forced to close.

Use debug(1) at the start of Stan's event code to follow the execution.

Using the * to generate events may generate more events than needed and then need to be defined so they can be handled or filtered out if not needed.

(edit: I have to type faster and test less.. ;) at least to get ahead of Stan.)

**Stan Mathews** · 10-29-2014, 04:43 PM

Re: xdialog - one works, the other don't

Thanks for the clarification on the modeless xdialog, Al.

One could also

Code:

,<<%code%
if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if left(a_dlg_button,10) = "empSelect_"
       'code here to process the possible events in a select...case...end select structure
else
    msgbox(a_dlg_button)
    a_dlg_button = ""
end if
%code%)

**Al Buchholz** · 10-29-2014, 04:49 PM

Re: xdialog - one works, the other don't

Sometimes it's like a bad penny, it just won't go away....

On the other hand generating events especially the killfocus one creates another caveat that is easy to become circular. And a ton of fun.

**Stan Mathews** · 10-29-2014, 04:59 PM

Re: xdialog - one works, the other don't

So you're saying the killfocus event is a killjoy?

Announcement

The Alpha Software Forum Participation Guidelines

xdialog - one works, the other don't

xdialog - one works, the other don't

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment