Network Optimization

[Gene FitzPatrick]

I just ventured into a private home network and followed the instructions in the V12 Runtime + doc for network optimization. Two things; one, the line on page 28 that begins with create_shadow2 has three arguments. It only needs two. The second argument is inappropriate. Two, ever since trying to use this, every build I make using the same routine I have used for a decade returns access errors when trying to run the installed app. I tried installing my app on a single machine that ran it before this and it still fails. Did the optimization routine mess something up? If so, how can I correct whatever it messed up?

My network is private and has a server, two PC's and a printer. I know I have permission issues as I can not print from more than one of the PC's.

I know this is a loaded submit but any help would be appreciated. Thanks.

[armasoft]

What version of V12 are you using? Doc changed some time between 3670/4684 and 5887/5315. code for later versions below

dim master_db_name as C
dim shadow_db_name as C
master_db_name = ""
shadow_db_name = ""
ui_modeless_dlg_box("Install MyAppName",<<%dlg%
{can_exit=exit}
{lf};
Specify the filename of the master copy of the application:;
[%P=ui_get_file("Select file","(*.adb)",master_db_name)%.100master_db_name];
{lf};
<Click Here to Start Install!oK?.not.(master_db_name="")> <Cancel!cancel>;
%dlg%,<<%code%
if a_dlg_button = "cancel" then
ui_modeless_dlg_close("Install MyAppName")
a_dlg_button = ""
end if
if a_dlg_button = "oK" then
if file.exists(master_db_name) = .f. then
ui_msg_box("Error","Master Database not found.")
else
shadow_db_name = a5.Get_Name()
a5.Load(master_db_name)
create_shadow2(shadow_db_name,.t.)
End If
ui_modeless_dlg_close("Install MyAppName")
end if
%code%  )
​

I suspect the doc change missed at some point then sorted on a later release.

Past experience suggests easiest way to set up network optimisation is to open the master app on one PC, then select 'Tools->Network Optimize'. Complete the form as needed then 'Create Shadow Workspace'. Provided you use the same path for the master you can then copy the ewhole shadow folder to the other PCs.

[Gene FitzPatrick]

My 'About' shows version 12.4.6.4.7, which is the latest stable build release. I will try your suggestion, thanks. One clarification though. When you state "on one PC" are you referring to the server?

[armasoft]

Open the app on any PC and create the shadow including any extra files required. You can then just copy this folder to any other PC on the netwprk providied it accesses the share on the server using the same path.

[Gene FitzPatrick]

That works great! How can I make it available in a runtime environment?

[armasoft]

Just install runtime on each PC as needed and point it to the shadow copy.

[Ronald Anusiewicz]

I got some help with this a number of years ago. I modified this script to automate the whole process. This script is run by a hidden button in my application. After installing the runtime, I connect directly to the main application. I click on my hidden button and run this script. This script creates the shadow, makes a new shortcut, closes the application and then starts the new shadowed application. To use this for your application, one can go in and tweak the code where needed.

'Date Created: 20-Aug-2015 08:33:45 AM
'Last Updated: 16-Feb-2023 10:45:01 AM
'Created By  : verboopa2
'Updated By  : Ron

'------------
'ShadowCreate
'------------
DIM DialogTtl as C = "Create Shadow Database (ShadowCreate)"

'----------------
'// do checks  --
'----------------
IF a5.Get_Master_Name()                            'verify this is not a shadow database
    ui_msg_box(DialogTtl,\
    *concat_lines("This is already a Shadow Database. A Shadow can not be built from a Shadow"),\
    UI_ATTENTION_SYMBOL+UI_OK)
    end
end if
'--------------------------------------


