Contradictory error: table not in change mode,table already in change mode

[shapse]

Please see GREEN highlighted code below. I've include the full code just in case something done previously interferes with later code.

I am getting contradictory error messages about the table either NOT in change mode or the table is already in change mode depending whether or not tbl.change_begin() is utilized in the code. What am I missing? thanks.

dim filter as c
dim order as c
dim options as c
dim vLast as c
dim vFirst as c
dim vInitial as c

if new_client = .t.
end
end if

vLast = alltrim(ptinfo->last)
vFirst = alltrim(ptinfo->first)
vInitial = ptinfo->initial

filter = "alltrim(Last) + alltrim(First) + Initial = " +quote(vlast+vfirst+vinitial)
order = "Last+First+Initial"
options = ""


dim tblp as p
dim qryp as p
dim reccount as n
dim code as a
dim result as a

tblp = table.open("ptinfo")
qryp =tblp.query_create("N",filter,order)
reccount = qryp.records_get()
code = UI_OK_CANCEL + UI_ATTENTION_SYMBOL + UI_SECOND_BUTTON_DEFAULT

if reccount > 0
ui_msg_box("Duplicate Patient!","Patient has already been entered.")
topparent.cancel()
end
end if

' start ui_msg_box actions
response = ui_msg_box("Client's name changed!", "Keep change? ", code)

if response = UI_OK_SELECTED


dim tbl as p
dim index1 as p
reccount = 1
tbl = table.open("records")
index1 = tbl.index_primary_put("alltrim")

tbl.change_begin()

while reccount > 0
reccount = tbl.fetch_find(vname)
tbl.Last = vLast
tbl.First = vFirst
tbl.Initial = vInitial
end while

tbl.change_end()

elseif response = UI_CANCEL_SELECTED then

'Cancel changes to record in current form.
topparent.cancel()

end if
' end ui_msg_box actions

[Stan Mathews]

Re: Contradictory error: table not in change mode,table already in change mode

Steven,

The context that any code runs in is important. This seems to be event code for some event of a form based on a set? Which event? You don't have a .close() statement for any of the table pointers established. It might be better to use table.current(n) to obtain pointers to the tables opened by the set but that's hard to say since the context is not known. With table.current() rather than table.open() the pointers aren't closed in the script.

[shapse]

Re: Contradictory error: table not in change mode,table already in change mode

Stan,

Thanks for you reply on a Sunday.

The overall goal is to change the person's name in the "records" table when it is changed in the "ptinfo" table. Records to Ptinfo is a many to one relationship. Perhaps there's an easier way to do this?

The context is this: a form for table "ptinfo" which contains first,last and initial fields is open on screen. If any of these three field values are changed, it triggers the code in first post. The (global) variable "new_client" is set to .F. prior to this script being called. The global variable "vname" is established when the record appears in the form for ptinfo. The script then checks to see it the changed name of the patient matches any existing patient. If so, the change is not allowed. Otherwise, the user is asked if he/she intended the change, and if so, the code is executed which changes the patient's name in the "records" table to match the new name. However, the coder errors out as originally described.

[shapse]

Re: Contradictory error: table not in change mode,table already in change mode

Stan,

Adding .close() statements allowed the code to work. However, in the below code, only one record is changed before the tbl.fetch_find(vname) returns a negative record number indicating no more records were found. However, this is false. What am I doing wrong?

dim tbl as p
dim index1 as p
reccount = 1
tbl = table.open("records")
index1 = tbl.index_primary_put("alltrim")
tbl.fetch_first()
while reccount > 0
reccount = tbl.fetch_find(vname)
tbl.change_begin()
tbl.Last = vLast
tbl.First = vFirst
tbl.Initial = vInitial
tbl.change_end()
end while
tbl.close()

[Tim Kiebert]

Re: Contradictory error: table not in change mode,table already in change mode

I think the fetch_find is always finding the same record because the updated index (caused by the record update) is not being applied to the current table pointer. Have never noticed that before because I have not used the construct that you have used.

You will probably find that if you place the tbl.index_primary_put("alltrim") before the fetch_Find(vname) in the while section that the tbl pointer will be set to the new index values. But I think that would be an unnecessary overhead.

For what it is worth this is how I do it

dim tbl as p
tbl = table.open("records")
tbl.index_primary_put("alltrim")
'No need to fetch_first() because fetch_find finds the first matching record
If tbl.fetch_find(vname) > 0 then   
    dim test_expression as C
    test_expression = what_ever_expression_gives_you_vname  'gets data from the just found record
                                                            'usually the same expression used to create the index 'alltrim'
    while test_expression = vname  
        tbl.change_begin()
        tbl.Last = vLast
        tbl.First = vFirst
        tbl.Initial = vInitial
        tbl.change_end()
        tbl.fetch_next()
        test_expression = what_ever_expression_gives_you_vname 'sets the test_expression to the data of the next record
    end while
End If
tbl.close()

or

dim tbl as p
dim qry as p
tbl = table.open("records")
qry = tbl.query_create("TN","what_ever_expression_gives_you_vname="+quote(vname),"")
IF qry.records_get() > 0 THEN
    tbl.fetch_first()
    WHILE .not. tbl.fetch_eof()
        tbl.change_begin()
        tbl.Last = vLast
        tbl.First = vFirst
        tbl.Initial = vInitial
        tbl.change_end()
        tbl.fetch_next()
    END WHILE
END IF
tbl.close()