Need help on xbasic calculator

[crimmelcp]

The plus sing works fine
1+1=2+2=4+5=9
The minus sign works fine
The divide sign works fine

The * or multiply sign fails
Any help would be appreciated.

Thanks
Charlie Crimmel

xbasic code is below
'Date Created: 11-May-2010 06:59:09 AM
'Last Updated: 14-May-2010 05:15:15 PM
'Created By : charlie
'Updated By : charlie
trace.clear()
dim global base as C
dim global base1 as C
dim global result as C

var->base = ""
var->base1 = ""
var->result = ""

ui_modeless_dlg_box("vn",<<%dlg%
{xmargin=2}
{ymargin=1}
{nocaption}
{font=a,10,b}
{color=white on white}

{font=a,25,b}
[.70 base];

{font=a,28,b}
{style}
$Button {
font:Arial,15,b;
border-shape:SMALL-rounded;
line-style:single;
line-width:1;
line-color:light blue;
fill-style:Gradient Horizontal Top;
fill-color:Pale blue;fill-accent-color:white;
}
$Button:hover,$Button:focused {
font:Arial,18,B;
border-shape:small-rounded;
line-style:single;
line-width:1;
line-color:blue;
fill-style:Gradient horizontal;
fill-color:Green;
fill-accent-color:White;}
}
$frame {
fill-style:Gradient horizontal;
fill-color:White;
fill-accent-color:light Blue;
}
{endstyle};
{color=black on white}
<15,5 1!1><15,5 2!2><15,5 3!3> <15,5+!+>;
<15,5 4!4><15,5 5!5><15,5 6!6> <15,5-!->;
<15,5 7!7><15,5 8!8><15,5 9!9> <15,5*!*>;
<15,5 .!.><15,5 0!0>
{font=a,15,b}
<15,5 Clear!clear> <15,5/!/>;
{font=a,15,b}
<15,5 OK!OK><15,5Cancel!Cancel><15,5 Reset!reset> <15,5=!>;
%dlg%,<<%code%
if a_dlg_button="clear" then
var->base = ""
var->base1 = ""
end if
if a_dlg_button="reset" then
var->base = ""
var->base1 = ""
end if
if a_dlg_button="Cancel" then
var->base = ""
var->base1 = ""
ui_modeless_dlg_close("VN")
end if
if a_dlg_button="OK" then
var->base = ""
var->base1 = ""
ui_modeless_dlg_close("VN")
end if

if a_dlg_button="." then
'Update value in existing variable 'base' to '=Var->base+"."
base = convert_type(a5_eval_expression("=Var->base+\".\""),"C")
trace.WriteLn("Pressed Number .")
end if

if a_dlg_button="1" then
'Update value in existing variable 'base' to '=Var->base+"1"
base = convert_type(a5_eval_expression("=Var->base+\"1\""),"C")
trace.WriteLn("Pressed Number 1")
end if

if a_dlg_button="2" then
'Update value in existing variable 'base' to '=Var->base+"2"
base = convert_type(a5_eval_expression("=Var->base+\"2\""),"C")
trace.WriteLn("Pressed Number 2")
end if

if a_dlg_button="3" then
'Update value in existing variable 'base' to '=Var->base+"3"
base = convert_type(a5_eval_expression("=Var->base+\"3\""),"C")
trace.WriteLn("Pressed Number 3")
end if

if a_dlg_button="4" then
'Update value in existing variable 'base' to '=Var->base+"4"
base = convert_type(a5_eval_expression("=Var->base+\"4\""),"C")
trace.WriteLn("Pressed Number 4")
end if

if a_dlg_button="5" then
'Update value in existing variable 'base' to '=Var->base+"5"
base = convert_type(a5_eval_expression("=Var->base+\"5\""),"C")
trace.WriteLn("Pressed Number 5")
end if

if a_dlg_button="6" then
'Update value in existing variable 'base' to '=Var->base+"6"
base = convert_type(a5_eval_expression("=Var->base+\"6\""),"C")
trace.WriteLn("Pressed Number 6")
end if

if a_dlg_button="7" then
'Update value in existing variable 'base' to '=Var->base+"7"
base = convert_type(a5_eval_expression("=Var->base+\"7\""),"C")
trace.WriteLn("Pressed Number 7")
end if

if a_dlg_button="8" then
'Update value in existing variable 'base' to '=Var->base+"8"
base = convert_type(a5_eval_expression("=Var->base+\"8\""),"C")
trace.WriteLn("Pressed Number 8")
end if

if a_dlg_button="9" then
'Update value in existing variable 'base' to '=Var->base+"9"
base = convert_type(a5_eval_expression("=Var->base+\"9\""),"C")
trace.WriteLn("Pressed Number 9")
end if

if a_dlg_button="0" then
'Update value in existing variable 'base' to '=Var->base+"0"
base = convert_type(a5_eval_expression("=Var->base+\"0\""),"C")
trace.WriteLn("Pressed Number 0")
end if

if a_dlg_button="+" then
base1 = convert_type(a5_eval_expression("=Var->base"),"C")
'Update value in existing variable 'result' to '1
result = "1"
'Clear fields 'Base' in current form.
Base = ""
trace.WriteLn("Pressed Number +")
end if

