Xbasic Script Tidy-up

[Graham Wickens]

I thought it would be a good idea to have a clear out of some of the redundant scripts and functions from my data dictionary.

I have got them into a table and can display the list in an Xdialog Box. Is it possible to tell Xbasic to delete any of the selected scripts/functions from this dialog box as I cant find any obvious method in the help file??

sys_obj_filename = "c:\my databases\aviation\txt\enumeration.txt"
IF file.exists(sys_obj_filename) THEN
	file.remove(sys_obj_filename)
END IF
sys_obj_list = <<%str%
Copy
Export
Join
Update
append
import
library
mark
menu
post
query
report
script
udf
%str%
FOR each tag in sys_obj_list
	statusbar.set_text("processing "+tag)
	tag = alltrim(tag)
	evaluate_template(evaluate_string("{tag}_list = :a5.{tag}_enum(8)"))
	evaluate_template(evaluate_string("save_to_file({tag}_list+crlf(),\"{sys_obj_filename}\",.t.)"))
next
t = table.open("enum_sys_obj",FILE_RW_EXCLUSIVE)
t.zap(.t.)
t.close()
t = table.open("enum_sys_obj")
t.Import_Ascii_Table(sys_obj_filename,0,.t.)
DIM SHARED varC_sys_obj as C
DIM SHARED varC_result as C
auto_list_varC_sys_obj = table.external_record_content_get("enum_sys_obj","Object_Name","","")
temp_count = w_count(auto_list_varC_sys_obj,crlf())
DELETE a_varC_sys_obj
DIM a_varC_sys_obj[temp_count] as c
a_varC_sys_obj.initialize(auto_list_varC_sys_obj)
heading_string = "Select Scripts to Delete"
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Script Maintenance",<<%dlg%
{region}
{text=113,1:heading_string};
{endregion};
{region}
| [%E%.98,25varC_sys_obj^#a_varC_sys_obj];
{endregion};
{line=1,0};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%)
if varC_result = "ok" then
	'
	'delete selected scripts from dictionary file *.ddd
	'
        '
end if

[Al Buchholz]

Re: Xbasic Script Tidy-up

http://alphafivewiki.com/Dictionary+...ns+and+Methods

[Graham Wickens]

Re: Xbasic Script Tidy-up

thanks Al,

I tried the examples in the Alphapedia, but I get as far as tbl = dictionay.open() and get error message Not Supported.

Also, where can I find a list of all the different item names in the dictionary? (so far I have "FRMI", "QBES", "TLBR" and "Menu")

[Al Buchholz]

Re: Xbasic Script Tidy-up

Personally, I would export all of the scripts/functions, build a new database, add the tables/sets, import the functions and scripts that you want.

[Al Buchholz]

Re: Xbasic Script Tidy-up

thanks Al,

I tried the examples in the Alphapedia, but I get as far as tbl = dictionay.open() and get error message Not Supported.

Also, where can I find a list of all the different item names in the dictionary? (so far I have "FRMI", "QBES", "TLBR" and "Menu")

1. You got the error because a table needs to be open first - ie command is run from a form...
The instructions mention that...

2. I haven't seen a list of those. If you find one let me know....

[aschone]

Re: Xbasic Script Tidy-up

Finian Lennon generated this list.

FRMI	FORM
BRW0	BROWSE
APND	APPEND
REP0	REPORT
SCRP	SCRIPT
DRUL	RULE EVENTS
UPDT	UPDATE
MARK	MARK
COPY	COPY
QBES	QUERY
RLTN	JOIN
POST	POST
EXPT	EXPORT
GPAL	GLOBAL COLORS
MENU	MENU
TLBR	TOOLBAR
GUDF	UDF
GBMP	TOOLBAR BITMAPS
LBLI	LABEL
SMZS	SUMMARY
RANG	RANGE
IMPT	IMPORT
XTBS	XTAB
FRUL	FIELD RULE
SAVU	SAVED SETTINGS

[aschone]

Re: Xbasic Script Tidy-up

First I export only the scripts I want to have to a text file.
Next I run the below code to delete all scripts in the database.
Last I import the scripts I exported in the first step back into the database.

I use this code to wipe out all scripts/udf's a database. Test, Test, Test before you use this.
I forgot to mention that you should test this first before using it in a live database.

FUNCTION pf_Delete_Scripts_UDFs as L ()

	pf_Delete_Scripts_UDFs = .f.
	DIM vDbC as C
	vDbC = a5.get_path() + chr(92) + file.filename_parse(a5.get_name(),"N")
	
	' Make and add new table to db
	'ui_msg_box("pf_Delete_Scripts_UDFs()",vDbC + ".alb" + crlf() + file.exists(vDbC + ".alb") )
	file.copy(vDbC + ".alb", vDbC + "_code.dbf")
	file.copy(vDbC + ".alm", vDbC + "_code.fpt")
	file.copy(vDbC + ".alx", vDbC + "_code.cdx")
	file_add_to_db(vDbC + "_code.dbf")

	' Remove scrips and UDFs
	DIM vCodeP as P
	DIM vFilterC
	vCodeP = table.open(vDbC + "_code")
	vFilterC = "type = 'scrp' .or. type = 'gudf'"
	vCodeP.delete_range(vFilterC)
	vCodeP.pack()
	vCodeP.close()

	' Replace al* files with new dictionary
	file.copy(vDbC + "_code.dbf", vDbC + ".alb")
	file.copy(vDbC + "_code.fpt", vDbC + ".alm")
	file.copy(vDbC + "_code.cdx", vDbC + ".alx")

	' Erase temp table
	table_remove( table.actual_filename_get( vDbC + "_code" ) )
	file_drop_from_db( table.actual_filename_get( vDbC + "_code" ) )
	
	pf_Delete_Scripts_UDFs = .t.
	
