ui_get_radio2(): cancel condition?

[abackstrom]

ui_get_radio2() has two buttons: OK and Cancel. When a default value is set, the function will return the default value regardless of which button is pressed. I would have expected Cancel to return an empty string. Has anyone else noticed this? I don't believe I'm doing anything wrong.

[MoGrace]

Re: ui_get_radio2(): cancel condition?

I have a post in here a couple of months ago on the same thing - it is a bug apparently.

Sorry I spoke too soon - it was ui_get_list2(). Perhaps you have found another one.

I suppose you could add Cancel as a radio button choice.

[CDeCinko]

Re: ui_get_radio2(): cancel condition?

ui_get_radio2() has two buttons: OK and Cancel. When a default value is set, the function will return the default value regardless of which button is pressed. I would have expected Cancel to return an empty string. Has anyone else noticed this? I don't believe I'm doing anything wrong.

I also concur, that when clicking the Cancel button, the default string is returned instead of an empty, null or canceled string. This is not the expected behavior and I would agree a bug.

[Tbaker]

Re: ui_get_radio2(): cancel condition?

The ui_get_radio2() function really does work as long as you don't show a default button.

If you code it as follow:

res = ui_get_radio2("Pick a color",[COLOR="Red"]""[/COLOR],list,"Color Selection")

Then if you pick a button and then decide to CANCEL the result will be null

Here is the code from the help file with no default

dim res as C
list = a5.Color_Enum()
list = word(list,1,crlf() ,5)
res = ui_get_radio2("Pick a color",[color="RED"]""[/color],list,"Color Selection")
ui_msg_box("Color Choice",res)

with the default as "" then you could select a button (a color is this case) and then push cancel, the message returned will be null - at least it works that way for me.

I don't think that it is a bug in Version 7, more than likely it should have been explained better in the help file.

FWIW

Tom Baker

[CALocklin]

Re: ui_get_radio2(): cancel condition?

If you want something that always returns <blank> when Cancel is pressed, here's an "AIMS_get_radio()" function that will do it. I left the original test routine in so you can see the slight differences with my version. (The frame title is in bold, there is no limit to the number of buttons except that it will eventually get too tall for the screen, much of that extra space around the OK/Cancel buttons is gone, and the buttons are indented a bit. Personally, I think mine looks more professional but you can easily modify it if you wish.)

list = a5.Color_Enum()
list = word(list,1,crlf() ,20)
res = ui_get_radio2("Pick a color","",list,"Color Selection")
res = aims_get_radio("Pick a color","black",list,"Color Selection")
ui_msg_box("Color Choice",res)

FUNCTION AIMS_get_radio as C ( title as C, default as C, choices as C, frameTitle="" as C )
 DIM radio_def as C
 DIM rad_chc as C
 rad_chc = default
 dlg_text = <<%dlg%
{ysize=.3}{units=F}{sp};
[[frame_def]]
[[radio_def]]
{sp=25};
<*10OK> <10Cancel>
%dlg%
 btn_cnt = w_count( choices, crlf() )
 IF frameTitle <> ""
  frame_def = "{font=Tahoma,8,b}{frame=1," + ltrim( str( btn_cnt + 1 ) ) + " " + frameTitle + " }{font=Tahoma,8,n};"
 ELSE
  frame_def = ""
 END IF
 dlg_text = stritran( dlg_text, "[[frame_def]]", frame_def )
 radio_def = ""
 FOR qx = 1 to btn_cnt
  radio_def = radio_def + " (rad_chc:" + word( choices, qx, crlf() ) + ");" + crlf()
 NEXT
 dlg_text = stritran( dlg_text, "[[radio_def]]", radio_def )
 DIM dlg_result as C
 dlg_result = ui_dlg_box( Title , dlg_text )
 IF dlg_result <> "OK"
  AIMS_get_radio = ""
 ELSE
  AIMS_get_radio = rad_chc
 END IF
END FUNCTION

DISCLAIMER: I just whipped this out in the last few minutes so it's relatively untested. If you use strange characters in your selection list it might mess up - characters like {, }, (, ), <, >, and \ are particularly "dangerous". Initial testing seems to be OK but I can't guarantee it in all circumstances. In other words, "your results may vary."

Alpha's:


Mine:

[CALocklin]

Re: ui_get_radio2(): cancel condition?

Here's an improved version that adds the ability for the user to hit the "O" or "C" key to "OK" or "Cancel" it from the keyboard. (Of course, they could also OK it with the Enter key or cancel it with the Esc key.)

If you use this, remember to make sure the list can't be so long that it's taller than your user's screen. Since each screen resolution is a different height, I didn't add any checks for this.

'Date Created: 08-Oct-2008 02:14:02 AM
'Last Updated: 08-Oct-2008 11:23:02 AM
'Created By  : Cal Locklin
'Updated By  : Cal Locklin
 
FUNCTION AIMS_get_radio as C ( title as C, default as C, choices as C, frameTitle="" as C )
 DIM radio_def as C
 DIM rad_chc as C
 rad_chc = default
 dlg_text = <<%dlg%
{ysize=.3}{units=F}{sp};
{on_char=*}
[[frame_def]]
[[radio_def]]
{sp=25};
<*10&OK> <10Cancel>
%dlg%
 btn_cnt = w_count( choices, crlf() )
 IF frameTitle <> ""
  frame_def = "{font=Tahoma,8,b}{frame=1," + ltrim( str( btn_cnt + 1 ) ) + " " + frameTitle + " }{font=Tahoma,8,n};"
 ELSE
  frame_def = ""
 END IF
 dlg_text = stritran( dlg_text, "[[frame_def]]", frame_def )
 radio_def = ""
 FOR qx = 1 to btn_cnt
  radio_def = radio_def + "{sp}(rad_chc:" + word( choices, qx, crlf() ) + ");" + crlf()
 NEXT
 dlg_text = stritran( dlg_text, "[[radio_def]]", radio_def )
 DIM dlg_result as C
 dlg_result = ui_dlg_box( Title , dlg_text, <<%code%
IF a_dlg_button = "o"
 a_dlg_button = "OK"
ELSEIF a_dlg_button = "c"
 'just quit
ELSEIF len(a_dlg_button) = 1
 a_dlg_button = ""
END IF
%code% )
 IF dlg_result <> "OK"
  AIMS_get_radio = ""
 ELSE
  AIMS_get_radio = rad_chc
 END IF
END FUNCTION