if a_dlg_button="-" then
'Update value in existing variable 'base1' to '=Var->base
base1 = convert_type(a5_eval_expression("=Var->base"),"C")
'Update value in existing variable 'result' to '2
result = "2"
'Clear fields 'Base' in current form.
Base = ""
trace.WriteLn("Pressed Number -")
end if

if a_dlg_button="*" then
base1 = convert_type(a5_eval_expression("=Var->base"),"C")
'Update value in existing variable 'result' to '3
result = "3"
'Clear fields 'Base' in current form.
Base = ""
trace.WriteLn("Pressed Number *")
end if


if a_dlg_button="/" then
'Update value in existing variable 'base1' to '=Var->base
base1 = convert_type(a5_eval_expression("=Var->base"),"C")
'Update value in existing variable 'result' to '4
result = "4"
'Clear fields 'Base' in current form.
Base = ""
trace.WriteLn("Pressed Number /")
end if

if a_dlg_button="=" then
'Conditional code follows. Executes only if the condition expression is True.
IF Var->result = "1" THEN
'Update value in existing variable 'base' to '=str(val(Var->base1)+val(base),10,2)
base = convert_type(a5_eval_expression("=str(val(Var->base1)+val(base),10,2)"),"C")
END IF

'Conditional code follows. Executes only if the condition expression is True.
IF Var->result = "2" THEN
'Update value in existing variable 'base' to '=str(val(Var->base1)-val(base),10,2)
base = convert_type(a5_eval_expression("=str(val(Var->base1)-val(base),10,2)"),"C")
END IF

'Conditional code follows. Executes only if the condition expression is True.
IF Var->result = "3" THEN
'Update value in existing variable 'base' to '=str(val(Var->base1)*val(base),10,2)
base = convert_type(a5_eval_expression("=str(val(Var->base1)*val(base),10,2)"),"C")
END IF

'Conditional code follows. Executes only if the condition expression is True.
IF Var->result = "4" THEN
'Update value in existing variable 'base' to '=str(val(Var->base1)/val(base),10,2)
base = convert_type(a5_eval_expression("=str(val(Var->base1)/val(base),10,2)"),"C")
END IF
trace.WriteLn("Pressed Number =")

end if

%code%)

[G Gabriel]

Re: Need help on xbasic calculator

Here you have it. This will give you a popup calculator. Add cosmetics.
I did not code for the OK button, you need to place the value wherever you want. Maybe something like:
this.value=val(base)

dim global base as C=""
dim global base1 as C=""
dim global result as C
dim vop as n=0
ui_modeless_dlg_box("vn",<<%dlg%
{xmargin=2}
{ymargin=1}
{nocaption}

{font=a,15,b}
[.70 base];
{font=a,28,b}
<15,5 1!x1><15,5 2!x2><15,5 3!x3> <15,5+!+a>;
<15,5 4!x4><15,5 5!x5><15,5 6!x6> <15,5-!-a>;
<15,5 7!x7><15,5 8!x8><15,5 9!x9> <15,5*!*a>;
<15,5 .!x.><15,5 0!x0>
{font=a,15,b}
<15,5 Clear!clear> <15,5/!da>;
{font=a,15,b}
<15,5 OK!OK><15,5Cancel!Cancel><15,5 Reset!reset> <15,5=!>;
%dlg%,<<%code%
select
	case left(a_dlg_button,1)="x"
	base=base+right(a_dlg_button,1)
    case a_dlg_button="clear"
	base = left(base,len(base)-1)
	case a_dlg_button="Reset"
	base=""
	case a_dlg_button="cancel"
	ui_modeless_dlg_close("vn")
end select
if right(a_dlg_button,1)="a"
	base1=base
	base=""
select
    case left(a_dlg_button,1) ="+"
    vop=1
    case left(a_dlg_button,1) ="-"
    vop=2
    case left(a_dlg_button,1) ="*"
    vop=3
    case left(a_dlg_button,1) ="d"
    vop=4       
end select
end if
if a_dlg_button="="
select
    case vop=1
    base=ltrim(str(val(base)+val(base1),70,2))
    case vop=2
    base=ltrim(str(val(base1)-val(base),70,2))
    case vop=3
    base=ltrim(str(val(base)*val(base1),70,2))
    case vop=4
    base=ltrim(str(val(base1)/val(base),70,2))
end select
end if
%code%)

[G Gabriel]

Re: Need help on xbasic calculator

Slightly better version for popup:

