V9 suggest function in xdialog

[christobal]

From the learning Xdialog database in V9 under the section whats new in V9. There is an example of using the suggest function as a type in lookup, which in my opinion is one of the most important enhancements made to the formidable list of functions available .
See Code:
"

'Date Created: 09-Feb-2008 02:54:28 PM
'Last Updated: 09-Feb-2008 02:54:28 PM
'Created By  : Selwyn
'Updated By  : Selwyn
dim lname as c 
dim suggestions as c 
dim t as p 
t = table.open("customer")
ui_dlg_box("Suggestions",<<%dlg%
{wrap=50}
{lf};
Type into the 'Lastname' field. As soon as you start typing, Alpha Five shows matching values. Clicking on a matching value selects the value.;
{lf};
{region}
Lastname: |[.40lname!changed];
|[.40,5selectedLname^#suggestions!selectedLnameChanged];
{endregion};
%dlg%,<<%code%
if a_dlg_button = "changed" then 
 suggestions = t.suggest("lastname",lname,10)
 a_dlg_button = ""
end if 
if a_dlg_button = "selectedLnameChanged" then 
 a_dlg_button = ""
 lname = selectedLname
end if 
 
%code%)
 
t.close()

Have tinkered with this,
but am unable to include other fields in the same dialogbox using this function i.e. Bill Address1 or Phone Number along with the Lastname dialog. Does anyone have any thoughts on this issue?

[Tim Kiebert]

Re: V9 suggest function in xdialog

Here is one way using one input and three lists. Take note of the mask functon used in the phone input.

dim input as c 
dim suggest_name as c 
dim suggest_Addr as c 
dim suggest_Ph as c 
dim t as p 
t = table.open("customer")
ui_dlg_box("Suggestions",<<%dlg%

{wrap=50}
{lf};
Type into the 'Lastname' field. As soon as you start typing, Alpha Five shows matching values. Clicking on a matching value selects the value.;
{lf};

{region}
Search for |[.40input!changed];

Last Name|[.40,5selectedName^#suggest_Name!Name_selected];
|[.40selectedName];
Address|[.40,5selectedAddr^#suggest_Addr!Addr_selected];
|[.40selectedAddr];
Phone|[.40,5selectedPh^#suggest_Ph!Ph_selected];
|[.40selectedPh];
{endregion};
%dlg%,<<%code%
if a_dlg_button = "changed" then 
    suggest_Name = t.suggest("lastname",input,10)
    suggest_Addr = t.suggest("Bill_Address_1",input,10)
    suggest_Ph = t.suggest("Phone",mask(input,"(   )|   -   "),10)
    a_dlg_button = ""
end if 

if right(a_dlg_button,9) = "_selected" then 
    a_dlg_button = ""
end if 


%code%)


t.close()

[christobal]

Re: V9 suggest function in xdialog

Tim thanks for your reply,
After "banging my head on the pavement" all afternoon I ended up with an almost identical script.
Am presently trying to use this function as an alternative to the script action lookup dialog example. Using the the resulting name value to return the selected fields in an embedded xdialog browse. Using the new "Browse" feature it appears quite straightforward.



I'll use the variable value in a filter expression to display all related fields as defined in the browse object of the table in question. Will post an example based on the learning Xdialog table "Customer". Keep you fingers crossed for this one!