Select ALL in a list view object(xdialog)

[Scott Emerick]

Hi All,

Can anyone tell me how I can select all records in a xDialog list view object by using xbasic.

The older style list box was simple to do this. I would just have my return value variable = my auto_list values

I can't seem to find what I need to select them by xbasic and have it highlighted as it would if I clicked on it.

Can anyone offer some help here.

Thanks,

Scott

[Peter.Wayne]

Hi, Scott. Not sure what you mean by new style list view object. This still works the way it always did:

DIM favorites as C=""

list_favorites = <<%list%
apples
bananas
cranberries
dates
figs
lemons
limes
mangoes
melons
raspberries
%list%

ui_dlg_box("Fruits",<<%dlg%
{region}
fruits:| [%MW%.40,5favorites^#list_favorites];
{endregion};
{line=1,0};
{region}
<*OK> <Select All!all>
{endregion};
%dlg%,<<%code%
if a_dlg_button="all" then
    favorites=list_favorites
    a_dlg_button=""
end if
%code%)

[Scott Emerick]

Peter,

I am talking about the List View Object, not the list object.

Attached is a script you can import and run in Alpha Sports to see what I mean.

When you select a name off the list and hit OK you will see the customer number in the msg box.
Now Select Randi Adams and press OK ... You will see 00000056 as the return value
Now just hit Select All, this will set vlist_rz to 00000056. Notice the row does not highlight, but when you hit OK you get the correct return.

You can also manually select anything you wish then hit Clear All and the row(s) clear.

Scott

[Peter.Wayne]

Scott,
I hadn't even noticed the Listview object! Here's an example of selecting more than one item, though:

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED varC_result as C
DIM fruit_FuncCode AS C = <<%CodeFunctions%
FUNCTION DoSort AS C (byref CurrentSortField AS C , byref CurrentSortDirection AS C, NewSortField AS C, pTableDef AS P,  arrContents AS P )
	DIM cResult AS C
	DIM SortDirection AS C
	DIM SortField AS C

	IF NewSortField = CurrentSortField
		' clicked on same field, reverse sort
		IF CurrentSortDirection = "D"
			CurrentSortDirection = "A"
		ELSE
			CurrentSortDirection = "D"
		END IF
	ELSE
		CurrentSortField = NewSortField
		CurrentSortDirection = "A"
	END If
	SortDirection	= CurrentSortDirection
	SortField		= CurrentSortField
	arrContents.sort(SortDirection, stritran(SortField, "->", "__"))
	cResult = DumpContents(pTableDef, arrContents)
	
	DoSort = cResult
END FUNCTION


FUNCTION GetContents AS C ( pTableDef AS P, arrContents AS P, lv AS P )
	DIM cResult AS C
	
	arrContents.Clear()

	DIM format AS C
	
	' normalize header names
	format = stritran(pTableDef.TitleRow, "|", crlf())
	format = *for_each(x, table.name_normalize(word(x,1,":"))+iif(":"$x,":"+word(x,2,":"),""), format)
	format = alltrim(format)
	format = stritran(format, crlf(), "|")


cResult = <<%txt%
apples
bananas
pears
peaches
raspberries%txt%
	
	cResult = alltrim(cResult)
	
	arrContents.resize(line_count(cResult))
	arrContents.initialize_properties(format, cResult)



	cResult = DumpContents(pTableDef, arrContents)
	GetContents = cResult
END FUNCTION



FUNCTION DumpContents AS C ( pTableDef AS P, arrContents AS P )
	DIM cResult AS C
	DIM cEval AS C

	pTableDef.FieldList	= alltrim(pTableDef.FieldList)

	IF pTableDef.FieldList = ""
		EXIT FUNCTION
	END IF
	
	cEval = *for_each(x, "TrimCRLFs(x." + stritran(table.name_normalize(x),"->", "__")+")", pTableDef.FieldList)
	cEval = alltrim(cEval)
	cEval = stritran(cEval, crlf(), "+"+quote("|")+ "+")
	IF pTableDef.ReturnValueExpression <> ""
		cEval = quote("{DATA=") + " + TrimCRLFs(x." + stritran(table.name_normalize(pTableDef.ReturnValueExpression),"->", "__") + ")+" + quote("}")+ "+" + cEval
	END IF
	
	cEval = "*for_each(x, " + cEval + ", arrContents)"
	cResult = eval(cEval)
	

	DumpContents = cResult	
END FUNCTION

FUNCTION TrimCRLFs AS A ( data AS A )
	IF typeof(data) = "C"
		TrimCRLFs = stritran(data, crlf(), " ")
	ELSE
		TrimCRLFs = data
	END IF
END FUNCTION



%CodeFunctions%
DIM fruit_Funcs AS P = compile_template(fruit_FuncCode)
DIM fruit_arrContents[1] AS P

DIM SHARED  fruit AS C
DIM fruit_CurrentSortField AS C = ""
DIM fruit_CurrentSortDirection AS C = "A"

DIM fruit_pTableDef AS P
DIM fruit_pTableDef.ReturnValueExpression AS C = ""
DIM fruit_pTableDef.FieldList AS C = "fruit"
DIM fruit_pTableDef.TitleRow AS C = "fruit"


fruit_pLV.titlerow = fruit_pTableDef.titlerow
fruit_pLV.titleevents = "fruit_Sort_fruit"
fruit_pLV.style = "report,showselalways,fullrowselect"
fruit_pLV.dragbehaviour = ""
fruit_pLV.dropbehaviour = ""
fruit_pLV.contents = fruit_Funcs.GetContents(fruit_pTableDef, fruit_arrContents, local_variables())

fruit_pLV.events = <<%code%
function OnRightClick as c(lv as p,listView as p,args as p)
	WITH lv 
		listView.Selection = listView.GetRowValue(args.GetClickRow())
		OnSelectionChanged(lv, listView )
	
		'to call a function outside the events code, you must use the ui_dlg_eval() function
		'menu = ui_dlg_eval(dlg_title,"a5wcb_PublishRclick(selectedFilename)")
		
'		ui_msg_box("OnRightClick",listview.selection)
	END WITH
end function	
			
function OnDoubleClick as c(lv as p,listView as p,args as p)
	WITH lv
		fruit  = listView.GetRowValue(args.GetClickRow())
'		ui_msg_box("OnDoubleClick",fruit)
	END WITH
end function	
	
FUNCTION OnSelectionChanged AS V (lv AS P, listView as p )
	WITH lv
		fruit = listView.Selection
		'		ui_msg_box("OnSelectionChanged",fruit)
	END WITH
END FUNCTION
		
FUNCTION OnKeyDown as v(vars as p,listView as p,args as p)
	DIM key AS C
	Dim KeyName as c 

	key = args.GetKeyName()
	KeyName = key 

	IF key = "{Delete}" .OR. key = "{Num Del}"
		KeyName = "{Delete}"
	ELSE IF args.keycode = 13 ' enter
		KeyName = "{Enter}"
	ELSE IF args.keycode = 8 ' backspace
		KeyName = "{Backspace}"
	END IF
	
	'ui_msg_box("OnKeyDown", KeyName)
END FUNCTION
%code%
fruit=<<%a%
apples
bananas
%a%
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Alpha Five",<<%dlg%
{region}
favorites:| {listview=40,5fruit^=fruit_pLV};
{watch=fruit!foo};
{endregion};
{line=1,0};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
<Select All!all>
{endregion};
%dlg%,<<%code%
IF left(a_dlg_button, len("fruit_Sort_")) = "fruit_Sort_"
	DIM NewSortField AS C
	NewSortField = substr(a_dlg_button, len("fruit_Sort_")+1)
	fruit_pLV.Contents = fruit_Funcs.DoSort(fruit_CurrentSortField, fruit_CurrentSortDirection, NewSortField, fruit_pTableDef, fruit_arrContents)
	a_dlg_button = ""
END IF
if a_dlg_button="all" then
    a_dlg_button=""
    fruit=<<%txt%
apples
bananas
pears
peaches
raspberries%txt%
end if

IF a_Dlg_button = "fruit_refresh"
	a_dlg_button = ""

	fruit_pLV.contents = fruit_Funcs.GetContents(fruit_pTableDef, fruit_arrContents, local_variables())
END IF

IF a_dlg_button = "foo"
	a_dlg_button = ""
	' do nothing
END IF
%code%)

[Scott Emerick]

Thanks Peter,

Your example uses a static list, but I think I know what I can do to make it work this way.

Thanks Again and hope to see you next week.

Scott