Access PDF Documents

[nugget3825]

I hope there is a simple solution to this one.

I have many documents that are in PDF format. I need to be able to
1. Prompt for a list of names stored in a folder, and
2. Display a list of documents therein contained, and
3. Return to the Main Menu, and either select another document or exit.

I know it's possible. Stan Mathews originally wrote something for me when I was with the State but, it's been many years since Stan provided the code.

Any help will be GREATLY appreciated.

Thanks,

Lar

[Ronald Anusiewicz]

This should get you started. Not polished but you can tweak this to meet your needs.

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vcPDF as c
DIM SHARED varC_result as C
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("PDF Search",<<%dlg%
{region}
Type prompt here:| [%p=ui_get_file("","File Type (*.pdf)",vcPDF,"X");I=$a5_smart_file%.100vcPDF];
{endregion};
{line=1,0};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%)

'Open file: vcPDF.pdf
if file.exists(vcPDF) then
    sys_open(vcPDF)
else
    ui_msg_box("Error Opening File","File " + vcPDF + " does not exist.",ui_stop_symbol)
end if

​

[nugget3825]

Ron,

Thank you so much ! I think I will be able to move forward, WITH YOUR HELP !

Lar

[nugget3825]

Ron,

Just posted and tried your code but it now says "Script contains errors at line 23"

???

[Ronald Anusiewicz]

You need to show me your code as the script I gave you only has 21 lines.

[nugget3825]

Ron,

I believe I found an errant ? on the last line. Must of been added in error. If I wanted to add a question in the code, is that simple enough ? Such as, show a list of the files that match a partial search ?

Lar

[Ronald Anusiewicz]

One can do a search using the search box in the upper right hand corner of the file explorer.

image.png

[Ted Giles]

Well I know Browses are unfashionable, but may I suggest a Set with links on the user.
People and PDF''s.
Then 2 Browses on a Form, People list and corresponding PDF''s will be shown.
You can scroll the people list or add a Search feature. When a person is selected, the corresponding PDF''s will present.
click one of those and they will display.

[Mike Wilson]

I believe this is what you want:

'SCRIPT VARIABLES
dim vLex as C=comma_to_crlf(".,..")
dim vroot_fldr as C="E:\Scans\Invoices"+chr(92) '<<< CHANGE THIS TO MATCH YOUR CIRCUMSTANCE
dim vroot_fldr_probe as C=vroot_fldr+"*.*"
dim vL1_fldr_list as C
dim vL1_fldr_probe as C
dim vL2_PDF_file_list as C
dim vfilename as C

'DIALOG STRUCTURE
dim dlg_title as C=" SEARCH PDF FILES "
dim dlg_body as C
dim dlg_code as C

'DIALOG FIELD VARIABLES
dim vL1_fldr_pick as C
dim vpdf_pick as C

'BUILD DIALOG
dlg_body = <<%dlg%
{startup=init}{background=Light Tan}{xmargin=3,3}{ymargin=1,1}

{comment= TOP BUTTONS}
{region}{justify=right}<%T=Open File;B=T;I=$$file.open%4,1!file_open>
{sp=3}<%T=Close Dialog;B=T;I=$$generic.exit%4,1!exit>
{endregion};{justify=left}