dim global base as C=""
dim global base1 as C=""
dim global result as C
dim vop as n=0
ui_modeless_dlg_box("vn",<<%dlg%
{xmargin=2}
{ymargin=.1}
{nocaption}
{region0}
{font=a,10,b}
{region1}{font=a,14,b}{ypad=2}{lf=4};[.27,2 base]{endregion1}{font=a,7}|{region2}{ypad=1}{lf};{ypad=.1}Decimal;[%z;s1,10%.6spin]{endregion2};
{endregion0};
{font=a,12,b}<7,2 1!x1><7,2 2!x2><7,2 3!x3>{font=a,22,b}<7,2+!+a>;
{font=a,12,b}<7,2 4!x7><7,2 5!x2><7,2 6!x6>{font=a,22,b}<7,2-!-a>;
{font=a,12,b}<7,2 7!x7><7,2 8!x8><7,2 9!x9>{font=a,22,b}<7,2x!*a>;
{font=a,12,b}<7,2 .!x.><7,2 0!x0>{font=a,8}
{font=a}<7,2 Clear!clear>{font=a,22,b}<7,2/!da>;{font=a}
<7,2 OK!OK><7,2Cancel!Cancel><7,2 Reset!reset>{font=a,22,b}<7,2=!>;
%dlg%,<<%code%
select
	case left(a_dlg_button,1)="x"
	base=base+right(a_dlg_button,1)
        case a_dlg_button="clear"
	base = left(base,len(base)-1)
	case a_dlg_button="Reset"
	base=""
	case a_dlg_button="cancel"
	ui_modeless_dlg_close("vn")
end select
if right(a_dlg_button,1)="a"
	base1=base
	base=""
select
    case left(a_dlg_button,1) ="+"
    vop=1
    case left(a_dlg_button,1) ="-"
    vop=2
    case left(a_dlg_button,1) ="*"
    vop=3
    case left(a_dlg_button,1) ="d"
    vop=4       
end select
end if
if a_dlg_button="="
select
    case vop=0
    base=base
    case vop=1
    base=ltrim(str(val(base)+val(base1),70,val(spin)))
    vop=0
    case vop=2
    base=ltrim(str(val(base1)-val(base),70,val(spin)))
    vop=0
    case vop=3
    base=ltrim(str(val(base)*val(base1),70,val(spin)))
    vop=0
    case vop=4
    base=ltrim(str(val(base1)/val(base),70,val(spin)))
    vop=0
end select
end if
%code%)

[MikeC]

Re: Need help on xbasic calculator

Nice G,
Substitute

4!x[COLOR="Blue"]4[/COLOR]><7,2 5!x[COLOR="Blue"]5[/COLOR]><7,2

for the

4!x[SIZE=5][COLOR=Red]7[/COLOR][/SIZE]><7,2 5!x[SIZE=5][COLOR=Red]7[/COLOR][/SIZE]><7,2

and think it is done!

[G Gabriel]

Re: Need help on xbasic calculator

Better..

'Date Created: 14-May-2010 05:45:56 PM
'Last Updated: 14-May-2010 08:14:32 PM
'Created By  : Gabriel
'Updated By  : Gabriel
dim global base as C=""
dim global base1 as C=""
spin="2"
dim vop as n=0
ui_modeless_dlg_box("vn",<<%dlg%
{xmargin=4}
{ymargin=.1}
{nocaption}
{region0}
{font=a,10,b}
{region1}{font=a,14,b}{ypad=2}{lf=4};[.27,2 base]{endregion1}{font=a,7}|{region2}{ypad=1}{lf};{ypad=.1}Decimal;{font=a,9}[%z;s1,10%.7spin]{endregion2};
{endregion0};
{font=a,12,b}<7,2 1!x1><7,2 2!x2><7,2 3!x3>{font=a,22,b}<7,2+!+a>;
{font=a,12,b}<7,2 4!x4><7,2 5!x5><7,2 6!x6>{font=a,22,b}<7,2-!-a>;
{font=a,12,b}<7,2 7!x7><7,2 8!x8><7,2 9!x9>{font=a,22,b}<7,2x!*a>;
{font=a,12,b}<7,2 .!x.><7,2 0!x0>{font=a,8}
{font=a}<7,2 Clear!clear>{font=a,22,b}<7,2/!da>;{font=a}
<7,2 OK!OK><7,2Cancel!Cancel><7,2 Reset!reset>{font=a,22,b}<7,2=!>;
 ; ;
%dlg%,<<%code%
select
	case left(a_dlg_button,1)="x"
	base=base+right(a_dlg_button,1)
    case a_dlg_button="clear"
	base = left(base,len(base)-1)
	case a_dlg_button="Reset"
	base=""
	case a_dlg_button="cancel"
	ui_modeless_dlg_close("vn")
end select
if right(a_dlg_button,1)="a"
	base1=base
	base=""
select
    case left(a_dlg_button,1) ="+"
    vop=1
    case left(a_dlg_button,1) ="-"
    vop=2
    case left(a_dlg_button,1) ="*"
    vop=3
    case left(a_dlg_button,1) ="d"
    vop=4       
end select
end if
if a_dlg_button="="
select
	case vop=0
	base=str(base,70,1)
    case vop=1
    base=ltrim(str(val(base)+val(base1),70,val(spin)))
    vop=0
    case vop=2
    base=ltrim(str(val(base1)-val(base),70,val(spin)))
    vop=0
    case vop=3
    base=ltrim(str(val(base)*val(base1),70,val(spin)))
    vop=0
    case vop=4
    base=ltrim(str(val(base1)/val(base),70,val(spin)))
    vop=0
end select
end if
%code%)