Trying to combine lists from arrays...

[djldc]

I am trying to combine selections from an array. Those selections have a list of their own which I'd like to combine. For example, I have a food list consisting of fruits, veges, meats, dairy, and legumes. Each food list has it's own list of foods: -fruits, for example, has a list of its own: apples, oranges, peaches, pears. When I select a food such as fruits I would like to also return those items. I can't however, figure out how to make multiple food selections and add those "subitems" to one group (in this case: TOTAL_LIST).


'code------------------
dim FOODLIST[5] as C
FOODLIST.initialize(<<%list%
fruits
veges
meats
dairy
legumes
%list%)

dim fruitlist[4] as c
FRUITLIST.initialize(<<%list%
apples
oranges
peaches
pears
%list%)

dim vegeslist[5] as c
VEGESLIST.initialize(<<%list%
carrots
string beans
broccoli
spinach
corn
%list%)

dim meatslist[4] as c
MEATSLIST.initialize(<<%list%
pork
chicken
lamb
ham
%list%)

dim legumeslist[4] as c
LEGUMESLIST.initialize(<<%list%
soybeans
peas
peanuts
lentils
%list%)

ui_modeless_dlg_box("show_array",<<%dlg%

[%mW%.50,10fLIST^#FOODLIST]
{watch=list!foo}{sp}
[%MW%.28,10fLIST];

[%mw%.50,5TOTAL_LIST];
<15&Cancel!cancel>
%dlg%,<<%code%

if a_dlg_button="cancel" then
ui_modeless_dlg_close("show_array")
end
end if

if a_dlg_button="foo" then


end if

%code%)

'end code-----------

[djldc]

Re: Trying to combine lists from arrays...

Here's something I came up with, but I am sure there's another (possibly more efficient) way.

'code------
dim FOODLIST as C
FOODLIST=<<%a%
fruits
veges
meats
dairy
legumes
%a%

dim fruits[5] as c
FRUITS.initialize(<<%list%
apples
oranges
peaches
pears
%list%)

dim dairy[4] as c
dairy.initialize(<<%list%
milk
eggs
cheese
cream
%list%)

dim veges[5] as c
VEGES.initialize(<<%list%
carrots
string beans
broccoli
spinach
corn
%list%)

dim meats[4] as c
MEATS.initialize(<<%list%
pork
chicken
lamb
ham
%list%)

dim legumes[4] as c
LEGUMES.initialize(<<%list%
soybeans
peas
peanuts
lentils
%list%)

dim total_list as c

ui_modeless_dlg_box("show_array",<<%dlg%

[%mW%.50,10fLIST^#FOODLIST]
{watch=Flist!foo}{sp}
[%MW%.14,10fLIST];

[%mw%.50,15TOTAL_LIST]
<15&Cancel!cancel>
%dlg%,<<%code%

if a_dlg_button="cancel" then
ui_modeless_dlg_close("show_array")
end
end if

if a_dlg_button="foo" then
dim total_list1 as c
total_list1=""
dim total_list2 as c
total_list2=""
dim total_list3 as c
total_list3=""
dim total_list4 as c
total_list4=""
dim total_list5 as c
total_list5=""

if flist="" then
total_list=""
end if

for each foo in fList
if is_one_of(foo, Flist) = .t.

if is_one_of("fruits",flist)
total_list1 = fruits.dump("r")
end if

if is_one_of("veges",flist)
total_list2 = veges.dump("r")
end if

if is_one_of("meats",flist)
total_list3 = meats.dump("r")
end if

if is_one_of("legumes",flist)
total_list4 = legumes.dump("r")
end if

if is_one_of("dairy",flist)
total_list5 = dairy.dump("r")
end if
continue
end if

next

end if
total_list=""
total_list=total_list1+total_list2+total_list3+total_list4+total_list5
%code%)

'end code-------

[Steve Andrews]

Re: Trying to combine lists from arrays...

I see that you have come up with a semi-solution to your combining of lists. But as powerful as Alpha's list-processing functions are, I wanted to chime in on this.

The approach shown below is simpler and more concise. With minimal code, all of the processing is done for creating the combined list. Often times after extracting field data into lists, I use the *for_each() and remove_blank_lines() functions to do powerful processing in a short time.

DIM SHARED cFoodlist as C
DIM SHARED cTotal_List as C
DIM SHARED cTypes as C
DIM SHARED varC_result as C
DELETE a_cFoodlist		
DIM a_cFoodlist[5] as c
dim temp_list as c 
temp_list = <<%list%
fruits
veges
meats
dairy
legumes
%list%
cItems = <<%itms%
f|apples
f|oranges
f|peaches
f|pears
d|milk
d|eggs
d|cheese
d|cream
v|carrots
v|string beans
v|broccoli
v|spinach
v|corn
m|pork
m|chicken
m|lamb
m|ham
l|soybeans
l|peas
l|peanuts
l|lentils
%itms%
a_cFoodlist.initialize(temp_list)
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("Food List",<<%dlg%
{region}
Food Groups:| [%M%.40,10cFoodlist^#a_cFoodlist!cFoods_];
{endregion};
{line=1,0};
{region}
[%mw%.50,15cTotal_List]
{endregion};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%,<<%code%
if left(a_dlg_button,7) = "cFoods_"
	cTypes = ""
	for j = 1 to w_count(cFoodlist,crlf())
		cTypes = cTypes + left(word(cFoodlist,j),1)
	next j
	cTotal_List = cItems
	cTotal_List = *for_each(foo,if(left(foo,1)$cTypes,word(foo,2,"|"),""),cTotal_List)
	cTotal_List = remove_blank_lines(cTotal_List)
	a_dlg_button = ""
end if
%code%)

I hope this helps.

Steve

[djldc]

Re: Trying to combine lists from arrays...

Hi Steve,
That's more like it! I just started using xbasic this year and really enjoy the flexibility. Thank you for chiming in! I'll study and implement into my "real" code. Enjoy the sunny day we're having in NJ!

Don