{comment= LEVEL 1 FOLDERS }
{region}{font=arial,8,bi}{frame=1,1: Level 1 Folders }{font=Arial,10}
[.40,21vL1_fldr_pick^#vL1_fldr_list!evL1_*];
{endregion}

{comment= LEVEL 2 PDF FILES }
{region}{font=arial,8,bi}{frame=1,1: Level 2 Files }{font=Arial,10}
[.90,21vpdf_pick^#vL2_PDF_file_list];
{endregion};{lf};
%dlg%

'DIALOG CODE
dlg_code=<<%code%
'INIT
IF a_dlg_button="init"
vL1_fldr_list=filefind.get(vroot_fldr_probe,FILE_FIND_DIRECTORY)
vL1_fldr_list=word_subtract(vL1_fldr_list,vLex,crlf())
sys_send_keys("{HOME}")
a_dlg_button=""
END IF

'ACTION FOR L1 FOLDER PICK >> GET PDF FILES IN SELECTED L1 FOLDER
IF left(a_dlg_button,5)="evL1_"
if a_dlg_button="evL1_change"
vL1_fldr_probe=vroot_fldr+vL1_fldr_pick+chr(92)+"*.pdf"
vL2_PDF_file_list=filefind.get(vL1_fldr_probe,FILE_FIND_NOT_DIRECTORY)
end if
a_dlg_button=""
END IF

'OPEN SELECTED PDF FILE
IF a_dlg_button="file_open"
if vL1_fldr_pick<>"" .and. vpdf_pick<>""
vfilename=vroot_fldr+vL1_fldr_pick+chr(92)+vpdf_pick
sys_open(vfilename)
else
dlg_msg_box("ERROR","Selection of both Primary folder and a PDF file is required before opening")
end if
end if

'EXIT
if a_dlg_button="exit"
ui_modeless_dlg_close(dlg_title)
end if
%code%

'GENERATE DIALOG
vR=ui_modeless_dlg_box(dlg_title,dlg_body,dlg_code)​

[nugget3825]

Mike,

It sounds like exactly what I had in mind. I installed the software and attempted to run. The software runs but, there is no data. How do I get the data into the search folder ?

Thank you for your work on this !

Lar

[Mike Wilson]

Lar,
From what you wrote, you seem to suggest you have a directory and file structure like below. For sake of explanation, I will arbitrarily assign that the NAMES folder is on the C:\ drive in a folder named MYAPP.. Therefore, the line 3 of the code I gave would be:
dim vroot_fldr as C="C:\MYAPP\NAMES"+chr(92)

NAMES
..........|____Jim
..........| ...........|___doc 1.pdf
..........|............|___doc 2.pdf
......... |........... |___doc 3.pdf
..........|____Bill
......................|___doc 1.pdf
......................|___doc 2.pdf
......................|___doc 3.pdf

[nugget3825]

Mike,

I had all of the pieces ready to upload to you and found out that Alpha does does cache the previous email.
So, I'll do it this way.

In pieces

[nugget3825]

These are the first few lines that I modified:



dim vLex as C=comma_to_crlf(".,..")

' dim vroot_fldr as C="E:\Scans\Invoices"+chr(92) '<<< CHANGE THIS TO MATCH YOUR CIRCUMSTANCE
dim vroot_fldr as C="C\LEGAL\client.dbf"+chr(92) 'Mike: Changes made here

dim vroot_fldr_probe as C=vroot_fldr+"*.*"
dim vL1_fldr_list as C
dim vL1_fldr_probe as C
dim vL2_PDF_file_list as C
dim vfilename as C

[nugget3825]

Mike,

So, here's some actual data:

The structure is:

C:\LEGAL\CLIENT.DBF Larry Carraher
C:\LEGAL\SCANS\CASE123.PDF
C:\LEGAL\SCANS\CASE234.PDF

C:\LEGAL\CLIENT.DBF John Carraher
C:\LEGAL\SCANS\CASE345.PDF
C:\LEGAL\SCANS\CASE456.PDF
C:\LEGAL\SCANS\CASE567.PDF

Pretty much exactly as you had previously detailed

Should the file name (CLIENT.DBF) be defined that way ?

[nugget3825]

Mike,

Last entry tonight, when executed, the system should display:

Larry CASE123
CASE234
John CASE345
CASE456
CASE567

When I select Larry, system should display CASE123 & CASE234 and display the PDF selected
And, when I select, if selected, John, the system should display the CASE345, CASE456, and CASE567 and whichever PDF I selected.

Thank you for your help today. You have made the issues understandable ! Thank you !

Lar