syntax problem using eval()

[MoGrace]

I don't know what I am doing wrong here but I am getting an error of "extra characters at end of expression"

This is the line that errs:

vn = eval("thf."+tmp.fldname)

tmp = table.open_session("t_repfin")
thf = table.open_session("hh_fin")

hh_fin is a one record table that has 50 fields with amounts I am trying to map to t_repfin->fldname that has 50 records. So I query hh_fin to set it to the one record I need, then fetch thru t_repfin and set each t_repfin record to the matching field in hh_fin.

here's the section of the script I am working with (Note TLN() is a udf that writes to the trace window)

if xflag then    
    tmp.batch_begin()
    tmp.fetch_first()
    WHILE .not. tmp.fetch_eof()        
        'map each of the hh_fin fields in the one record to create a matching record in t_repfin
        'errs with 'extra chars at end of expression'
       [COLOR=#ff0000] vn = eval("thf."+tmp.fldname)[/COLOR]
        'returned fieldname instead of amount                 
        'vn = thf.eval(quote(tmp.fldname))
        Tln("hh_fin->"+tmp.fldname,vn)
        commit_flag = .t.    
        select
            case blankflag = .t.            
                on error goto ERRMSG3                
                tmp.change_begin()
                    'select all records to display as blank in report                
                    tmp.sel_flag = .t.
                tmp.change_end(commit_flag)
                goto SKIPIT
            case tmp.FLDNAME = ""
                goto SKIPIT
            [COLOR=#0000ff]case eval("thf."+tmp.fldname) > 0[/COLOR] 
            'case thf.eval(quote(tmp.fldname)) > 0            
                on error goto ERRMSG3
                tmp.change_begin()                                                                    
                    [COLOR="#0000FF"]'tmp.amount = eval("thf."+tmp.fldname)
                    tmp.amount = thf.eval(quote(tmp.fldname))[/COLOR]
                    tmp.sel_flag = .t.
                tmp.change_end(commit_flag)    
        end select
            
        SKIPIT:        
        on error goto 0
        'should stop loop on error
        if commit_flag then            
            tmp.fetch_next()    
        else
            EXIT WHILE
        end if    
    END WHILE
    tmp.batch_end()
    
    CLOSETBLS:
    lst1 = crlf_to_comma(tmp.Enum_Session_Open())
    Tln("tmp open list",lst1)
    if inlist2(tmp.name_get(),lst1) then
        tmp.close()
    end if
    lst2 = crlf_to_comma(thf.Enum_Session_Open())
    Tln("thf open list",lst2)
    if inlist2(thf.name_get(),lst2) then
        thf.close()
    end if
    
end if

if commit_flag then
    ui_beep(UI_STANDARD_BEEP)
end if

[Al Buchholz]

Re: syntax problem using eval()

Not sure what is going on.

I do what you are doing, but in 2 steps to make it easier to diagnose.

so

vn = eval("thf."+tmp.fldname)

becomes

text2eval = "thf."+tmp.fldname
vn = eval(text2eval)

Then I can see what the value the eval() is acting on through debug(1) or a msgbox.

or

command2eval = "vn =thf."+tmp.fldname
evaluate_template(command2eval)

Without an example of the your table it's only a guess as to what is happening..

[Stan Mathews]

Re: syntax problem using eval()

I am not seeing how tmp.fldname returns a field name. At least I think that is what is being attempted.

[MoGrace]

Re: syntax problem using eval()

Didn't expect such a quick reply - here's what the test data looks like:

testdata.jpg

[Stan Mathews]

Re: syntax problem using eval()

Ok, I understand more about what you are doing and the theory is sound.

tbl = table.open("dept")
tmp = table.open("a")
? eval("tbl."+tmp.fldname)
= 1
tmp.fetch_next()
? eval("tbl."+tmp.fldname)
= "Grocery

Your test data has a blank value in fldname for S011. That will throw the error you are seeing.

[MoGrace]

Re: syntax problem using eval()

The test for the blank fldname was in a lower part of the script so I moved it to the beginning. In the meantime I used Al's suggestion so I could view the values in the trace window. Here is what it looks like now:

if xflag then
	dim vfldstr as c = ""
	dim vamt as n = 0	
	tmp.batch_begin()
	tmp.fetch_first()
	WHILE .not. tmp.fetch_eof()		
		'map each of the hh_fin fields in the one record to the matching amount field in t_repfin				
		[COLOR="#0000FF"]vfldstr = "thf."+tmp.fldname
		if eval_valid(vfldstr) then
			vamt = eval(vfldstr)		
			Tln(vfldstr,vamt)
			commit_flag = .t.	
		else
			goto SKIPIT
		end if[/COLOR]
		
		select
			case blankflag = .t.			
				on error goto ERRMSG3				
				tmp.change_begin()
					'select all records to display as blank in report				
					tmp.sel_flag = .t.
				tmp.change_end(commit_flag)
				goto SKIPIT
			'case tmp.FLDNAME = ""
				'goto SKIPIT			
			case vamt > 0
				on error goto ERRMSG3
				tmp.change_begin()																						
					tmp.amount = vamt
					tmp.sel_flag = .t.
				tmp.change_end(commit_flag)	
		end select
			
		SKIPIT:		
		on error goto 0
		'should stop loop on error
		if commit_flag then			
			tmp.fetch_next()	
		else
			EXIT WHILE
		end if	
	END WHILE
	tmp.batch_end()
	
	CLOSETBLS:
	lst1 = crlf_to_comma(tmp.Enum_Session_Open())
	Tln("tmp open list",lst1)
	if inlist2(tmp.name_get(),lst1) then
		tmp.close()
	end if
	lst2 = crlf_to_comma(thf.Enum_Session_Open())
	Tln("thf open list",lst2)
	if inlist2(thf.name_get(),lst2) then
		thf.close()
	end if
	
end if

You guys are the best! Thanks

[Stan Mathews]

Re: syntax problem using eval()

And now it works?

[MoGrace]

Re: syntax problem using eval()

Here's what the report section looks like when there are amounts filled in - no zero amounts are displayed.

repsection.jpg

phooey - I see I still have a DOB error to fix... but this part works.

[gkeramidas]

Re: syntax problem using eval()

if i'm understanding what you're trying to do, here's what I use when I have to do what you're doing.

something like this:

dim arr[0] as p
arr.initialize_from_table(tablename, your filter , order)

this would populate the array with the all of fields and their values for the one record you want.

after change_begin, assuming your filter returned the 1 record you were looking for:

tmp.fieldname = arr[1].fieldname (the fieldname from hh_fin)

it's just much easier for me to address, since I know the fieldnames from the other table.

if this isn't what you're trying to accomplish or want more info how I do it, let me know. I use arrays or collections a lot for this type of operation

[MoGrace]

Re: syntax problem using eval()

Hi Gary,
I am not matching field to field, instead I am mapping the hh_fin field to the amount field in t_repfin by matching the t_repfin->fldname to the hh_fin->fieldname (which holds the value I need to get into the t_repfin->amount field). Did you see the screenshot of my data example above in post #4?

[Stan Mathews]

Re: syntax problem using eval()

Robin,

You may have a logic issue but I am still struggling with the flow. Not a big fan of goto <label>.

If the first record has a valid fieldname you commit_flag = .t. and transfer the value to the appropriate field. I don't see where you reset commit_flag to .f. for the next loop. That should probably be done immediately after WHILE .not. tmp.fetch_eof().

[Al Buchholz]

Re: syntax problem using eval()

Robin

Consider adding some logging to this process to indicate what records are read and how they are processed.

If not forever, but at least during some extensive testing. Writing to a text file is fast and easy to monitor while a process is running.

[gkeramidas]

Re: syntax problem using eval()

I created a tmp table with one field, fldname. in it, I entered reason, which is a fieldname in my attend table.

when I ran this code, txt contained "Vacation" which is the value of the reason field in the first record in my attend table. is that what you're trying to achieve here?

dim tmp as p
dim thf as p
dim txt as c
thf =table.open("Attend")
tmp= table.open("tmp")

tmp.fetch_first()
while .not. tmp.fetch_eof()
	txt = eval("thf." + tmp.fldname)
end while
thf.close()
tmp.close()

[MoGrace]

Re: syntax problem using eval()

Robin,

You may have a logic issue but I am still struggling with the flow. Not a big fan of goto <label>.

If the first record has a valid fieldname you commit_flag = .t. and transfer the value to the appropriate field. I don't see where you reset commit_flag to .f. for the next loop. That should probably be done immediately after WHILE .not. tmp.fetch_eof().

The commit_flag is set to false by the error handler, but I can see that it makes more sense to set the flag to .f. before testing with eval_valid(). So far the only error that triggered was because of the one blank fldname.

[MoGrace]

Re: syntax problem using eval()

Robin

Consider adding some logging to this process to indicate what records are read and how they are processed.

If not forever, but at least during some extensive testing. Writing to a text file is fast and easy to monitor while a process is running.

The udf I have TLN() writes to the trace window with the name of the thf fieldname and the value of that field. I will comment that out once testing is done.

I do have another routine that creates an array of the data which I show to the user to confirm, I suppose I could do that here, but this is only for a report and the report preview should accomplish the same. If the data is not right the user can fix it and run the report again before printing. I added a linked field on the report that will take the user back to the input form.