'--------------------------------------
'\\ explain option and get file name --
'--------------------------------------
DIM Shortcut_Name as C = "Work Orders & Invoices"        'default shortcut Title
DIM Result as C                                    'Result of Dialog Box
DIm Mess as C                                    'Check messages to user
DIM ShadowName as C                                'Name of Shadow database to build
DIM DefaultFolder as C                            'the shadow folder's name
DIM RT_EXE as C                                    'returns the path of the Alpha Five runtime executable
DIM ShortCut as C                                'determine all settings for creating a desktop shortcut
DIM Description as C
DIM StartIn as C
DIM AppDataMaster as C
DIM app_startup as C
DIM Desktop as C
DIM Icon as C                                    'Folder to build shadow database in
DIM Target as C

RT_EXE = a5.Get_Exe_Path() + "\\"
DefaultFolder = RT_EXE + "Shadow" + chr(92) + file.filename_parse(a5.Get_Name(),"n")
Target = RT_EXE + "alpha5.exe"

Dialog = <<%dlg%
{units=f}{font=calibri,11}{ysize=.3}{xmargin=2,2};;

{region}
{wrap=95}
Build a Shadow \(Network Optimized\) Database.;;

{region};
Shortcut Name:  A new Shortcut will be created on the desktop for the Shadow Database.;
[.40Shortcut_name];
{endregion};;

{region};
Shortcut Icon:  It is recommended to use a custom icon stored on the server.  In the future, this missing custom Icon will indicate a loss of connectivity to the Server.;
[%p=ui_get_file("Runtime Folder","Text (*.ico)",Icon,"");I=$a5_smart_file%.100Icon];
{endregion};;

{region};
A5VxxRT.Exe Target:;
[%p=ui_get_file("Runtime EXE File","Text (*.exe)",Target,"");I=$a5_smart_file%.65Target];
{endregion};;

{region};
Specify an empty folder and create the shadow database.  I recommend the word Shadow be in the folder path.;;
[%p=ui_get_path("Folder for Shadow Database",DefaultFolder,"");I=$a5_folder%.100DefaultFolder];
{endregion};;;

{region}
{justify=center}
<10,1.5&Proceed!Proceed?right(Icon,3)="ico">   <*10,1.5&Cancel!CANCEL>
{endregion};
%dlg%

Code =<<%code%
    if a_dlg_button = "proceed" then                             'Used to proceed after dialog            
        Folder = DefaultFolder
        Mess = ""                                                'but first do checks while dialog is on screen
        IF Right(Folder,1) <> "\\"
            Folder = Folder + "\\"
        end if
        ShadowName = file.filename_parse(Folder,"dp") + file.filename_parse(A5.GET_NAME(),"ne")
        IF isnull(Folder)
            Mess = *concat_lines(Mess,"A Folder Must be specified")
        end if
        IF file.filename_parse(Folder,"p") ="\\"
            Mess = *concat_lines(Mess,"Shadow Database will not be created in Root directory")
        end if
        IF .NOT. isnull(Mess)                                    
            ui_msg_box(DialogTtl,Mess,UI_ATTENTION_SYMBOL+UI_OK)
            a_dlg_button = ""                                    'failed checks so we will no exit dialog
        end if                                
    end if
%code%

Result = ui_dlg_box(DialogTtl,Dialog,Code)                        'present Dialog
if Result <>"Proceed" then                                        'do we proceed
    end
end if

'debug(1)

IF FILE.DIR_CREATE_RECURSE(DefaultFolder)
    Folder = DefaultFolder
else
    ui_msg_box(DialogTtl,"Unable to create suggested default folder",UI_ATTENTION_SYMBOL+UI_OK)
    end
end if

'------------------
'// Now build it --
'------------------
AppDataMaster = :a5.Get_Path()
ShortCut = win_special_folder("Desktop")+ "\\" + Shortcut_Name
Description = "Launch the Program " + Shortcut_Name
StartIn = file.filename_parse(ShadowName,"dp")
app_startup = DefaultFolder + "app.startup"

''create the file app.startup and enter a line to hide the splash screen
dim file_pointer as P
file_pointer = file.create(StartIn + "App.Startup",FILE_RW_EXCLUSIVE)
file_pointer.write_line("-NOSPLASH")
file_pointer.flush()
file_pointer.close()