END FUNCTION

[Graham Wickens]

Re: Xbasic Script Tidy-up

Thanks Finian and Andrew,

I am indeed using a TEST database.

[MoGrace]

Re: Xbasic Script Tidy-up

Andrew,
That is a very handy script I wish I had a few weeks ago! I wanted to share the same scripts and functions with several applications and so I made several databases to split up the scripts, functions and bitmaps into separate libraries, leaving only the menus and toolbars specific to the individual database apps. I put these files in a subdirectory of the A5 program files and then attached them as libraries. I can still tweak the scripts in each app or add new ones now and have the change available to all of them. Had I thought to export them all first into a text file would have made the job much easier as well.

[MoGrace]

Re: Xbasic Script Tidy-up

Question: Can all these TYPE codes be used to generate lists in the same way your script does? The SAVU is interesting here if it can somehow be exported and imported from one app to another.

Edit: Found the answer here for A5_LOAD_SETTINGS()

[aschone]

Re: Xbasic Script Tidy-up

Finian Lennon's Copy Object Utilities has the capability to transfer Saved Settings (SAVU type); I have never tested this.

http://msgboard.alphasoftware.com/al...ject-Utilities

I think you can generate lists based on the TYPE codes, but you would first have to convert the Data Dictionary to a table by changing the extensions. *Then you could open the table and see whats inside.

I have a junk database that I run this function from. The function will prompt the name of a table or set. Then data dictionaries will be copied to the junk database, added as a normal table and then the default browse will open showing the actual records. I found this helpful when I was trying to correct set definitions where the parent table name was changed.

'Date Created: 14-Mar-2011 04:09:43 PM
'Last Updated: 01-Dec-2011 10:18:34 AM
'Created By  : andy
'Updated By  : andy
FUNCTION f_BrwsDataDict AS C ( )
	
	OPTION STRICT
	OPTION ENCRYPTED_TOKENS
	ON ERROR GOTO ERR_HANDLER
	
	DIM vFilenameC as C
	DIM vTitleC as C
	DIM vTypeC as C
	DIM vDefaultC as C
	DIM vExistC as C
	vTitleC = "Data dictionary"
	vTypeC = "Table(*.dbf)|Set(*.set)"
	vDefaultC = "" 'a5.Get_Path()
	vExistC = "X"
	
	vFilenameC = ui_get_file(vTitleC, vTypeC, vDefaultC, vExistC)
	IF vFilenameC = "" THEN
		END
	ELSE
		'ui_msg_box("",vFilenameC)
	END IF
	
	DIM vDbfP as P
	DIM vDbfP.Orig as C
	DIM vDbfP.New as C
	
	DIM vFptP as P
	DIM vFptP.Orig as C
	DIM vFptP.New as C
	
	DIM vCdxP as P
	DIM vCdxP.Orig as C
	DIM vCdxP.New as C
	
	DIM vPathC as C
	DIM vBasenameC as C
	DIM vExtensionC as C
	vPathC = file.filename_parse(vFilenameC,"DP")
	vBasenameC = file.filename_parse(vFilenameC,"N")
	vExtensionC = file.filename_parse(vFilenameC,"E")
	
	'.ddd = .dbf
	'.ddm = .fpt
	'.ddx = .cdx
	
	'.set = .dbf
	'.sem = .fpt
	'.sex = .cdx

	SELECT
		CASE vExtensionC = ".DBF"
			vDbfP.Orig = vPathC + vBasenameC + ".ddd"
			vFptP.Orig = vPathC + vBasenameC + ".ddm"
			vCdxP.Orig = vPathC + vBasenameC + ".ddx"
		CASE vExtensionC = ".SET"
			vDbfP.Orig = vPathC + vBasenameC + ".set"
			vFptP.Orig = vPathC + vBasenameC + ".sem"
			vCdxP.Orig = vPathC + vBasenameC + ".sex"
		CASE ELSE
			ui_msg_box("Error", "Unknown Extension" + crlf() + vExtensionC, UI_STOP_SYMBOL)
			END
	END SELECT

	vDbfP.New = a5.get_path() + chr(92) + vBasenameC + "_Temp.dbf"
	vFptP.New = a5.get_path() + chr(92) + vBasenameC + "_Temp.fpt"
	vCdxP.New = a5.get_path() + chr(92) + vBasenameC + "_Temp.cdx"

	'f_BrwsDataDict = vDbfP.Orig + crlf() + vDbfP.New + crlf() + vFptP.Orig + crlf() + vFptP.New + crlf() + vCdxP.Orig + crlf() + vCdxP.New
	
	file.copy(vDbfP.Orig,vDbfP.New)
	file.copy(vFptP.Orig,vFptP.New)
	file.copy(vCdxP.Orig,vCdxP.New)
	
	file_add_to_db(vDbfP.New)
	
	a5_open_default_browse(vDbfP.New)
	
	END
'-----------------------------------
'Error handler
'-----------------------------------
ERR_HANDLER:
	Dim err as N= error_code_get()
	Dim msg as C= "Error # "+ err + crlf() + error_text_get(err)
	msg = msg + crlf() + "Script: " + error_script_get()
	msg = msg + crlf() + "Line #: " + error_line_number_get()

	trace.writeln(msg)

	ui_msg_box("Error", msg, ui_attention_symbol)
	msg = ""
	
	END  
	
	
END FUNCTION

[MoGrace]

Re: Xbasic Script Tidy-up

Interesting data, but I was looking more for a way to copy the Database preference settings.

[Stan Mathews]

Re: Xbasic Script Tidy-up

I think the preferences are kept in the system registry.