xDialog, Check Box-List Box and events

[Ronald Anusiewicz]

I'm having trouble refreshing a check box-list box using an event trapped between <<%code% 'my refresh code is here %code%).

This is the initial code which generates the list. The list was created using the genie.

auto_list_vPickList = table.external_record_content_get("persons",\
"\"  \"+P_Status+\"|\"+Id+\"|\"+Address+\"|\"+City+\"|\"+recno()",\
"p_status+ID+Address+City",\[COLOR="#0000FF"][/COLOR]
"P_Status="+s_quote(left(var->vFiltered,1)) )

Dim format as p 
Format.tab_stops=".75,2.75,4.75,6.75,8.7"
Format.odd_row_color="White"
Format.even_row_color="White"
Format.odd_selected_color="Dark Blue"
Format.even_selected_color="Dark Blue"
Format.font="Calibri,11"
Format.font_color_unselected="Black"
Format.font_color_selected="White"
Format.lastbutton="OK"
Format.group_size=1
Format.number_rows=.f.
Format.alternating_bands=.f.

'Apply 'owner draw' formatting information to the list
auto_list_vPickList = a5_owner_draw_list_fmt(auto_list_vPickList,Format)
		
temp_count = w_count(auto_list_vPickList,crlf())
DELETE a_vPickList
DIM a_vPickList[temp_count] as c
a_vPickList.initialize(auto_list_vPickList)

And this is the line of code which displays the list in the xdialog. Again this line of code was generated
using the genie.

[%d;O={@@}%.76,20vPickList^$$a_vPickList?vfilteredLabel="Selected"]

Following the line which displays the list is a row of radio buttons which when selected, dynamically
changes the filter for the list. Any time a different button is selected, the event is trapped using !x.

View:  (vFiltered:Active!x?vFilteredLabel="Selected")
 (vFiltered:InActive!x?vFilteredLabel="Selected")
 (vFiltered:Pre-School!x?vFilteredLabel="Selected")
 (vFiltered:School!x?vFilteredLabel="Selected")
 (vFiltered:Archive!x?vFilteredLabel="Selected");;;

I then copied the original code from the first code block above, stripping out the format stuff as it is dimmed, and placed it in the
event area of the xdialog script.

%dlg%,<<%code%

IF a_dlg_button = "x" THEN
	auto_list_vPickList = table.external_record_content_get("persons",\
	"\"  \"+P_Status+\"|\"+Id+\"|\"+Address+\"|\"+City+\"|\"+recno()",\
	"p_status+ID+Address+City",\
	"P_Status="+s_quote(left(var->vFiltered,1)) )
	
	'Apply 'owner draw' formatting information to the list
	auto_list_vPickList = a5_owner_draw_list_fmt(auto_list_vPickList,Format)
	
	temp_count = w_count(auto_list_vPickList,crlf())
	DELETE a_vPickList
	DIM a_vPickList[temp_count] as c
	a_vPickList.initialize(auto_list_vPickList)
	a_dlg_button = ""
END IF

%code%)

This setup does not work. The initial list is create. But when I change a radio button, the list disappears.

With some guessing, I stumbled on to a work around.

If I change

