Announcement

**Tom@Abacus** · 09-21-2009, 12:22 PM

Re: XDialog Box - Header and Detail

Jack,

I have created this code by simply copying and pasting from code written in the Learning Xdialog sample database that is provided in the alpha five install. If I have understood you correctly then this should provide the foundation of what you desire. I don't know how experienced you are with xbasic but some is required to change relevant fields to fit your tables in the invoice set.

Tip - Any problems when using xdialog look at the many examples in the Learning Xdialog database for code to use/modify.

Code:

dim setname as c 
'path to invoice set
setname = "c:\a5v9\samples\alphasports\invoice.set"

dim vl as p 
vl = local_variables()
dim s as p 
s = set.open_session(setname)
 
'get pointer to invoice_header table
tih = s.invoice_header 

tih.index_primary_put("")
tih.fetch_first()

'get pointer to invoice_items table
tii = s.invoice_items 

dim line_number as n 
line_number = 1 

dim invoice_number as c 
dim invoice_date as d
dim customer as c 
dim lastname as c 
dim firstname as c 
dim address1 as c 
dim address2 as c 
dim city as c 
dim state as c 
dim zip as c 

dim items as c 
items = ""

dim direction as c 
direction = ""

invoice_number = ""

dim title_bar as c 
title_bar = "{F=Arial,8}{C=Dark Blue,White,Dark Blue}{B=White,Dark Blue,Blue White}#{T=0.25}Quantity{T=0.75}Description{T=3.25}Price{T=4.00}Total"

page = "Header"
ui_modeless_dlg_box("Invoice",<<%dlg%
{can_exit=close}
{startup=init}
{tab=page}
{pane=Header}
{region0}
<%B=T;T=First;I=$a5_record_first;%!first>
<%B=T;T=Previous;I=$a5_record_previous;%!prev>
<%B=T;T=Next;I=$a5_record_next;%!next>
<%B=T;T=Last;I=$a5_record_last;%!last>
<%B=T;T=Find;I=$a5_find_by_key;%!find>
;
{endregion0};
{line=1,0};
{region}
Invoice Number: |[.20invoice_number];

Date: |[.20invoice_date];
Customer:|[.55customer];
Name:|[.20firstname] [.32lastname];;
Address1:|[.55address1];
Address2:|[.55address2];
City, ST Zip: |[.31city] [.5state] [.12zip];

{endregion};

{pane=Details}
{region}
[%O={@@};D%.90,1^#title_bar?.f.];
[%O={@@};D%.90,10line_number^#items];
{endregion};

{endtab}
%dlg%,<<%code%
if a_dlg_button = "init" then 
	get_header_variables(vl)
	line_number = 1
end if 

if a_dlg_button = "find" then 
	find_invoice(vl)
	line_number = 1 
end if 

if a_dlg_button = "close" then 
	s.close()
	ui_modeless_dlg_close("invoice")
end if 

if inlist(a_dlg_button,"first","next","prev","last") then 
	if a_dlg_button = "first" then 
		direction = "first"
	else if a_dlg_button = "prev" then 
		direction = "prev"		
		
	else if a_dlg_button = "next" then 
		direction = "next"
	else if	a_dlg_button = "last" then 
		direction = "last"		
	end if 
	fetch_next(vl)
	line_number = 1 
end if 

%code%)

function fetch_next as  c (vars as p)
with vars 	
if direction = "next" then 
	tih.fetch_next(1)
else if direction = "prev" then 
	tih.fetch_prev(1)
else if direction = "last" then 
	tih.fetch_last(1)
else if direction = "first" then 
	tih.fetch_first(1)
end if 
	get_header_variables(vl)
end with 	
end function 

function get_header_variables as v (vars as p)
with vars 	
	invoice_number = tih.eval("invoice_number")
	invoice_date = tih.eval("Date")
	lastname = tih.eval("customer->lastname")
	firstname = tih.eval("customer->firstname")
	company = tih.eval("customer->company")
	address1 = tih.eval("customer->Bill_Address_1")
	address2 = tih.eval("customer->Bill_Address_2")
	
	city = tih.eval("customer->Bill_City")
	state = tih.eval("customer->Bill_State_Region")
	zip = tih.eval("customer->Bill_Postal_Code")
	get_items(vl)
end with 	
end function 



function get_items as c (vars as p)
with vars 

items = ""
tii.fetch_first()
while .not. tii.fetch_eof()
	items = items + tii.eval("quantity + '|'+product->description+'|'+ price + '|' + alltrim(str((quantity*price),12,2,'$'))")+ crlf()
	
	tii.fetch_next()
end while 

Dim format as p 
Format.tab_stops=".5,3,3.75"
Format.odd_row_color="White"
Format.even_row_color="Blue White"
Format.odd_selected_color="Dark Blue"
Format.even_selected_color="Dark Blue"
Format.font="Arial,8"
Format.font_color_unselected="Black"
Format.font_color_selected="White"
Format.lastbutton="OK"
Format.group_size=1
Format.number_rows=.t.
Format.alternating_bands=.t.

'Apply 'owner draw' formatting information to the list
items = a5_owner_draw_list_fmt(items,Format)

end with 
end function 



function find_invoice as c (vars as p)
with vars

menu_choices = <<%list%
Record Number
Invoice Number
Lastname
%list%
 
 
result = ui_popup_menu(menu_choices) 
text_prompt = alltrim(result) + ":"
find_what = ""
if result = "" then 
	exit function 
end if 
	
find_result = ui_dlg_box("Find Invoice by " + result,<<%dlg%
{on_key=enter}
{lf};
{text=25,1:text_prompt} [.20find_what] {sp};;
{lf};
{line=1,0};
<10&Find!find?.not.(find_what="")> <10&Cancel!cancel>;
%dlg%)

if find_result = "find" .or. find_result = "enter" then 
	if find_what <>"" then 
		if result = "record number" then 
			tih.index_primary_put("")
			tih.fetch_goto(val(find_what))
			get_header_variables(vl)
		else if result = "invoice number" then 
			tih.order("invoice_number")
			tih.fetch_find(find_what)
			get_header_variables(vl)
		else if result = "lastname" then 
			tih.order("customer->lastname")
			tih.fetch_find(find_what)
			get_header_variables(vl)
		end if 
	end if 
end if 
end with 
end function

**jacklcs22** · 09-21-2009, 09:00 PM

Re: XDialog Box - Header and Detail

Many thanks.. I will study that...

Announcement

The Alpha Software Forum Participation Guidelines

XDialog Box - Header and Detail

XDialog Box - Header and Detail

Comment

Comment