Compare table function to display in 2 columns

[MikeData]

This is the code for a function to display the diffeence between 2 tables.
It has been great. I could use an improvement.
Can the display be in 2 columns if the results are longer than 15 items?

Here is the code:

table1 = ui_get_table("Table One","Table")
table2 = ui_get_table("Table Two","Table")


'table1 = ui_get_table("tmonuord.dbf","Table")
'table2 = ui_get_table("monuordxx.dbf","Table")

if table1 = "" .or. table2 = "" .or. (table1 = table2)
ui_msg_box("Alert","Invalid table selection.")
end if

struct1 = table.external_field_name_get(table1,"N,T,W,D,R")
struct2 = table.external_field_name_get(table2,"N,T,W,D,R")

found_same = word_in_common(struct1,struct2,crlf())
ui_msg_box("Same fields",found_same)

unq_to_table1 = word_subtract(struct1,found_same,crlf())
ui_msg_box("Only in "+table1+" (or different.)",unq_to_table1)

unq_to_table2 = word_subtract(struct2,found_same,crlf())
ui_msg_box("Only in "+table2+" (or different.)",unq_to_table2)

[aschone]

Re: Compare table function to display in 2 columns

This may work for you

vTextC = <<%str%
#1
#2
#3
#4
#5
#6
#7
#8
#9
#10
#%str%
?

?f_WrapText( vTextC, 4)
= 
1	5
2	6
3	7
4	8
 	9
 	10

?f_WrapText( vTextC, 5)
= 
1	6
2	7
3	8
4	9
5	10

?f_WrapText( vTextC, 6)
= 
1	7
2	8
3	9
4	10
5	
6

'Date Created: 31-Jan-2012 05:43:17 PM
'Last Updated: 31-Jan-2012 05:43:17 PM
'Created By  : andy
'Updated By  : andy
FUNCTION f_WrapText AS C ( vTextC AS C, vWrapN AS N )
	
	OPTION STRICT
	OPTION ENCRYPTED_TOKENS
	ON ERROR GOTO ERR_HANDLER

	
	DIM vCol1C as C
	DIM vCol2C as C
	
	vCol1C = word( vTextC, 1, crlf(), vWrapN )
	vCol2C = word( vTextC, vWrapN + 1, crlf(), Line_count(vTextC) - vWrapN )
	
'	ui_msg_box("",vCol1C)
'	ui_msg_box("",vCol2C)
	

	DIM vCount_Col1N as N
	DIM vCount_Col2N as N
	vCount_Col1N = line_count(vCol1C)
	vCount_Col2N = line_count(vCol2C)
	
	DIM vMaxLen_Col1N as N
	FOR EACH foo in vCol1C
		IF vMaxLen_Col1N < len(foo.value) THEN
			vMaxLen_Col1N = len(foo.value)
		END IF
	NEXT
	
	DIM vCountN as N
	vCountN = max( vCount_Col1N, vCount_Col2N )
	
	DIM vReturnC as C
	DIM vWord_Col1C as C
	DIM vWord_Col2C as C

	DIM x as N
	FOR x = 1 to vCountN
		IF x <= vCount_Col1N THEN
			vWord_Col1C = word(vCol1C,x,crlf())
		ELSE
			vWord_Col1C = ""
		END IF

		IF x <= vCount_Col2N THEN
			vWord_Col2C = word(vCol2C,x,crlf())
		ELSE
			vWord_Col2C = ""
		END IF
		
		vReturnC = vReturnC + crlf() + padr(vWord_Col1C,vMaxLen_Col1N," ") + chr(9) + vWord_Col2C
	NEXT
	f_WrapText = vReturnC
	END
'-----------------------------------
'Error handler
'-----------------------------------
ERR_HANDLER:
	DIM vErrN as N 
	DIM vMsgC as C
	vErrN = error_code_get()

	vMsgC = "Error # "+ vErrN + crlf() + error_text_get(vErrN)
	vMsgC = vMsgC + crlf() + "Script: " + error_script_get()
	vMsgC = vMsgC + crlf() + "Line #: " + error_line_number_get()

	trace.writeln(vMsgC)

	ui_msg_box("Error", vMsg,UI_ATTENTION_SYMBOL)
	vMsgC = ""
	
	END  
	
END FUNCTION

[MikeData]

Re: Compare table function to display in 2 columns

Thanks for responding.
How do I incorporate supplied code to the "table compare" code?

[Stan Mathews]

Re: Compare table function to display in 2 columns

Rather nice, Andrew.

Mike,


Having saved/created the funtion in your database you would use it like

found_same = word_in_common(struct1,struct2,crlf())
found_same = f_WrapText(found_same, 15)
ui_msg_box("Same fields",found_same)

Instead of hard coding the 15 into the script you could also compute the total line count and divide it by two to balance the columns.

found_same = word_in_common(struct1,struct2,crlf())
fs_count = line_count(found_same)
found_same = f_WrapText(found_same, ceiling(fs_count/2))
ui_msg_box("Same fields",found_same)

[MikeData]

Re: Compare table function to display in 2 columns

Stan, thanks, that did it.
I will review it and post the cnew code.

[MikeData]

Re: Compare table function to display in 2 columns

Herer is the new code.


table1 = ui_get_table("Table One","Table")
table2 = ui_get_table("Table Two","Table")
Dim Tbl1 as p
Dim Tbl2 as p

if table1 = "" .or. table2 = "" .or. (table1 = table2)
ui_msg_box("Alert","Invalid table selection.")
end if

struct1 = table.external_field_name_get(table1,"N,T,W,D,R")
struct2 = table.external_field_name_get(table2,"N,T,W,D,R")

found_same = word_in_common(struct1,struct2,crlf())
found_same = f_WrapText(found_same, 25 )
ui_msg_box("Same fields",found_same)

Tbl1 = word_subtract(struct1,found_same,crlf())
unq_to_table1 = word_subtract(struct1,found_same,crlf())
unq_to_table1 = f_WrapText(found_same, 25 )
ui_msg_box("Only in "+table1+" (or different.)",unq_to_table1)

Tbl2 = word_subtract(struct1,found_same,crlf())
unq_to_table2 = word_subtract(struct2,found_same,crlf())
unq_to_table2 = f_WrapText(found_same, 25 )
ui_msg_box("Only in "+table2+" (or different.)",unq_to_table2)

[Ton Spies]

Re: Compare table function to display in 2 columns

Hi Mike,

It would be nice if you could add this code with a little instruction/description as a useful function to the Code Archive Section.
TIA
Ton

[MikeData]

Re: Compare table function to display in 2 columns

No Problem. See it here:

http://msgboard.alphasoftware.com/al...y-in-2-columns

[CALocklin]

Re: Compare table function to display in 2 columns

You might also want to go here and check out Jim Chapman's "Compare Apps" routine. It compares a LOT more than just the table structures. It basically compares everything. It even tells you if the location of objects on the layouts is different; e.g., if you moved a button.

I just used it last night and it saved a HUGE amount of time comparing two different versions of the same app. I was pretty sure that the only differences were (a) one form that the customer changed in his version and (b) 4 scripts that I changed in my version. Using this routine it was very easy and took only about 10-15 minutes to verify that I was wrong - I had changed 5 scripts. (Maybe it was less than 10 minutes but it seemed that long. I didn't time it.)

[MikeData]

Re: Compare table function to display in 2 columns

Nice to hear from you Cal.
Yes, this is a great addition to our collections of utilities.
This will help a great deal.