Xdialog Highlight non focused listbox selections

[Pete119j]

Hi,

Is it possible to keep the selected items highlighted in a list box when it looses focus?

Capture.JPG

dim people as c
people = <<%str%
{data=Joe Smith}Joe|Smith
{data=John Smith}John|Smith
{data=John Public}Ann|Jones
%str%
dim person as c = "John Smith"
dim events as c


ui_dlg_box("",<<%dlg%
This dialog shows the events fired by a simple ListView;
{lf};
[20field1];
[%M;K%.100,10person^"Firstname|Lastname"people];
[20field2];

%dlg%)

I'm creating a Xdialog with several list views and a tree view and it's hard for the users to see what items they have selected when going to the next control!

Capture2.JPG

Thanks in advance for any help

Pete

[Stan Mathews]

Re: Xdialog Highlight non focused listbox selections

I don't do much with xdialog but I don't see keeping the highlight of an unfocused control as an option.

Can you add a variable, store the choices made to it (concatenating) and display that in the lower right corner?

Or display the variables themselves?

Mode_n = 1
Mode_c = "Exclusive"
choices = <<%a%
Shared
Read only
Exclusive
%a%

result=ui_dlg_box("Title",<<%dlg%
Filename:| [.32filename];
Open as:;
Mode:| [.10,5mode_n^#choices];
Mode:| [.10,5mode_c^#choices];
<OK>;
Numeric Mode:|[.10mode_n];
Character Mode:|[.10mode_c]
%dlg% )

[Pete119j]

Re: Xdialog Highlight non focused listbox selections

Hi Stan,

Thanks for your reply.

Adding variables may be my best option!

My other thought was, are there any options anywhere to globally change the unfocused colour? is this set by alpha5 or the windows operating system?

Pete

[Al Buchholz]

Re: Xdialog Highlight non focused listbox selections

Check box list?

[Ronald Anusiewicz]

Re: Xdialog Highlight non focused listbox selections

You should be able to do what you want.

MultipleSelects.JPG

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vcHead as C = ""
dim shared vcHeadTransno as C
DIM GLOBAL vcSwk as C
DIM SHARED vcSwkNo as C
DIM GLOBAL vcCA as C
DIM SHARED vcCATno as C
DIM SHARED vcCASwkNo as C = ""
DIM SHARED varC_result as C

''see if logged in user is a tech or inspector
dim shared Inspector as L = .F.
permis = lookup("wodesclabor_m_entry_mech1", "Initials="+s_quote(var->vc_user),"mechlevel")
if permis = "I" then
	inspector = .T.
end if

auto_list_vcHead = table.external_record_content_get("wo_hdr",\
"alltrim(Billingname)+\"|\"+N_Number+\"|\"+alltrim(Make)+\" \"+alltrim(Model)+\"|\"+Wo_No+\"|\"+space(5)+\"$\"+transno+\"$$\" ",\
"invert(Wo_no)",\
"alltrim(n_number)<>\"\" .and. (Paid=\"N\" .or. (Paid=\"I\" .and. alltrim(remspecial(dtoc(date_closed))) = \"\" ) ) .and. Site =" + s_quote(var->vc_user_site) )

Dim format as p
Format.tab_stops="2.5,3.5,5.5,7"
Format.odd_row_color="White"
Format.even_row_color="White"
Format.odd_selected_color="Dark Blue"
Format.even_selected_color="Dark Blue"
Format.font="calibri,11"
Format.font_color_unselected="Black"
Format.font_color_selected="White"
Format.lastbutton="OK"
Format.group_size=1
Format.number_rows=.f.
Format.alternating_bands=.f.

'Apply 'owner draw' formatting information to the list
auto_list_vcHead = a5_owner_draw_list_fmt(auto_list_vcHead,Format)

temp_count = w_count(auto_list_vcHead,crlf())
DELETE a_vcHead
DIM a_vcHead[temp_count] as c
a_vcHead.initialize(auto_list_vcHead)

auto_list_vcSwk=""
auto_list_vcCA=""

ok_button_label = "&Save"
cancel_button_label = "&Close"
vTitle = "Enter/Change Corrective Actions"
varC_result = ui_modeless_dlg_box(vTitle,<<%dlg%
{units=F}{font=calibri,11}{ysize=.3}{xmargin=4,4}
{can_exit=close}
{position=remember=vTitle}

{region}
Open Work Orders:;
[%d;O={@@}%.82,6vcHead^#a_vcHead!NewHead];
{endregion};;

{region}
Work Order Discrepancies:  <%T=Add a New Discrepancy to this Work Order;B=T;I=$$code.library.add%!NewSqwK?inspector = .T.>
 <%T=Print a New Discrepancy Sheet;B=T;I=$$print%!PrintSqwK?inspector = .T.>;
{font=fixdsys regular,10}
[.110,10vcSwk^#auto_list_vcSwk!SelectSwk_*];
{endregion};;

{region}
{font=calibri,11}
Corrective Actions - Double Click on Item to Edit.
Checked Item Requires Inspection.  Glasses Item is Signed Off.  Green Ball Item Sent to Work Order:;
{font=fixdsys regular,10}
[%O={@@}%.110,10vcCA^#auto_list_vcCA!Edit_*]
{endregion};;

{region}
{font=calibri,11}
{comment=<*15=ok_button_label!OK>}
{justify=center,center}
<Refresh!refresh_view>  <View Report!view_report>
{endregion};
%dlg%,<<%code%

[johnkoh]

Re: Xdialog Highlight non focused listbox selections

Ron,

What is your trick? I could not find that.

[Ronald Anusiewicz]

Re: Xdialog Highlight non focused listbox selections

If you want to call it a trick, I used sys_send_keys. When the choice is changed in the first list, the send_keys command activates each other list which activates the first record in the other lists. Other than that, I can't remember doing anything special to keep the active record in the list highlighted.

%dlg%,<<%code%

IF a_dlg_button = "close" THEN		'Close
	ui_modeless_dlg_close(vTitle)
	end
	
ELSEif a_dlg_button = "newhead" THEN
	vcHeadTransno=extract_string(vcHead,"$","$$")
	auto_list_vcSwk = table.external_record_content_get("wosquawk",\
	"\"Item: \"+Itemno+\" \"+left(Descrep,100)+space(60)+\"&\"+swkno+\"&&\"","Itemnorpt",\
	"Transno="+s_quote(vcHeadTransno))
	vcSwkNo=extract_string(vcSwk,"&","&&")
	auto_list_vcCA=CA_List(vcHeadTransno)
	xbasic_wait_for_idle()
	sys_send_keys("{tab}{Home}{tab}{Home}")
	a_dlg_button = ""

ELSEif a_dlg_button = "SelectSwk_dblclick" THEN
	vcSwkNo=extract_string(vcSwk,"&","&&")
	NewEntry(vcHeadTransno, vcSwkNo, var->vc_user_site)
	auto_list_vcCA=CA_List(vcHeadTransno)
	a_dlg_button = ""

ELSEif a_dlg_button = "NewSqwK" THEN
	script_play_local("WONewDesc")
	vcHeadTransno=extract_string(vcHead,"$","$$")
	auto_list_vcSwk = table.external_record_content_get("wosquawk",\
	"\"Item: \"+Itemno+\" \"+left(Descrep,100)+space(60)+\"&\"+swkno+\"&&\"","Itemnorpt",\
	"Transno="+s_quote(vcHeadTransno))
	a_dlg_button = ""
		
ELSEif a_dlg_button = "Edit_dblclick" THEN
	vcCAKey = extract_string(vcCA,"&","&&")
	if ChgEntry( vcCAKey, var->vc_user_site) = .T. then
		auto_list_vcCA=CA_List(vcHeadTransno)
	end if
	a_dlg_button = ""
	
ELSEif a_dlg_button = "view_report" THEN
	if alltrim(vcHeadTransno) = "" then
		msgbox("Oops","Please Select an Open Work Order",UI_ATTENTION_SYMBOL+UI_OK)
	else
		query.filter = "transno = " + s_quote(vcHeadTransno)
		query.order = "transno"
		query.filter = convert_expression(query.filter,"VE")
		:Report.Preview("CA",query.filter,query.order)
	end if
	
	a_dlg_button = ""

ELSEif a_dlg_button = "PrintSqwK" THEN
	if alltrim(vcHeadTransno) = "" then
		msgbox("Oops","Please Select an Open Work Order",UI_ATTENTION_SYMBOL+UI_OK)
	else
		script_play_local("WOPrintThisDesc")
	end if
	
	a_dlg_button = ""
	
ELSEif a_dlg_button = "Refresh_View" THEN
	auto_list_vcCA=CA_List(vcHeadTransno)
	
	a_dlg_button = ""
	
END IF

%code%)

[johnkoh]

Re: Xdialog Highlight non focused listbox selections

Ron,

Thank you for sharing.

[Pete119j]

Re: Xdialog Highlight non focused listbox selections

Thanks everyone, Have some good examples to try!

For now I've gone with Stan's method of displaying all the variables at the bottom of the dialog

I shall look at Ron's example later when I have some more time