Specify Printer- Same label differt PCs and printers

[Reyesii]

Hello:

I have labels and reports that need to use a specific printer. The issue is that each computer has a different printer model and port number. The application works great on one computer but is unable to print, on other computers, because the printer name and port number are different then the one specified on the report or label.

I am thinking that the best way is to name all the local printers the same and to insure that all the USB Label printer are on the same Port number.

[MoGrace]

Re: Specify Printer- Same label differt PCs and printers

You can have the same printer listed with more than one name in the PC control panel/printers & faxes, so naming different printers the same should work. That way if you need different settings for each printer to work in Alpha you can configure the different drivers and yet everybody will be using the 'same' printer. Let us know how that turns out.

[Ronald Anusiewicz]

Re: Specify Printer- Same label differt PCs and printers

I wrote the following script that allows the choosing of a specific printer for a report and a specific printer for labels. When needed, this is used to override the default printer.
These setting are written to the computer's registry so the settings are for that one computer only. This does not corupt the settings on other computers.

In the autoexec script, you will need to add these lines:

dim global vcReport_Printer as C
dim global vcLabel_Printer as C

dim retrieve_settings as P
a5_load_settings("Printer", retrieve_settings)
vcLabel_Printer = retrieve_settings.Label
vcReport_Printer = retrieve_settings.Report

This is the script that is run to pick a specific printer for reports and a specific printer for labels and stores those choices in the registry.

'Date Created: 11-Aug-2012 09:19:59 AM
'Last Updated: 11-Aug-2012 09:28:04 AM
'Created By  : Ron
'Updated By  : Ron
'
'ui_msg_box("Report Printer",vcReport_Printer)
'ui_msg_box("Label Printer",vcLabel_Printer)

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vcList as C = vcLabel_Printer
DIM SHARED vcList2 as C = vcReport_Printer
DIM SHARED varC_result as C
auto_list_vcList = ui_printers_get()
auto_list_vcList2 = ui_printers_get()

temp_count = w_count(auto_list_vcList,crlf())
DELETE a_vcList
DIM a_vcList[temp_count] as c
a_vcList.initialize(auto_list_vcList)

temp_count = w_count(auto_list_vcList2,crlf())
DELETE a_vcList2
DIM a_vcList2[temp_count] as c
a_vcList2.initialize(auto_list_vcList2)

ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Select Application Printers",<<%dlg%
{xmargin=2,2}
{font=arial,10}
{ysize=.3};
{region}
{font=arial,10,b}
Select the Label Printer:;;
{font=arial,10}
 [%d%.80,10vcList^#a_vcList];
{endregion};

{region}
{font=arial,10,b}
Select the Report Printer:;;
{font=arial,10}
 [%d%.80,10vcList2^#a_vcList2];
{endregion};;
{region}
<15,1.5=ok_button_label!OK> <*15,1.5=cancel_button_label!CANCEL>
{endregion};
%dlg%)

if varC_result <> "OK" then
	end
end if

vcReport_Printer = vcList2
vcLabel_Printer = vcList

'ui_msg_box("Report Printer",vcReport_Printer)
'ui_msg_box("Label Printer",vcLabel_Printer)

dim Printersettings as P
dim Printersettings.Report as C
dim Printersettings.Label as C

Printersettings.Label = vcList
Printersettings.Report = vcList2

a5_save_settings("Printer", printersettings)

Last, in the code you use to print, in this case we are printing labels, you need to add the line:

:report.Printer_override(vcLabel_Printer)
:Label.Print("MyLabel",query.filter,query.order)

[Mike Wilson]

Re: Specify Printer- Same label differt PCs and printers

I was hopeful this would answer my question of how to determine what the current default printer is, but no joy. Ron, I get an error with your script. How is it this works for you?

[Stan Mathews]

Re: Specify Printer- Same label differt PCs and printers

I imagine you need to create those settings with the provided script for them to be able to be read later.

[Ronald Anusiewicz]

Re: Specify Printer- Same label differt PCs and printers

Mike, check out this: https://www.alphasoftware.com/docume...20Function.xml