Dialog box - change default variable value based on selection

[Mike Reed]

I have a dialog box with these variables
v_stmt_type - this is a list of the types of statements that the company will run
V_stmt_days - the default is set to 0 and is used in the aging of accounts receivable and statement runs.

What I need is for the variable v_stmt_days to change to 45 when the user selects "Management Company Statements" in the v_stmt_type.
See the attached image for a better explanation.

So the question, how do I code the dialog box to do this?

Thanks

[Davidk]

Re: Dialog box - change default variable value based on selection

Xdialog is still pretty much voodoo to me but...

IF a_dlg_button = "v_stmt_type_change"
IF v_stmt_type = "Management Company Statement"
v_stmt_days = 45
END IF
END If

Post your dialog box code so we can see specifically.

[Mike Reed]

Re: Dialog box - change default variable value based on selection

Here is the code. What you wrote in your post makes sense, I don't how and where to place it.


DELETE a_v_stmt_type
DIM a_v_stmt_type[4] as c
dim temp_list as c
temp_list = <<%list%
All Complex Statements
Complex Statement - Select
Lien Statement
Management Company Statement
%list%

a_v_stmt_type.initialize(temp_list)
' this next line would have to have some static data in it to run properly, since you don't have the 'accounts' table.
auto_list_v_stmt_cmplx = table.external_record_content_get("accounts","padr(Complex,70,\" \") + \" | \" + comid","complex","balance > 0 .and. unique_key_value()")

