roll down xdialog using code outside xdialog code

[Mike Wilson]

I have the following dialog that is a rollup-roll-down modeless xdialog to collect NOTES called from a primary modeless xdialog, REVIEW, that presents users with image files and has functionality to rename the image files. Notes are entered into the NOTES roll-up-roll-down dialog asynchronously during the review of many images in the priimary REVIEW dialog. At the completion of the review, the user presses a button on the REVIEW dialog which calls a script that completes the review process. What I need is for the script that completes the review process to roll-down the NOTES dialog at a particular moment in the script sequence. How do I roll down the Notes dialog when rolled up from the script that completes the review process?

'DAILOG VALUES AND VARIABLES
	DIM dlg_nbody as C
	DIM dlg_ncode as C
	DIM dlg_ntitle as C="INSTALLATION NOTES"

	DIM rup_body as C
	DIM rup_code as C
	DIM ruptitle as c 
	DIM vFilter as C
	
	'DLG BODY MAIN
	dlg_nbody = <<%dlg%
{background=#215+223+253}{position=remember=XD_cp_fit_Down}{xmargin=1,1}{ymargin=1,0}
{comment=TOP BUTTONS}
	{region}
	{justify=right}<%T=Roll up;B=T;I=$$generic.exit%4,1!exit>  <%T=Roll up;B=T;I=$$generic.roll.up%4,1!B_rollup> {text=2}
	{endregion};{lf=.5};
{comment=REMAINDER OF DIALOG}
	{region}
	{font=arial,9,b}[%mw%.90,18vcs_inotes]
	{lf};
	{endregion};
	%dlg%
	dlg_ncode = <<%code%
'CLOSE
	IF a_dlg_button = "EXIT"
		ui_modeless_dlg_close(dlg_ntitle)
	END IF
	
'NOTES ROLLUP
	IF a_dlg_button = "B_Rollup"
		ui_modeless_dlg_box(dlg_ntitle,rup_body,rup_code)
	END IF
	%code%
	
'ROLL UP BODY	
	rup_body = <<%dlg%
	{removecomments}{background=#215+223+253}{can_exit=close}
	{position=remember=XD_cp_fit_Up}
	{title=Notes}{xmargin=3,3}{xmargin=2,2}{font=Arial,8}{justify=center}
	<%T=Roll Down;B=T;I=$$generic.roll.down%4,1!Rolldown> ;
	%dlg%
		
'ROLLUP CODE
	rup_code = <<%code%
	IF a_dlg_button = "Rolldown"
		ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)
	END IF
	%code%

'GENERATE THE DIALOG
	ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)

[Stan Mathews]

Re: roll down xdialog using code outside xdialog code

Make all your variables global and then to roll down externally,

ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)

[Mike Wilson]

Re: roll down xdialog using code outside xdialog code

Thanks Stan! It worked dimming them shared.

[MoGrace]

Re: roll down xdialog using code outside xdialog code

You could also try

ui_dlg_event(dlg_ntitle,"rolldown")

[Mike Wilson]

Re: roll down xdialog using code outside xdialog code

I am trying to preview a report from a button in a modeless dialog. The problem is that the report preview falls behind the dialog and viewing is impaired. I thought I could use a roll up event to move the dialog out of the way, which works great, however bringing back the dialog when the report preview is closed I can't get to happen. The code below does not have a report preview but to emulate previewing a report I have the opening of a second modal dialog. What I'm trying to have happen is when modal dialog closes, the modeless dialog rolls down. I have tried many different combinations and cannot get this to happen. Is it possible? Thanks.

FUNCTION _aatesting2 AS C ( )

'DAILOG VALUES AND VARIABLES
	DIM shared dlg_nbody as C
	DIM shared dlg_ncode as C
	DIM shared dlg_ntitle as C="INSTALLATION NOTES"

	DIM shared rup_body as C
	DIM shared rup_code as C
	DIM shared rup_title as c 
	
	'DLG BODY MAIN
	dlg_nbody = <<%dlg%
{background=#215+223+253}{position=remember=XD_cp_fit_Down}{xmargin=1,1}{ymargin=1,0}
{comment=TOP BUTTONS}
	{region}
	{justify=right}<Call subUDF>  <%T=Roll up;B=T;I=$$generic.exit%4,1!exit>  <%T=Roll up;B=T;I=$$generic.roll.up%4,1!B_rollup> {text=2}
	{endregion};{lf=.5};
{comment=REMAINDER OF DIALOG}
	{region}
	{font=arial,9,b}[%mw%.90,18vcs_inotes]
	{lf};
	{endregion};
	%dlg%
	dlg_ncode = <<%code%
'CLOSE
	IF a_dlg_button = "EXIT"
		ui_modeless_dlg_close(dlg_ntitle)
	END IF
	
'NOTES ROLLUP
	IF a_dlg_button = "B_Rollup"
		ui_modeless_dlg_box(dlg_ntitle,rup_body,rup_code)
	END IF
	
'CALL
	IF a_dlg_button="Call subUDF"
		test_internal_rolldown()
		ui_dlg_event(dlg_ntitle,"rolldown") 
		ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)
	END IF

%code%
	
'ROLL UP BODY	
	rup_body = <<%dlg%
	{removecomments}{background=#215+223+253}{can_exit=close}
	{position=remember=XD_cp_fit_Up}
	{title=Notes}{xmargin=3,3}{xmargin=2,2}{font=Arial,8}{justify=center}
	<%T=Roll Down;B=T;I=$$generic.roll.down%4,1!Rolldown> ;
	%dlg%
		
'ROLLUP CODE
	rup_code = <<%code%
	IF a_dlg_button = "Rolldown"
		ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)
	END IF
	%code%

'GENERATE THE DIALOG
	ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)

END FUNCTION
_aatesting2()

'OOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOO

FUNCTION test_internal_rolldown as C ( )
	ui_modeless_dlg_box(dlg_ntitle,rup_body,rup_code)
	
	ui_dlg_box("INSIDE ROLLDOWN",<<%dlg%
	{lf};{font=arial,10,b}This is a test of the internal rolldown to see;if internal code can roll down the dialog ;;;;;;;;;;;
	{sp=21}<Close>
	%dlg%,<<%code%
	if a_dlg_button="close"
		ui_dlg_event(dlg_ntitle,"rolldown") 
		'ui_modeless_dlg_box(dlg_ntitle,dlg_nbody,dlg_ncode)
	end if
	%code%)
	
END FUNCTION

[MoGrace]

Re: roll down xdialog using code outside xdialog code

I have a docked toolbox panel (modeless dialog) that calls my report preview from a button. The vFltr var is set using the report genie and I have a watch for it, then I parse it into a global var that my report uses. Notice the flag settings in the report.preview() function that sets both the modal and session_modal flags to .f. This allows you to click on the preview when the other modeless dialog is open. Repname and Repfilter are both global vars.

if a_dlg_button = "B_PREV" then	
'	set the global var so report doesn't prompt for filter
	with global_variables()
		rep_filter = vfltr
	end with	
	:report.preview(repname,vfltr,"",.f.,.f.)
end if

Then I have another button on the panel that will close the preview window:

if a_dlg_button ="B_EXITPREV" then
	openlist = a5_list_open_windows()
	vlist = crlf_to_comma(openlist) 
	windowname = object_name_normalize(repname)
	windowname = "Preview__"+windowname	
	if inlist2(windowname,vlist)
		cmd = windowname+".close()"
		evaluate_template(cmd)
	end if
end if

[Mike Wilson]

Re: roll down xdialog using code outside xdialog code

Thanks Robi! I'll give this a whirl.