Alpha Five crashes when attempting to send an email template

[David Montgomery]

Can someone help me determine why Alpha Five crashes at the following line in the script.

param_message = a5_mailmerge(em.message_body_temp,form_name)

'Date Created: 22-May-2011 11:25:33 PM
'Last Updated: 22-May-2011 11:40:00 PM
'Created By  : David
'Updated By  : David
 
'Send an e- mail message using the default external e-mail clilent.
IF is_object(topparent.this) THEN 
 form_name = topparent.name()+".this"
  ELSE
 form_name = ""
END IF
 
 
template_text = get_from_file("C:\My Data\All Databases\MDC Database\Pre-authorized notice.txt")
 
 
DIM em as P
DIM param_to as C 
DIM param_subject as C 
DIM param_cc as C 
DIM param_bcc as C 
DIM message_type as C 
 
 
'A5_email_parser() parses out the different sections of the e-mail template
em = a5_email_parser(template_text)
 
 
'The template may have stored expressions rather than constant values for the address components.
'Expressions will be prefixed with '='.
'a5_eval_expression() will evaluate any expressions that are prefixed with '=' in the context of the current form.
param_to = alltrim(a5_eval_expression(em.send_to_temp,local_variables()))
param_subject = alltrim(a5_eval_expression(em.subject_temp,local_variables()))
param_cc = alltrim(a5_eval_expression(em.cc_temp,local_variables()))
param_bcc = alltrim(a5_eval_expression(em.bcc_temp,local_variables()))
 
 
message_type = em.style
 
 
'Template message may have mail merge commands. a5_mailmerge() evaluates the mail merge commands.   
param_message = a5_mailmerge(em.message_body_temp,form_name)
'
''Evaluate any mail-merge commands in the message body. 
param_message = a5_mailmerge(param_message,form_name)
 
 
'Send the e-mail using the external e-mail client
email_client_external(param_to,param_subject,param_message,param_cc,param_bcc)

[David Montgomery]

Re: Alpha Five crashes when attempting to send an email template

Can someone help me with this please?

[David Montgomery]

Re: Alpha Five crashes when attempting to send an email template

I have solved the crashing issue, however when I try to email the template I get this. See attachment.

[TTI]

Re: Alpha Five crashes when attempting to send an email template

Did you ever find a solution to this? I am having a similar issue when using runtime I am getting the code you like you have in the email body.

[Al Buchholz]

Re: Alpha Five crashes when attempting to send an email template

I've found that keeping the template as a file allows me to edit with notepad.

[David Montgomery]

Re: Alpha Five crashes when attempting to send an email template

Hope this helps.

I haven't tried it with Runtime but works well with my desktop app.

I created and saved the template as instructed in the help file.

I use the following code to send the templates.

'Date Created: 26-May-2011 03:45:49 PM
'Last Updated: 09-Jun-2011 07:16:28 PM
'Created By  : David
'Updated By  : David

FUNCTION Email_Templates as C ()

	'Send an e- mail message using the default external e-mail clilent.
	IF is_object(topparent.this) THEN 
		form_name = topparent.name()+".this"
	  ELSE
		form_name = ""
	END IF
	template_name = alltrim(ui_get_email_templates())
	IF template_name = "" THEN 
		END'
	END IF

	IF template_name = "Client Miscellaneous"
		DIM tbl as P

		tbl = table.current()
		cont_name = calc->cClientname
		cont_company = ""
		cont_add = trim(tbl.address1)
		cont_add2 = trim(tbl.address2)
		cont_city = trim(tbl.city)
		cont_state = trim(tbl.state)
		cont_zip = trim(tbl.zip_code)

		ui_beep(48)
		DIM lastbutton as C
		lastbutton = ""
		DIM SHARED varP_Clntnote_Text_dialog as P
		DIM layout_name as C
		layout_name = "Clntnote Text dialog"
		varP_Clntnote_Text_dialog = :Form.load(layout_name,"dialog")
		varP_Clntnote_Text_dialog.new_record()
		varP_Clntnote_Text_dialog.show()
		lastbutton = :Clntnote_Text_dialog.last_pressed()

		IF lastbutton = "OK" THEN
			text = :Clntnote_Text_dialog:text.value
		  ELSE
			EXIT FUNCTION
		END IF

		response = ui_msg_box("Save note?","" + f_upper(text) + "",ui_ok_cancel + ui_question_symbol)
		IF response = ui_cancel_selected THEN
			Clntnote_Text_dialog.close()
			EXIT FUNCTION
		  ELSE IF response = ui_ok_selected THEN
			cl_note_txt = f_upper(text)
			ClntMemo()
		END IF
	END IF 

	template_text = a5_get_saved_email(template_name)
	DIM em as P
	DIM param_to as C 
	DIM param_subject as C 
	DIM param_cc as C 
	DIM param_bcc as C 
	DIM message_type as C 


	'A5_email_parser() parses out the different sections of the e-mail template
	em = a5_email_parser(template_text)
	'The template may have stored expressions rather than constant values for the address components.
	'Expressions will be prefixed with '='.
	'a5_eval_expression() will evaluate any expressions that are prefixed with '=' in the context of the current form.
	param_to = alltrim(a5_eval_expression(em.send_to_temp,local_variables()))
	param_subject = alltrim(a5_eval_expression(em.subject_temp,local_variables()))
	param_cc = alltrim(a5_eval_expression(em.cc_temp,local_variables()))
	param_bcc = alltrim(a5_eval_expression(em.bcc_temp,local_variables()))
	message_type = em.style

	'Template message may have mail merge commands. a5_mailmerge() evaluates the mail merge commands.   
	param_message = a5_mailmerge(em.message_body_temp,form_name)

	'Evaluate any mail-merge commands in the message body. 
	param_message = a5_mailmerge(param_message,form_name)

	'Put attachments into a zip file if more than one attachment is specified
	IF w_count(em.attachments_temp,crlf()) > 1 THEN 
		zipfile = file.temp_create(file.temp_path_get())+".zip"
		zip_files(zipfile,em.attachments_temp,.t.)
		param_attachments = zipfile
	  ELSE
		param_attachments = em.attachments_temp
	END IF
	'Send the e-mail using the external e-mail client
	email_client_external(param_to,param_subject,param_message,param_attachments,param_cc,param_bcc)

END FUNCTION