How do I place a Dynamic image in an xDialog list

[Ronald Anusiewicz]

I'm working with a list in an xDialog.

I want to display one of 2 images in a list. I have a logical field that is either true or false.

If the field is false, I would like to have the image: Image_Not_Posted = "{I:'A5_ball_white'}".
If the field is true, I would like to have the image: Image_Posted = "{I:'A5_ball_green'}".

The list is built from the following code:

auto_list_vcCA = table.external_record_content_get("wodesclabor_m_ca",\
" 'Item: ' + Itemno + ' ' + if(Posted=.F.,' ','*') + left(Descrep,100) + space(60) + '&' + transno + swkno + '&&' ",\
"padl(alltrim(Itemno),4,\"0\")",\
"Transno="+s_quote(vcHeadTransno))

The controlling field is: if(Posted=.F.,' ','*')

I want something that would give me this: if(Posted=.F.,image_not_posted,image_posted)

the code for the list is:

{region}
{font=calibri,11}
Corrective Actions - Double Click on Item to Edit, an * Denotes Entries Posted to the Work Order:;
{font=fixdsys regular,10}
[.110,10vcCA^#auto_list_vcCA!Edit_*];
{endregion};;

I've been looking at the Help and either I can do this and I'm just not understanding the help examples or I can't do what I want.

Thanks,

[MoGrace]

Re: How do I place a Dynamic image in an xDialog list

Hi Ron,
Have you considered creating the xdialog from a browse? If you add buttons or images into the browse column, the XML will convert it.

In this example the button image changes (and corresponding action) based on whether a field is blank or not.

brwsrch.jpg

[Mike Wilson]

Re: How do I place a Dynamic image in an xDialog list

Ron,
Get the data, loop through and identify what image is needed, and build the list string. I attached an example. Hope it helps.

dim postlist[100] as C
dim vwhich_img as C
dim list as C=""
dim filelist[100] as C
data = <<%a%
value1^^f
value2^^t
value3^^f
%a%

for each foo in data
	if word(foo,2,"^^")="f"
		vwhich_img=".1"
	else
		vwhich_img=".2"
	end if
	list=list+word(foo,1,"^^")+vwhich_img+crlf()
next

postlist.initialize(list)
postlist.sort()
result = ui_dlg_box("Select Table/Set",<<%dlg%
{region}
[%I=A5_ball_white,A5_ball_green;O={I=@$(.)+1} {@1,$(.)-1}%.25,10posted^#postlist!evk_*]
{endregion};
<10OK> <10Cancel>
%dlg%,<<%code%
if left(a_dlg_button,4)="evk_"
	if a_dlg_button="evk_change"
		msgbox(posted)
	end if
a_dlg_button=""
end if
%code%)

[johnkoh]

Re: How do I place a Dynamic image in an xDialog list

Ron

I have this for your question,

I want something that would give me this: if(Posted=.F.,image_not_posted,image_posted)

'set the image before get the list.
image1 = "{I:'$$generic.checked.on'}"
image2 = "{I:'$$generic.checked.off'}"
vTempList = table.external_record_content_get("mytable",\
"Myfield1+'{T=3.0}'+"\
"If(limited=.t.,"+quote(var->image1)+","+quote(var->image2)+")+'{T=3.5}'+"\
"If(IsDrop=.t.,"+quote(var->image1)+","+quote(var->image2)+")"," ",query.filter)

The key is, apply this "+quote(var->image1)+"
It is simple but I spent a lots time to figure it out. I used the O={@@} owner_draw directive on my listbox and have not try the other directive yet.

[Ronald Anusiewicz]

Re: How do I place a Dynamic image in an xDialog list

Thank you all very much.

Robin, your example is a beautiful piece of work.

In my situation, I have 3 lists on a single xDialog with each list filtered on the first list. I have never done what you suggested and I didn't want to go that route at this time.

Mike, great suggestion and thanks so much for you help. I was able to get your code to work but I was running into an odd situation where if my text had a period in it, the description of work would be truncated.

While trying to resolve that problem, John came up with his suggestion. His was the easiest to implement and it works perfectly.

{region}
{font=calibri,11}
Corrective Actions - Double Click on Item to Edit, an * Denotes Entries Posted to the Work Order:;
{font=fixdsys regular,10}
[%O={@@}%.110,10vcCA^#auto_list_vcCA!Edit_*]
{endregion};;

ELSEif a_dlg_button = "newhead" THEN
	vcHeadTransno=extract_string(vcHead,"$","$$")
	auto_list_vcSwk = table.external_record_content_get("wosquawk",\
	"\"Item: \"+Itemno+\" \"+left(Descrep,100)+space(60)+\"&\"+swkno+\"&&\"","padl(alltrim(Itemno),4,\"0\")",\
	"Transno="+s_quote(vcHeadTransno))
	vcSwkNo=extract_string(vcSwk,"&","&&")
	auto_list_vcCA=CA_List(vcHeadTransno)
	a_dlg_button = ""



FUNCTION CA_List as C ( vTrans as C )
	image1 = "{I:'A5_ball_green'}"
	image2 = "{I:'A5_ball_white'}"
	
	auto_list_vcCA = table.external_record_content_get("wodesclabor_m_ca",\
	"If(Posted=.t.,"+quote(var->image1)+","+quote(var->image2)+")+'  Item: ' + Itemno + ' ' + left(Descrep,100) + space(60) + '&' + transno + swkno + '&&' ",\
	"padl(alltrim(Itemno),4,\"0\")",\
	"Transno="+s_quote(vTrans))
	
	ca_list=auto_list_vcCA
END FUNCTION

This code is used in a number of places, so I made it into a function to simplify my code.

Thanks again everyone.

[johnkoh]

Re: How do I place a Dynamic image in an xDialog list

Share something in this A5 community