Announcement

**Tom Henkel** · 12-10-2009, 10:16 AM

Re: xdialog help please

Charlie,

I realize it is really cool to use the html and all, but couldn't you just do this all in straight x_dialog? I think the issue here is how to get a variable into the HTML code. We could do this quite easily in x_dialog without all the html, even with the font sizing and colors.

Tom

**Tom Henkel** · 12-10-2009, 10:42 AM

Re: xdialog help please

See this; It needs some error checking, but it should do what you want...

Code:

'Date Created: 10-Dec-2009 08:36:06 AM
'Last Updated: 10-Dec-2009 08:36:06 AM
'Created By : E009933
'Updated By : E009933
'Create an XDialog dialog box to prompt for parameters.
DIM global vndaysleft as C
var->vndaysleft="1"
dim win3dcolor as c 
win3dcolor = ui_color_format("win3d","#rhghbh")
'vdaysleft_html = a5_html_background(replace_parameters(vdaysleft_html,local_variables()),win3dcolor)
ok_button_label = "Upgrade Licence"
cancel_button_label = "Continue in DEMO Mode"
Delete XdialogStyle
dim XDialogStyle as p
XDialogStyle.AccentColor = "White"
XDialogStyle.Color = "#51+102+255"
varC_result = ui_dlg_box("BSE Accounting",<<%dlg%
{Windowstyle=Gradient Horizontal Bottom}
{startup=init}
{region}
{font=arial,12,B}You have 
{color=red,white}{font=arial,16,bold} {text=vndaysleft}
{color=black,white}{font=arial,12,B} days left on; 
your 30 day subscription ;
To upgrade or renew your licence,;
Please select the "Upgrade" button Below;
{endregion};
{line=1,0};
{region}
<*40,2=ok_button_label!OK>; 
<40,2=cancel_button_label!CANCEL>
{endregion};
%dlg%,<<%code%
if a_dlg_button = "init" then 
a_dlg_button = ""
end if
%code%)
end

**crimmelcp** · 12-10-2009, 04:27 PM

Re: xdialog help please

Thanks Tom:
I would use Xdialod with out the HTML if I could figure out how to center the text on selected rows.

You have

6

days left in your subscription

needs to be centered within the xdialog box

**G Gabriel** · 12-10-2009, 05:27 PM

Re: xdialog help please

{justify=center}

P.S.
Didn't read your html script.

**CALocklin** · 12-11-2009, 04:07 AM

Re: xdialog help please

HINTS:
- This is one of the keys to making really fancy xdialogs... Move the "dlg_text" outside of the ui_dlg_box() function so you can really manipulate it any way you want. (Note how I handled the "1" day left - it works much better than using {text=} because the {text=} always takes up a set amount of space. By using stritran() to insert the desired text, the result will take up only whatever space is needed whether the text consists of 1 character or 50. I surround the text I want to replace with [[...]] because it was something I could easily identify at a glance. First, they are easy to see in the script itself. Second, if I forget to change them, it's really obvious during testing. (try it!) If I simply inserted some unique text such as changethis, then it wouldn't stand out if I forgot to change it.)
- Add a {ysize=.3} so that the ";" characters will give about 1/3 line per character when there is nothing else on the line. This helps a lot with getting a nice looking dialog.
- STOP USING UNNECESSARY REGIONS!!! (One of my pet peeves in case you couldn't guess.) Every time you use a {region}, it adds (forces) extra space at the bottom of the region. By taking out the regions (neither of which was necessary), you have more control over the spacing because YOU add the spacing as you want it. My result has less space at the bottom of the last button ONLY because I removed the {region}. There is also less space between the initial text and the horizontal 'separator' line.
- Note that I removed the "ok_button_label" and "cancel_button_label" variables. (Another pet peeve.) They are almost never needed and, as far as I'm concerned, just add more confusion. Just put the text in the button and leave out the "=" sign.
- {line} commands always need to be left justified. (i.e., if everything else is center justified, you will have to add a "{justify=left}" before the {line} command and another {justify=center} after it.)
- Line spacing can get really weird sometimes. When it does, it's usually best to leave the line as one long one rather than starting new lines in the middle of a "sentence". Remember that the only thing that should be used to start a new line in an xdialog is a ";" symbol - not just adding a carriage return of your own in the input text. (When I first started editing the script, the lines started overlapping. I've run into that before and just had to play with it and, quite often, getting each output line on one line in the xdialog definition solved the problem - note that the first line was split after the "{text=vndaysleft}" even though it wasn't the actual end of the output line. (confused yet?))

This one has everything centered, smaller horizontal spaces as noted above, and no weird spacing around the number of days. (I also take out that "create xdialog to prompt..." - more useless drivel. I often add a comment to tell what the xdialog really does but that one is virtually useless. Besides, this isn't really prompting for parameters; it's warning that the registration is about to expire.)

Code:

 'Date Created: 10-Dec-2009 08:36:06 AM
'Last Updated: 10-Dec-2009 08:36:06 AM
'Created By : E009933
'Updated By : E009933
DIM GLOBAL vndaysleft as C
var->vndaysleft = "1"
DIM win3dcolor as C
win3dcolor = ui_color_format( "win3d", "#rhghbh" )
'vdaysleft_html = a5_html_background(replace_parameters(vdaysleft_html,local_variables()),win3dcolor)
DELETE XdialogStyle
DIM XDialogStyle as P
XDialogStyle.AccentColor = "White"
XDialogStyle.Color = "#51+102+255"
dlg_text = <<%dlg%
{Windowstyle=Gradient Horizontal Bottom}
{ysize=.3}
{startup=init}
{justify=center}
{font=arial,12,B}You have {color=red,white}{font=arial,16,bold}[[vndaysleft]] {color=black,white}{font=arial,12,B} days left on;
your 30 day subscription.;
To upgrade or renew your license,; please select the "Upgrade" button Below ;;
{justify=left}{line=1,0};
{justify=center}
{sp};
<*40,2Upgrade License!OK>;
<40,2Continue in DEMO Mode!CANCEL>
%dlg%
dlg_text = stritran( dlg_text, "[[vndaysleft]]", vndaysleft )
varC_result = ui_dlg_box( "BSE Accounting", dlg_text, <<%code%
IF a_dlg_button = "init" THEN
    a_dlg_button = "" 'Huh? This doesn't do anything. I assume it's just a place holder for the future.
END IF
%code% )
END'

Announcement

The Alpha Software Forum Participation Guidelines

xdialog help please

xdialog help please

Comment

Comment

Comment

Comment

Comment