Report List in Xdialog

[Keith Hubert]

Here is a small script to see a list of reports in a Xdialog box. The selected report can be Previewed then printed if required. This script can be used in any aplication as it is not tied to a table or form.

Keith Hubert
Guild Member
London.

'Date Created: 27-Dec-2003 09:24:47 PM
'Last Updated: 28-Dec-2003 03:23:12 PM
'Created By : Keith Hubert
'Updated By : Cal Locklin
DIM SHARED a_reports[100] as C
DIM SHARED varC_result as C

report_list = a5.Report_Enum(2)
a_reports.initialize(report_list)
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Print Report",{sp=2}
{endregion};
%dlg%, "" then
report.preview(reportlist)
end if

[Scott Rusoff]

RE: Report List in Xdialog

Hello Keith,

Thanks for the code, I found it very useful.

Thanks,

[Robin James]

RE: Report List in Xdialog

Hi Keith

That's great piece of code!
So small and so neat & useful.

Thanks a lot.
Robin

[ronwills]

RE: Report List in Xdialog

Keith,

Thanks for posting the code! I added a few things:

1. Added a sort function so that the reports sort in alphabetical order. [ a_reports.sort() ]

2. I added a variable that I use in my applications which displays the Software name (v_Softwarename). I placed this variable in the pop-up box heading. If you do not have this global variable in your application, the heading will just display "List of Reports in the Program" rather than "List of Reports in the ABC Billing Program"

3. Put some basic instructions on the pop-up form "Click on a Report, then Click OK to Preview" - My users need all the help they can get!


'Date Created: 27-Dec-2003 09:24:47 PM
'Last Updated: 25-Jan-2004 05:05:09 PM
'Created By : Keith Hubert
'Updated By :
DIM SHARED a_reports[100] as C
DIM SHARED varC_result as C
DIM GLOBAL v_softwarename as c 'Added - see below

report_list = a5.Report_Enum(2)
a_reports.initialize(report_list)
'==========================================================
'1. Added a sorting function so that the reports sort in alphabetical order
a_reports.sort() 'added this function to sort the reports in alphabetical order.
'==========================================================
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
'==========================================================
'1. Changed the Dialog box heading text to display the name of the program (found in the variable v_softwarename)
'2. Added a check to see if the variable 'v_softwarename' has a value, if not, don't attempt to use it.
'3. Increased the width so that the pop-up box would be a little wider from .4 to .8
'4 Changed the Frame 1 Text to provide some instructions for the user 'Click on a Report, then Click OK to Preview'
varC_result = ui_dlg_box("List of Reports in the "+if(alltrim(var->v_Softwarename)v_Softwarename))+" Program",{sp=2}
{endregion};
%dlg%, "" then
report.preview(reportlist)
end if


Thanks again for posting some very usable code.

Ron Wills
Small Business Technology, Inc.
[email protected]

[[email protected]]

RE: Report List in Xdialog

Ron,
Just used your script...
GREAT
Al Lipsky

[lcbarker]

Re: Report List in Xdialog

I was happy to find this last night. Something I was looking for. But when I tried each of these dialogs I received errors.

I first tried the dialog by Keith and received an error "Missing right parenthesis" on Line 12. As I examined the code again, I could see that although there was a parenthesis right after ui_dlg_box, there was not a closing one. So I added one at the very end and still got the same error. Added a parenthesis in other places and got different errors. Somehow, something's not being closed.

I then tried the dialog by Ron. When I try to save that, I get a "Bad Expression Character" error on line 43. Tried to change a few things, but to no avail.

Perhaps in the last 6-7 years the coding requirements have changed.

Any thoughts?

Les

[Stan Mathews]

Re: Report List in Xdialog

The code has become corrupted somehow.

Keith's

DIM SHARED a_reports[100] as C 
DIM SHARED varC_result as C 