temp_count = w_count(auto_list_v_stmt_cmplx,crlf())
DELETE a_v_stmt_cmplx
DIM a_v_stmt_cmplx[temp_count] as c
a_v_stmt_cmplx.initialize(auto_list_v_stmt_cmplx)
heading_string = "Make your selections below"
footer_string = "Click 'OK' to continue or 'Cancel' to quit"
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("STATEMENT PREPARATION",<<%dlg%
{region}
{text=65,1:heading_string};
{endregion};
{region}
Statement Type:| [.40,4v_stmt_type^#a_v_stmt_type];
{condition_begin=v_stmt_type = "All Complex Statements"}
Print Complexes Marked to Exclude:| (40vexclude);
{condition_end}
{condition_begin=v_stmt_type <> "Lien Statement" }
Print Statements Only:| (40v_stmt_print);
List Paid Amount:| (40v_stmt_paid);
{condition_begin=v_stmt_paid}
Beginning Date Paid:| [%DATE;P=popup.calendar(dtoc(vbeg));I=popup.calendar%.20vbeg!vbeg_*];
Ending Date Paid:| [%DATE;P=popup.calendar(dtoc(vend));I=popup.calendar%.20vend!vend_*];
{condition_end}
Days Due \(0 for all):| [%z%.3v_stmt_days];
{condition_begin=v_stmt_print = .f.}
Return Email Address:| [.50v_stmt_rtn];
Blind Carbon Copy Email Address:| [.50v_stmt_bcc];
Email/Fax Message:| [%mw%.40,5v_stmt_msg];
{condition_end}
{condition_end}
{condition_begin=(v_stmt_type="Complex Statement - Select" .and. v_stmt_days = 0 ).or. v_stmt_type = "Lien Statement" }
Select Complex\(s):| [%M;d;O={@@}%.50,15v_stmt_cmplx^#a_v_stmt_cmplx];
{condition_end}
{endregion};
{region}
{text=65,1:footer_string};
{endregion};
{line=1,0};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%)

[Davidk]

Re: Dialog box - change default variable value based on selection

You wouldn't need to change much...

Here's the full code... then I'll explain the changes...

DELETE a_v_stmt_type 
DIM a_v_stmt_type[4] as c
dim temp_list as c 
temp_list = <<%list%
All Complex Statements
Complex Statement - Select
Lien Statement
Management Company Statement
%list%

a_v_stmt_type.initialize(temp_list)
' this next line would have to have some static data in it to run properly, since you don't have the 'accounts' table.
auto_list_v_stmt_cmplx = table.external_record_content_get("accounts","padr(Complex,70,\" \") + \" | \" + comid","complex","balance > 0 .and. unique_key_value()")

temp_count = w_count(auto_list_v_stmt_cmplx,crlf())
DELETE a_v_stmt_cmplx
DIM a_v_stmt_cmplx[temp_count] as c
a_v_stmt_cmplx.initialize(auto_list_v_stmt_cmplx)
heading_string = "Make your selections below"
footer_string = "Click 'OK' to continue or 'Cancel' to quit"
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
varC_result = ui_dlg_box("STATEMENT PREPARATION",<<%dlg%
{region}
{text=65,1:heading_string};
{endregion};
{region}
Statement Type:| [.40,4v_stmt_type^#a_v_stmt_type!tc_*];
{condition_begin=v_stmt_type = "All Complex Statements"}
Print Complexes Marked to Exclude:| (40vexclude);
{condition_end}
{condition_begin=v_stmt_type <> "Lien Statement" }
Print Statements Only:| (40v_stmt_print);
List Paid Amount:| (40v_stmt_paid);
{condition_begin=v_stmt_paid}
Beginning Date Paid:| [%DATE;P=popup.calendar(dtoc(vbeg));I=popup.calendar%.20vbeg!vbeg_*];
Ending Date Paid:| [%DATE;P=popup.calendar(dtoc(vend));I=popup.calendar%.20vend!vend_*];
{condition_end}
Days Due \(0 for all):| [%z%.3v_stmt_days];
{condition_begin=v_stmt_print = .f.}
Return Email Address:| [.50v_stmt_rtn];
Blind Carbon Copy Email Address:| [.50v_stmt_bcc];
Email/Fax Message:| [%mw%.40,5v_stmt_msg];
{condition_end}
{condition_end}
{condition_begin=(v_stmt_type="Complex Statement - Select" .and. v_stmt_days = 0 ).or. v_stmt_type = "Lien Statement" }
Select Complex\(s):| [%M;d;O={@@}%.50,15v_stmt_cmplx^#a_v_stmt_cmplx];
{condition_end}
{endregion};
{region}
{text=65,1:footer_string};
{endregion};
{line=1,0};
{region}
<*15=ok_button_label!OK> <15=cancel_button_label!CANCEL>
{endregion};
%dlg%,<<%code%
IF a_dlg_button = "tc_change"
	If v_stmt_type = "Management Company Statement"
		v_stmt_days = 45
	Else
		v_stmt_days = 0
	end if
end if
a_dlg_button = ""
%code%)

On the line...

Statement Type:| [.40,4v_stmt_type^#a_v_stmt_type!tc_*];

I added !tc_* to the end of the variable to capture the events.

And then at the end, after %dlg% remove the paren and add

,<<%code% and the rest as you can see.

[Mike Reed]

Re: Dialog box - change default variable value based on selection

Thanks for your help. Capturing the event, was a part I missed.

One small issue remains. I copy the code over and now the OK and Cancel buttons won't respond, the only way of the dialog box is the Red X.

Thanks again,
mike

[Davidk]

Re: Dialog box - change default variable value based on selection

Put this code in after the check for the selection...

If a_dlg_button = "OK"
	ui_modeless_dlg_close("STATEMENT PREPARATION")
end if
If a_dlg_button = "CANCEL"
	ui_modeless_dlg_close("STATEMENT PREPARATION")	
end if	
a_dlg_button = ""

You have to move the a_dlg_button = "" code.

This forces the dialog to stay open so you can click away inside the dialog.

[Mike Reed]

Re: Dialog box - change default variable value based on selection

David,
Thanks again!

It works great. I don't know much about the Xdialog stuff, so this is a good learning tool for me.

Now to get it my notes, so can remember how to use it again. :)

I appreciate your help.

mike

[Davidk]

Re: Dialog box - change default variable value based on selection

I don't either... I can cobble together some changes based on existing code... but to build an xdialog... yikes... and as soon as I've done something in xdialog... I forget it.

[crimmelcp]

Re: Dialog box - change default variable value based on selection

Mike:
here is another version
'Date Created: 21-Sep-2010 12:00:41 PM
'Last Updated: 21-Sep-2010 01:49:06 PM
'Created By : E009933
'Updated By : E009933
trace.clear()
DELETE a_v_stmt_type
DIM a_v_stmt_type[4] as c
dim temp_list as c
dim global vdat1 as D
dim global vbeg as D
dim global vend as D
dim global v_stmt_days AS N
dim lv as p
lv = local_variables()

vdat1=date()
vbeg=date()
vend=date()
v_stmt_days = 0
temp_list = <<%list%
All Complex Statements
Complex Statement - Select
Lien Statement
Management Company Statement
%list%

a_v_stmt_type.initialize(temp_list)
' this next line would have to have some static data in it to run properly, since you don't have the 'accounts' table.
auto_list_v_stmt_cmplx = table.external_record_content_get("accounts","padr(Complex,70,\" \") + \" | \" + comid","complex","balance > 0 .and. unique_key_value()")

temp_count = w_count(auto_list_v_stmt_cmplx,crlf())
DELETE a_v_stmt_cmplx
DIM a_v_stmt_cmplx[temp_count] as c
a_v_stmt_cmplx.initialize(auto_list_v_stmt_cmplx)


heading_string = "Make your selections below"
footer_string = "Click 'OK' to continue or 'Cancel' to quit"
ok_button_label = "&OK"
cancel_button_label = "&Cancel"
Delete XdialogStyle
dim XDialogStyle as p
XDialogStyle.AccentColor = "White"
XDialogStyle.Color = "#153+204+255"

dlg_title=""
dlg_title="STATEMENT PREPARATION"
varC_result = ui_modeless_dlg_box(dlg_title,<<%dlg%
;
{on_key=enter}
Press Enter to advance to next field. When focus is on OK button, Enter will close the dialog;
{lf};
{watch=v_stmt_type!v_stmt_type_changed_*}
{Windowstyle=Gradient Horizontal Bottom}
{region}
{text=65,1:heading_string};
{endregion};
{region}
Statement Type:|[.40,4v_stmt_type ^#a_v_stmt_type !v_stmt_type_changed_*];
{condition_begin=v_stmt_type = "All Complex Statements"}

Print Complexes Marked to Exclude:| (40vexclude);
{condition_end}
{condition_begin=v_stmt_type <> "Lien Statement" }
Print Statements Only:| (40v_stmt_print);
List Paid Amount:| (40v_stmt_paid);
{condition_begin=v_stmt_paid}
Beginning Date Paid:| [%DATE;P=popup.calendar(dtoc(vbeg));I=popup.calendar%.20vbeg];
Ending Date Paid:| [%DATE;P=popup.calendar(dtoc(vend));I=popup.calendar%.20vend];

{condition_end}
Days Due \(0 for all):| [%z%.3v_stmt_days];
{condition_begin=v_stmt_print = .f.}
Return Email Address:| [.50v_stmt_rtn];
Blind Carbon Copy Email Address:| [.50v_stmt_bcc];
Email/Fax Message:| [%mw%.40,5v_stmt_msg];
{condition_end}
{condition_end}
{condition_begin=(v_stmt_type="Complex Statement - Select" .and. v_stmt_days = 0 ).or. v_stmt_type = "Lien Statement" }
Select Complex\(s):| [%M;d;O={@@}%.50,15v_stmt_cmplx^#a_v_stmt_cmplx];
{condition_end}
{endregion};
{region}
{text=65,1:footer_string};
{endregion};
{line=1,0};
{region}
{endregion};
{lf};
<15=ok_button_label!OK> <15=cancel_button_label!CANCEL>

%dlg%, <<%code%
if a_dlg_button = "OK" then
' exit
end if

if a_dlg_button = "OK" then
a_dlg_button = ""
ui_msg_box("OK Button Pushed","OK Button Pushed")
ui_modeless_dlg_close(dlg_title)
end if

if a_dlg_button = "enter" then
if atc("!ok",ui_dlg_ctl_current(dlg_title)) > 0 then
'user is on the OK button, so close the dialog
else
'user is not on the OK button, so advance to next control
ui_dlg_navigate(dlg_title,"Next")
'set a_dlg_button to null to keep the dialog open
a_dlg_button = ""
end if
end if

if a_dlg_button = "v_stmt_type_changed_*" then
if v_stmt_type= "All Complex Statements" then
trace.WriteLn("v_stmt_type= " + v_stmt_type)
v_stmt_days = 45
end if
if v_stmt_type = "Complex Statement - Select" then
trace.WriteLn("v_stmt_type= " + v_stmt_type)
v_stmt_days = 10
end if
if v_stmt_type = "Management Company Statement" then
trace.WriteLn("v_stmt_type= " + v_stmt_type)
v_stmt_days = 20
end if
xbasic_wait_for_idle()
a_dlg_button = ""
end if

if left(a_dlg_button,4) = "vbeg" then
if a_dlg_button = "vbeg_killfocus" then
vbeg = ctod(dtoc(vbeg))
end if
a_dlg_button = ""
end if

if left(a_dlg_button,4) = "vend" then
if a_dlg_button = "vend_killfocus" then
vend = ctod(dtoc(vend))
end if
a_dlg_button = ""
end if

if a_dlg_button = "vend_change" then
a_dlg_button = ""
xbasic_wait_for_idle()
end if

if a_dlg_button = "vbeg_change" then
a_dlg_button = ""
xbasic_wait_for_idle()
end if

if a_dlg_button = "save" then
a_dlg_button = ""
Save(local_variables())
xbasic_wait_for_idle()
end if

if a_dlg_button = "cancel" then
a_dlg_button = ""
ui_msg_box("Cancel Button Pushed","CANCEL Button Pushed")
xbasic_wait_for_idle()
ui_modeless_dlg_close(dlg_title)
end if


%code%)