text and line position in xdialog

[Mike Wilson]

Could someone please help me understand how to have the text "color" positioned closer to the text box and how to get the line above the buttons the full width of the box. The syntax of the second I have struggled with forever, usually trying every possible combination until somehow it ends up working, but I have yet to understand what makes it work and what doesn't. Thanks.

dim vG1 as C="Color"
dim vcolor as C
dim dlg_text as C
dim dlg_title as C="Colors"

dlg_text=<<%dlg%
{on_key=enter}
{lf};
{region}
{justify=center}{font=Arial,10,B}{text=vG1}{font=Arial,10}[.30vcolor];
{endregion};
{region}
{line=1,0}
{lf};
<10&OK!ok> <10&Cancel!cancel>
{endregion};
 %dlg%

vresults=ui_dlg_box(dlg_title,dlg_text,<<%code%

%code%)

[Tbaker]

Re: text and line position in xdialog

Mike

Here is new code with comments

dim vG1 as C="Color"
dim vcolor as C
dim dlg_text as C
dim dlg_title as C="Colors"

dlg_text=<<%dlg%
{on_key=enter}
{lf};
{region}
{justify=center}{font=Arial,10,B}{text=8,vG1}{font=Arial,10}[.30vcolor]; {comment  Text takes a width parameter}
{comment  remove this endregion};
{comment remove this region}
{justify=left}; {comment add a justify left here}
{line=1,0}
{lf};
{justify=center} {comment  add justify center to center ok cancel}
<10&OK!ok> <10&Cancel!cancel>
{endregion};
 %dlg%

vresults=ui_dlg_box(dlg_title,dlg_text,<<%code%

%code%)

I added a text width parameter to put the text color closer
I removed the region and endregion to put the whole dialog together (as commented)
I then justified the ok and cancel buttons so they are centered

I think this is what you want

Tom

[Mike Wilson]

Re: text and line position in xdialog

Tom.
I had it solidly in my head that the text width parameter had a default to the width of the text entered. It's a "once you get it in your head" error that you nicely unclouded. Thanks.

The line thing is still a bit murky though. The interplay of the regions, the columns, and the justifications are still blurry, but your response has lifted the vail that {line} is affected by justification and the columns fits in there too. I've pretty much got the {frame} thing understood (almost). I'm going to work through this all today until I completely get it, and I think your response has me well on my way. Thanks much.

[CALocklin]

Re: text and line position in xdialog

Here's some more comments/changes for learning purposes.

- Get rid of ALL the regions in this case. They are only need if you have MULTIPLE lines that need to have various objects line up even though the labels/objects are different lengths. Alpha's genies create LOTS of unnecessary regions but I believe that's just because the genie doesn't know how many things will be in the region when it first creates it. When creating an xdialog yourself, all those regions are not necessary. Extra regions have two downsides in my opinion: (1) they add confusion and (2) they add unnecessary extra vertical space. I don't know why they have to create all that extra space but Alpha doesn't seem to want to change it. I especially hate putting a region around the buttons at the end of an xdialog because, in my opinion, all that does is put a huge empty, wasted space below the buttons. In this case that extra space at the bottom was originally 'balanced' by using an {lf}; command before the buttons - check my result with no region and a {sp}; command using {ysize=.3} and see if you don't think it looks a little more professional.

- It usually works better to put a ";" after the {line=} command. Otherwise vertical spacing can do strange things sometimes. Putting it after the "justify" command as it was here only adds an additional new line before the {line=} command. In this case, that new line is useful for the sake of appearance but I'd prefer to specify it with a separate {sp}; command because I think that's more understandable if I have to edit it later.

- Note the use of {ysize=.3}. I use this to give me better control over vertical spacing. Without it a simple ";" results in a very, very small additional space and it takes many of them to get a nice appearance instead of the huge (full) line space created with "{lf};". You can simply 'stack' semi-colons like this - <end of line>;;; - but I prefer to use {sp}; because it stands out more when debugging/editing. Of course, I also have a keyboard macro to make the {sp}; easier to type; othewise I'd get tired of typing those squiggly brackets. (I tried various heights and found .3 to be the best for my taste.)

- I changed the label to simply be the text itself rather than setting a variable and using {text=} to show it. Unless there is a need to change the actual label based on something else in the application, why not make things simpler and just put the text label right in the dlg_text? That way you don't have to worry about setting the right size in the {text=} command - it's more of a "wysiwyg" situation. (See also my method below for entering "variables" in the dlg_text. That method may be better when the text width can vary. Otherwise you might find yourself being forced to set a {text=} width that is larger than you want in most cases just to handle the one really long one.)

I noticed right away that you put the button labels right in the buttons without setting a variable for them. Bravo! Simplicity is a good thing. Xdialogs are complex enough without adding unnecessary complexity.

I also like the fact that you are separating the dlg_text and keeping it outside the ui_dlg_box() command. As you continue working with it you will find that the fact the dlg_text is just a character string will bring LOTS of versatility to your xdialogs. I have one unusually complex xdialog where the dlg_text itself is 15 lines long but there are 160 lines of code after it that modify the dlg_text. The changes are mostly done with stritran() commands but there are also a lot of IF statements to determine how each item needs to be changed.

Here's a sample to give you an idea...

This line is in the dlg_text string:
{ysize=.3}{units=F}{sp}{wrap=[[wrap_c]]};
I use [[...]] to identify something I want to change later. In this case, the wrap width is set based on some previous parameter. My decision to use double square brackets was basically a personal choice but it was also based on the fact that they are pretty easy to pick out and they will create a strange "field object" if I forget to make the change before running the xdialog. I tried just putting the variable name in at first but soon discovered that it was sometimes very difficult to see that I had forgotten to replace the variable with the correct string - the double square brackets fixed that.

Also, fwiw, the text between the double brackets is the actual variable name I'll use to replace it. That isn't necessary but it makes it easier and more logical for me to work with.

Then a line like this will be used to replace the "variable string" once the desired value has been determined. Note that the wrap width being modified here isn't really a "number"; it's character string that only represents a number. Everything inside the dlg_text is a character string.
dlg_text = stritran( dlg_text, "[[wrap_c]]", wrap_c )

I haven't found it as useful to keep the dlg_code section separate but maybe that's just me. Having it separate is certainly not bad.

You might also want to take a look at the two xdialog posts I did on the v9 board for Charlie Crimmel this evening - here and here. There are lots of other comments in those. (Xdialog has been a biggie for me today - and I was intending to get some work done before hitting the sack. Oh well, so much for that - g'nite now!)

 
dim vG1 as C="Color" 'Not needed. At least not in this case.
dim vcolor as C
dim dlg_text as C
dim dlg_title as C="Colors"
dlg_text=<<%dlg%
{on_key=enter}
{ysize=.3}
{lf};
{justify=center}{font=Arial,10,B}Color {font=Arial,10}[.30vcolor]; {comment  Text takes a width parameter - but defaults to 10 which isn't really big enough here.}
{sp};
{justify=left}{line=1,0};
{sp}; {comment Changed from lf because it was way too much space to look good once the region was removed.}
{comment  add justify center to center ok cancel}
{justify=center}
<10&OK!ok> <10&Cancel!cancel>
 %dlg%

vresults=ui_dlg_box(dlg_title,dlg_text,<<%code%
%code%)