report_list = a5.Report_Enum(2) 
a_reports.initialize(report_list) 
ok_button_label = "&OK" 
cancel_button_label = "&Cancel" 
varC_result = ui_dlg_box("Print Report",<<%dlg% 
{frame=1,2:Select a Report to Print} 
{sp=.5} 
{lf=1} 
{region} 
[.40,15reportlist^#a_reports!select_report]; 
{endregion}; 
{region} 
{lf}{justify=center} 
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL> 
{endregion}; 
%dlg%,<<%code% 
if a_dlg_button="select_report" then 
a_dlg_button="" 
end if 
%code%) 

if varc_result = "OK" .and. reportlist <> "" then 
report.preview(reportlist) 
end if

[lcbarker]

Re: Report List in Xdialog

Thanks Stan. Works perfectly.

Les

[WokingJon]

Re: Report List in Xdialog

Great bit of 'simple' coding. I just grabbed this and modified to give user a list of letters to select from to edit...

'Date Created: 14-Sep-2011 07:41:19 AM
'Last Updated: 14-Sep-2011 07:41:19 AM
'Created By : Jon
'Updated By : Jon
DIM SHARED a_letters[100] as C
DIM SHARED varC_result as C

letter_list = a5.letter_Enum(2)
a_letters.initialize(letter_list)
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Edit letter",<<%dlg%
{frame=1,2:Select a letter to Edit}
{sp=.5}
{lf=1}
{region}
[.40,15letterlist^#a_letters!select_letter];
{endregion};
{region}
{lf}{justify=center}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%,<<%code%
if a_dlg_button="select_letter" then
a_dlg_button=""
end if
%code%)

if varc_result = "OK" .and. letterlist <> "" then
a5_layout_design(letterlist,"letter")
'letter.preview(letterlist)
end if

Thanks,

Jon

[CALocklin]

Re: Report List in Xdialog

FWIW:

- one of my pet peeves is the use of arrays when they aren't necessary. Alpha does this a lot in their examples but I think it just makes things more complicated - it adds extra lines that complicate the code and it also leaves the issue of setting the array size. In this particular case, this routine wouldn't work in a few of my apps because they have over 100 reports. Of course, I could change the number but that makes it less generic. Or, the script itself could determine the number of lines needed after getting the list and then set the array but why even bother doing all that when the array is totally unnecessary?

- another pet peeve is the use of regions that are completely unnecessary.

Here's the same thing as above but without the array (sorting is still easy) and with a few other changes. This was done not to correct anyone (I started from Stan's version only because it was convenient to do so) but hopefully to help people learning xdialog by providing some new ideas and explaining the logic of why I do certain things.

Add'l changes:

- The use of Shared variables probably isn't needed and they shouldn't be set as Shared unless necessary. Shared variable are used a lot in Action Scripting because they are often necessary due to the fact that multiple actions are combined. If writing 'normal' xbasic routines they shouldn't be used unless needed. Using Shared variables when not necessary opens up the possibility for accidentally changing a variable that wasn't meant to be changed. If you DON'T use a Shared variable when one IS needed, the code probably won't work and you will find out very quickly. If you DO use a Shared variable when it is NOT needed, the code may work just fine but something else outside of the code you are working on may get messed up and it's likely to take awhile to figure out why since you probably weren't thinking about that other script that used the same variable name.

- The regions could be removed completely but I left one in only because it makes the frame command easier. The frame now goes around 1 "line/vertical item" (the region) and the number of lines inside the region can be changed without needing to change the "1,1" in the frame command. This is a somewhat unusual use of regions but it definitely makes things easier. Just be aware that every region you add to an xdialog adds a little bit of extra space after the region. (Another "feature" of A5.) The more regions you use, the larger the extra space at the bottom and the only solution is to eliminated the regions.

- I changed some variable names but that's just personal preference - I think they are more descriptive of what the variable actually is. For example, using "reportlist" to return the name of one report doesn't seem like 'good form' to me.

- Simplified the naming of the buttons. (Alpha's default method is OK for Action Scripting but it isn't necessary and is overly complex in 99% of the cases.)

- Changed the %Code% section so the user can't accidentally click the OK button and exit without selecting a report. This is much more user friendly than making the user start all over again. It also tells the users what was wrong rather than forcing them to figure it out on their own when nothing happens after clicking the OK button.

- Removed the event action in the report list control. There may have been a need for it that was removed before posting the original routine; for example, I would have added the ability for the user to double click the report name but I didn't add that here. There are enough things added/changed already.

- Note also a couple things I did to the frame. I made it bold and added an extra space before and after the text. It's a minor thing but I've never liked how close the frame line is to the text so I add the extra spaces to fix that. Obviously you don't need to do that unless you want to but it took me awhile before I tried it and discovered that it would work.

- At the last minute I decided to throw in the ability to resize the dialog since some people may find that useful. It originally took me a little bit to figure out the correct syntax to make this work but I use it a lot now. Add the {stretch} command before the display box and add the{stickto} command before the buttons. (Note - it gets much more complicated when there are multiple objects getting stretched!) If the buttons are centered, use {stickto=bottom,center} and if they are left justified, use {stickto=bottom,left}. The {remember} commands can also be useful for opening the dialog up in the same place and size in the future but I'll leave it up to you to check the Help file for more info on that.

DIM report_list as C 
DIM dlg_result as C 

report_list = sortsubstr( a5.Report_Enum(2), crlf() )
dlg_result = ui_dlg_box("Print Report",<<%dlg% 
{font=Arial,9,b}{frame=1,1: Select a Report to Print }{font=Arial,9,n}
{region}
{sp=.5} 
{lf=1}
{stretch=height,width}[.40,15report_chc^#report_list]; 
{stickto=bottom,center}{lf}{justify=center} 
<*15OK> <15Cancel>
{endregion}
%dlg%,<<%code% 
IF a_dlg_button="OK"
	IF report_chc = ""
		ui_msg_box("SELECTION REQUIRED", "Please select a report or press 'Cancel' to quit.", ui_attention_symbol )
		a_dlg_button=""
	END IF
END IF
%code%) 

IF dlg_result = "OK"
	report.preview( report_chc ) 
END IF