Selwyn's Xbasic Printing example

[Jim Chapman]

Hello,

I'm having trouble getting a simple ui_printer_draw() function to work. I don't have distiller and in comparing the popup help with Selwyn's example I'm getting confused. The second parameter in the example appears to be a message to the user. However in the context help, the second parameter is 'c output_file".

Can anyone give me a very simple example. For instance, what is wrong with the following:



ui_printer_draw("NEC SuperScript 1400 Series","This is a test","c:\atestPrint.prn","This is the content")


Thanks,
Jim

[Selwyn Rabins]

RE: Selwyn's Xbasic Printing example

since you don't have distiller, you are printing directly to the printer and not to a file. so leave the filename parameter blank.


ui_printer_draw("NEC SuperScript 1400 Series","This is a test","","This is the content")

[Selwyn Rabins]

RE: Selwyn's Xbasic Printing example

i should add that you will waste a lot of paper because you have to test each iteration by printing to a physical printer.

since you don't have acrobat, i suggest that you use the ui_bitmap_create() command, which uses the same arguments as the printer command.

ui_bitmap_create("mytest",8.5,11)
'put a white background on the bitmap
ui_bitmap_draw("mytest",

[Selwyn Rabins]

RE: Selwyn's Xbasic Printing example








New Page 1




Here is an even easier way to test out the drawing commands.

Run this script, then as you type drawing commands, A5 shows you the
resulting output.

'Date Created: 21-Mar-2003
01:01:02 PM
'Last Updated: 21-Mar-2003 01:01:02 PM
'Created By : Selwyn Rabins
'Updated By : Selwyn Rabins
ui_bitmap_create("test",5,5)

clear_bitmap(local_variables())


code = ""%code%
'set the font for the next piece of text we write
set_font("Arial,24,B")
'output some text
text = "Alpha Software Inc."

'left alligment means that the text object has its top left bounding box as the
specified co-ordinate
'other options for aligment are
'right, center, left-top, right-top, bottom-left, left-center etc. and rotate
(used with set_rotate())
text(text,0,0,"Left")

'measure the width and height of the last text we wrote
w = text_width(text)
h = text_height(text)

'draw a line under this text
'set the brush color, which determines the fill for the box
set_brush("red")
inner_rect(0,0 + h,w,.1)
'pen styles are dot and dash or blank for a solid line
set_pen("green","dot",30)
line(0.5,3,4,3.5)
'now lets put some slanted text
text = "This is to cool for words"
set_origin(3,3)
set_rotate(-45)
set_font("arial,10")
text(text,0,0,"rotate")
set_rotate(0)
set_origin(0,0)
set_pen("black","",1)
line(0,1,8,1)
line(0,2,8,2)
set_origin(0,0)
'offset
h = wrap_text_height(word_wrap_text,2)
offset = draw_wrap_text(word_wrap_text,2,6,3,h)
%code%



word_wrap_text = ""%a%
This is an example of how we can do word wrap text on the page. Alpha Five gives
you fantastic control over every aspect of how you output text to the printer.
%a%



ui_modeless_dlg_box("Bitmap Tester",""%dlg%
{startup=init}
{can_exit=exit}

{region}
Type commands here and then view the resulting bitmap;
[%L%.80,28code!code_changed];
{endregion}
|
{region}
{embedded=120,30:bitmap}
{endregion}



%dlg%,""%code%
if a_dlg_button = "code_changed" then
clear_bitmap(local_variables())
on error goto bad_code
ui_bitmap_draw("test",code)
on error goto 0
'show_embedded(local_variables())
ui_dlg_refresh("bitmap")
end if
if a_dlg_button = "init" then
show_embedded(local_variables())
clear_bitmap(local_variables())
on error goto bad_code
ui_bitmap_draw("test",code)
on error goto 0
'show_embedded(local_variables())
ui_dlg_refresh("bitmap")

end if
if a_dlg_button = "exit" then
ui_modeless_dlg_close("Bitmap Tester")
end if

end
bad_code:
resume next



%code%)

function show_embedded as v (vars as p)
with vars
ui_modeless_dlg_box("bitmap",""%dlg%
{image=test};
%dlg%,""%code%
1=1
%code%)

end

end with
end function



function clear_bitmap as c (vars as p)
with vars
ui_bitmap_draw("test",""%code%
set_brush("white")
inner_rect(0,0,5,5)
%code%)
end with
end function

[Selwyn Rabins]

RE: Selwyn's Xbasic Printing example

after you have the above script running, try pasting this into the code area:

set_origin(0,0)
set_pen("win3d","",.1)

spacing = .25
for i = 1 to 10
y = i * spacing
line(0,y,5,y)
next i

[Jim Chapman]

RE: Selwyn's Xbasic Printing example

Thanks Selwyn!

It is playtime for me!

Thanks,
Jim