Arg = quote(ShadowName) + " -INCLUDE=" + quote(StartIn + "App.Startup")

sResult = win_create_shortcut(ShortCut,Target,Description,StartIn,Icon,Arg)

''create the shadow, close the app and reopen using the shadow
create_shadow2(ShadowName, .T., .T.)

END  ​

[Tim Sutherland]

I got some help with this a number of years ago. I modified this script to automate the whole process. This script is run by a hidden button in my application. After installing the runtime, I connect directly to the main application. I click on my hidden button and run this script. This script creates the shadow, makes a new shortcut, closes the application and then starts the new shadowed application. To use this for your application, one can go in and tweak the code where needed.

'Date Created: 20-Aug-2015 08:33:45 AM
'Last Updated: 16-Feb-2023 10:45:01 AM
'Created By : verboopa2
'Updated By : Ron

'------------
'ShadowCreate
'------------
DIM DialogTtl as C = "Create Shadow Database (ShadowCreate)"

'----------------
'// do checks --
'----------------
IF a5.Get_Master_Name() 'verify this is not a shadow database
ui_msg_box(DialogTtl,\
*concat_lines("This is already a Shadow Database. A Shadow can not be built from a Shadow"),\
UI_ATTENTION_SYMBOL+UI_OK)
end
end if
'--------------------------------------


'--------------------------------------
'\\ explain option and get file name --
'--------------------------------------
DIM Shortcut_Name as C = "Work Orders & Invoices" 'default shortcut Title
DIM Result as C 'Result of Dialog Box
DIm Mess as C 'Check messages to user
DIM ShadowName as C 'Name of Shadow database to build
DIM DefaultFolder as C 'the shadow folder's name
DIM RT_EXE as C 'returns the path of the Alpha Five runtime executable
DIM ShortCut as C 'determine all settings for creating a desktop shortcut
DIM Description as C
DIM StartIn as C
DIM AppDataMaster as C
DIM app_startup as C
DIM Desktop as C
DIM Icon as C 'Folder to build shadow database in
DIM Target as C

RT_EXE = a5.Get_Exe_Path() + "\\"
DefaultFolder = RT_EXE + "Shadow" + chr(92) + file.filename_parse(a5.Get_Name(),"n")
Target = RT_EXE + "alpha5.exe"

Dialog = <<%dlg%
{units=f}{font=calibri,11}{ysize=.3}{xmargin=2,2};;

{region}
{wrap=95}
Build a Shadow \(Network Optimized\) Database.;;

{region};
Shortcut Name: A new Shortcut will be created on the desktop for the Shadow Database.;
[.40Shortcut_name];
{endregion};;

{region};
Shortcut Icon: It is recommended to use a custom icon stored on the server. In the future, this missing custom Icon will indicate a loss of connectivity to the Server.;
[%p=ui_get_file("Runtime Folder","Text (*.ico)",Icon,"");I=$a5_smart_file%.100Icon];
{endregion};;

{region};
A5VxxRT.Exe Target:;
[%p=ui_get_file("Runtime EXE File","Text (*.exe)",Target,"");I=$a5_smart_file%.65Target];
{endregion};;

{region};
Specify an empty folder and create the shadow database. I recommend the word Shadow be in the folder path.;;
[%p=ui_get_path("Folder for Shadow Database",DefaultFolder,"");I=$a5_folder%.100DefaultFolder];
{endregion};;;

{region}
{justify=center}
<10,1.5&Proceed!Proceed?right(Icon,3)="ico"> <*10,1.5&Cancel!CANCEL>
{endregion};
%dlg%