[%d;O={@@}%.76,20vPickList^$$a_vPickList
  to 
[%d;O={@@}%.76,20vPickList^$$auto_list_vPickList

the list is regenerated using the new filter. While it works, I'm not sure why and I'm not sure if this could cause
a problem.

Anyone have any thoughts?

[johnkoh]

Re: xDialog, Check Box-List Box and events

Ron,

I have not tested your code.

See "Redim". you need Redim the Array that is why i do not using the array in my listings.
also the filter "P_Status="+s_quote(left(var->vFiltered,1)) , i think it should be may be "left(P_Status,1)="+s_quote(left(var->vFiltered,1))

[Ronald Anusiewicz]

Re: xDialog, Check Box-List Box and events

John, I'm not sure I understand the purpose for using redim. If I copy line for line all the code which creates the list in the first place and use that code to recreate the list, the code fails. If I read the code correctly, the code deletes the array and then dims the revised array.

temp_count = w_count(auto_list_vPickList,crlf())
DELETE a_vPickList
DIM a_vPickList[temp_count] as c
a_vPickList.initialize(auto_list_vPickList)

That said, for some reason the array a_PickList does not appear to be created. So I have to use auto_list_vPickList instead.

The field p_status is a c,1 field so "left(P_Status,1)" is meaningless.

[johnkoh]

Re: xDialog, Check Box-List Box and events

Ron,

Did you read about "Redim" from Help? - you have to call with redim your array ...., not copy of the original

Can you try it without an Array?
- give me some samples i will show you my modification.

[Ronald Anusiewicz]

Re: xDialog, Check Box-List Box and events

Thank you John,

I changed the code to:

temp_count = w_count(auto_list_vPickList,crlf())
'DELETE a_vPickList
REDIM a_vPickList[temp_count] as c
a_vPickList.initialize(auto_list_vPickList)

Now the list updates like it should.

I thought that I could delete the array and re-create the array but that didn't work.

[MoGrace]

Re: xDialog, Check Box-List Box and events

If its an array, can't you just resize it with the new temp_count?

[johnkoh]

Re: xDialog, Check Box-List Box and events

Ron,

I have a sample code how to do in both cases, an array and without array in the list box.
You can get the sample table data from A5 samples.

I do not know your filter is logically right or not but the expression is shown as " left(last_name,len("r")) = "r" "

the filter "P_Status="+s_quote(left(var->vFiltered,1)) , i think it should be may be "left(P_Status,1)="+s_quote(left(var->vFiltered,1))

'get list
dim vWhichState as c="MA"
'without an array
Sub_getTableRecords(local_variables())
'
'array case
Sub_getArrayRecords(local_variables())
DELETE array_vPickList
DIM array_vPickList[temp_count] as c
array_vPickList.initialize(auto_list_vPickList)	


dlgbody=<<%dlg%
{startup=Init}
View by state:  (vWhichState:MA!vWhich)(vWhichState:CA!vWhich)(vWhichState:IL!vWhich);
[%d;O={@@}%.162,20vPickList^$$auto_list_vPickList];
{lf=2};
array list;
[%d;O={@@}%.162,20vPickList^$$array_vPickList];
%dlg%

dlgevent=<<%code%
If a_dlg_button ="vWhich" then
	'get the list with filter
	'vWhichState ="MA"
	Sub_getTableRecords(local_variables())
	
	'Array case - apply the "Redim" at here
        'get list and define the array again
Sub_getArrayRecords(local_variables())	
REDIM array_vPickList[temp_count] as c
array_vPickList.initialize(auto_list_vPickList)		
	
	a_dlg_button =""
end if
%code%

ui_dlg_box("Ron Sample",dlgbody,dlgevent)

function Sub_getTableRecords as c (vars as p)
	with vars
auto_list_vPickList = table.external_record_content_get("contacts",\
"\"  \"+first_name+\"|\"+contact_id+\"|\"+address+\"|\"+City+\"|\"+state",\
"first_name+City","state="+s_quote(vWhichState) )

Dim format as p 
Format.tab_stops="1.50,2.75,4.75,6.75,8.7"
Format.odd_row_color="White"
Format.even_row_color="White"
Format.odd_selected_color="Dark Blue"
Format.even_selected_color="Dark Blue"
Format.font="Calibri,11"
Format.font_color_unselected="Black"
Format.font_color_selected="White"
Format.lastbutton="OK"
Format.group_size=1
Format.number_rows=.f.
Format.alternating_bands=.f.

'Apply 'owner draw' formatting information to the list
auto_list_vPickList = a5_owner_draw_list_fmt(auto_list_vPickList,Format)
		
	end with
end function

function Sub_getArrayRecords as c (vars as p)
	with vars
auto_list_vPickList = table.external_record_content_get("contacts",\
"\"  \"+first_name+\"|\"+contact_id+\"|\"+address+\"|\"+City+\"|\"+state",\
"first_name+City","state="+s_quote(vWhichState) )

Dim format as p 
Format.tab_stops="1.50,2.75,4.75,6.75,8.7"
Format.odd_row_color="White"
Format.even_row_color="White"
Format.odd_selected_color="Dark Blue"
Format.even_selected_color="Dark Blue"
Format.font="Calibri,11"
Format.font_color_unselected="Black"
Format.font_color_selected="White"
Format.lastbutton="OK"
Format.group_size=1
Format.number_rows=.f.
Format.alternating_bands=.f.

'Apply 'owner draw' formatting information to the list
auto_list_vPickList = a5_owner_draw_list_fmt(auto_list_vPickList,Format)
		
temp_count = w_count(auto_list_vPickList,crlf())


	end with
end function