Code =<<%code%
if a_dlg_button = "proceed" then 'Used to proceed after dialog
Folder = DefaultFolder
Mess = "" 'but first do checks while dialog is on screen
IF Right(Folder,1) <> "\\"
Folder = Folder + "\\"
end if
ShadowName = file.filename_parse(Folder,"dp") + file.filename_parse(A5.GET_NAME(),"ne")
IF isnull(Folder)
Mess = *concat_lines(Mess,"A Folder Must be specified")
end if
IF file.filename_parse(Folder,"p") ="\\"
Mess = *concat_lines(Mess,"Shadow Database will not be created in Root directory")
end if
IF .NOT. isnull(Mess)
ui_msg_box(DialogTtl,Mess,UI_ATTENTION_SYMBOL+UI_OK)
a_dlg_button = "" 'failed checks so we will no exit dialog
end if
end if
%code%

Result = ui_dlg_box(DialogTtl,Dialog,Code) 'present Dialog
if Result <>"Proceed" then 'do we proceed
end
end if

'debug(1)

IF FILE.DIR_CREATE_RECURSE(DefaultFolder)
Folder = DefaultFolder
else
ui_msg_box(DialogTtl,"Unable to create suggested default folder",UI_ATTENTION_SYMBOL+UI_OK)
end
end if

'------------------
'// Now build it --
'------------------
AppDataMaster = :a5.Get_Path()
ShortCut = win_special_folder("Desktop")+ "\\" + Shortcut_Name
Description = "Launch the Program " + Shortcut_Name
StartIn = file.filename_parse(ShadowName,"dp")
app_startup = DefaultFolder + "app.startup"

''create the file app.startup and enter a line to hide the splash screen
dim file_pointer as P
file_pointer = file.create(StartIn + "App.Startup",FILE_RW_EXCLUSIVE)
file_pointer.write_line("-NOSPLASH")
file_pointer.flush()
file_pointer.close()

Arg = quote(ShadowName) + " -INCLUDE=" + quote(StartIn + "App.Startup")

sResult = win_create_shortcut(ShortCut,Target,Description,StartIn,Icon,Arg)

''create the shadow, close the app and reopen using the shadow
create_shadow2(ShadowName, .T., .T.)

END ​

Thanks for sharing this Ron. I've always thought about adding something like this but didn't know where to start.

After a few tweaks to match our system, it works great!

[martinwcole]

A wise man (Bill Parker, an Alpha sage) once told me he didn't use optimization. And that the only difference in performance is in the original load. After that there is no appreciable difference.
At the time I had a big Medical app that was giving me fits with optimization, but after the change I never had a problem.

[Tim Sutherland]

A wise man (Bill Parker, an Alpha sage) once told me he didn't use optimization. And that the only difference in performance is in the original load. After that there is no appreciable difference.
At the time I had a big Medical app that was giving me fits with optimization, but after the change I never had a problem.

I have been running an extensive desktop app via shadow for years. Outside of occasional unexplainable, random errors, it runs pretty well with about 8 users active at a time.

The above inspired me to try running all the desktops directly from the server and eliminate the shadow to see what happens. We have all brand new hardware, including the server. We also have a 1,000 Mbps network. I came in early and eliminated the shadow on each desktop without notifying any of my employees.

By noon, I had multiple complaints from several users asking why the system was running slow. They all experienced a slight delay whenever they attempted to open forms, enter data, etc. It caused the fast typers/clickers the most trouble as they were having issues having to click buttons multiple times as the first click hadn’t executed yet as it normally does. The lag was causing issues as they would already be several clicks in and the first click still hadn’t executed.

Needless to say, I shut the system down and recreated the shadow on all the desktops and everyone was happy again.

I suspect if our environment always ran without the shadow, nobody would know otherwise and all would fine.

Your mileage may vary, but that was my experience yesterday.

At least it was quite easy to recreate the shadows, since I just implemented Ron’s auto creation script into our app the day before.

[Al Buchholz]

The best performance and least number of issues in the desktop environment in my never to be humble opinion is each user having a remote desktop connection to a server where everything runs on the server and the user has a window on their desktop to the server.

Shadow not needed, data access and processing is much faster, less network issues and traffic, and a server is more stable.

Also called a thin client.

[Ted Giles]

I got in trouble at a site when I refered to a "Thick Client" - true.