Add an Exit button to a logon Dialog

[Scott Kurimski]

I know this is probably a very easy answer although I have not worked with dialogs very much at this point and could use some assistance. I would like to add an Exit button directly to the left of the "Log On" button and check for which button was pressed.

    ok_button_label = "Log On"
    vLogonDialog = ui_dlg_box(" Logon",<<%dlg%
    {toolcaption}
    {font=Arial,9}
    {frame=1,1: Enter your Username and Password }
    {region}
    {lf};
    Username:| [.40gvUserName];
    Password:| [%p%.40vUserPassword];
    {lf};
    {endregion};
    {lf};
    {region}
    {justify=right}
    <*15=ok_button_label>
    {endregion};
    %dlg%)

To add the button, I tried the code below although there is "extra" space between the two buttons

    exit_button_label = "Exit"
    ok_button_label = "Log On"
    vLogonDialog = ui_dlg_box(" iTrackAll",<<%dlg%
    {toolcaption}
    {font=Arial,9}
    {frame=1,1: Enter your Username and Password }
    {region}
    {lf};
    Username:| [.40gvUserName];
    Password:| [%p%.40vUserPassword];
    {lf};
    {endregion};
    {lf};
    {region}
    {justify=right}
    <*15=ok_button_label>    
    <*15=ok_button_label>
    {endregion};
    %dlg%)

[G Gabriel]

Re: Add an Exit button to a logon Dialog

1-You have 2 "OK" buttons
2-What do you want the "Exit" Button to do? Exit of course. But, that's what any button will do unless you add a code to your xdlg
3-Are you trying to get rid of the space?

[Scott Kurimski]

Re: Add an Exit button to a logon Dialog

1. Sorry about that, that was not the actual code I tried, I had typed it in and just forgot to chane the second button. It would be something like this....

    exit_button_label = "Exit"
    ok_button_label = "Log On"
    vLogonDialog = ui_dlg_box(" iTrackAll",<<%dlg%
    {toolcaption}
    {font=Arial,9}
    {frame=1,1: Enter your Username and Password }
    {region}
    {lf};
    Username:| [.40gvUserName];
    Password:| [%p%.40vUserPassword];
    {lf};
    {endregion};
    {lf};
    {region}
    {justify=right}
    <*15=exit_button_label>    
    <*15=ok_button_label>
    {endregion};
    %dlg%)

2. I would like the Exit button to Exit the application.
3. I would like the spacing on the buttons to be the normal spacing if one button is placed next to the other, just as a standard dialog would be if you had an "OK" and "Cancel" button.

[Stan Mathews]

Re: Add an Exit button to a logon Dialog

You can control the spacing like

<*15=exit_button_label>{sp=5}<*15=ok_button_label>

You want the exit button to quit Alpha?

[Scott Kurimski]

Re: Add an Exit button to a logon Dialog

Yes, Exit Alpha

[Stan Mathews]

Re: Add an Exit button to a logon Dialog

exit_button_label = "Exit"
ok_button_label = "Log On"
vLogonDialog = ui_dlg_box(" iTrackAll",<<%dlg%
{toolcaption}
{font=Arial,9}
{frame=1,1: Enter your Username and Password }
{region}
{lf};
Username:| [.40gvUserName];
Password:| [%p%.40vUserPassword];
{lf};
{endregion};
{lf};
{region}
{justify=right}
<*15=exit_button_label>{sp=5}<*15=ok_button_label>
{endregion};
%dlg%,<<%code%
if (a_dlg_button = "Exit") then
    a5.close()
end if
if (a_dlg_button = "Log On") then
    'logon routine here
    '... end the dialog
end if
%code%)

[Scott Kurimski]

Re: Add an Exit button to a logon Dialog

Thanks Stan and Gabe, I am running off to a meeting and will try it this afternoon.

[Tom Henkel]

Re: Add an Exit button to a logon Dialog

Scott,

For what its worth, this is my code for our login dialog. It runs in the on_init event of the main menu form. I have an "OK", "Clear" (in case they typed wrong), and an "Exit". There is much more code, but this should get you started. (aa.bcbss is addin variable space I use for many variables I need in the app)

userid = ""
passwd = ""

f = file.open(aa.bcbss.path+"\bcbss\seal.jpg",FILE_RO_SHARED)
UI_BITMAP_LOAD("BCBSS",F.READB(10000000))
f.close()

rslt = ui_dlg_box(aa.bcbss.agency+" - Security",<<%dlg%
{background=#255+253+159}
{frame=1,1}
{region1}
{justify=center}
{image=BCBSS};
{lf};
Welcome to the {text=38aa.bcbss.agency};
{lf};
Before proceeding, You Must Enter {font=arial,8,B}YOUR{font=arial,8,N} User-ID and Password
{lf};
{endregion1};
{lf};
{frame=1,1:Please Sign In:}
{region2}
{justify=left}
{lf};
{sp=10} Enter User-ID: |{initial_focus}[5.8userid!userid_killfocus] ;
{lf};
{sp=10} Enter Password: |[%p%6.8passwd] ;
{lf};
{endregion2};
{lf};
{color=Red on Pale Yellow} 
{frame=1,1:Error Messages:}
{region3}
{color=Black on Pale Yellow} 
{sp=5}{text=60,2errmsg}
{endregion3};
{frame=1,1}
{region4}
{justify=center}
<10&OK ?.not.(userid="").and.errmsg=""> {sp=4} <&Clear> {sp=4} <10&Exit>
{endregion4}
%dlg%, <<%code%
IF a_dlg_button = "&Exit"
	:A5.close()
END IF
IF a_dlg_button = "&Clear"
	a_dlg_button = ""
	if upper(left(errmsg,3))="USE"
		errmsg = ""
		userid = ""
		passwd = ""
		ui_dlg_ctl_goto(aa.bcbss.agency+" - Security","userid")
	end if
	if upper(left(errmsg,3))="PAS"
		errmsg = ""
		passwd = ""
		ui_dlg_ctl_goto(aa.bcbss.agency+" - Security","passwd")
	end if
end if
if a_dlg_button = "userid_killfocus"
	a_dlg_button = ""
  	if ((left(userid,3)="SYS".or.left(userid,3)="ADM".or.left(userid,3)="SSS".or.left(userid,3)="CLE".or.left(userid,3)="CSP".or.left(userid,3)="LEG".or.left(userid,3)="FIN".or.left(userid,3)="REL").and.len(userid)<5).or.len(userid)<4
  		'OK now
  		a_dlg_button = "" 	
   	  else
   		a_dlg_button = ""
		'get the secure2 user_id and password
		TBL_SECURE = table.open("secure2.dbf",FILE_RW_SHARED)
		TBL_SECURE.index_primary_put("User")

		recno=TBL_SECURE.fetch_find(UT(userid))
		if recno < 0
			errmsg = "User_ID Entered is Invalid - Click \"Clear\""
			trys = trys+1
			IF trys <4 THEN
				'OK now
	  		  ELSE
	  		  	a_dlg_button = "&Exit"
				ui_msg_box(aa.bcbss.agency+" - Security Error","Too many tries, Application Closing")
				:A5.Close()
			END IF
		end if
 	 end if
end if
if a_dlg_button = "&OK"
	if ut(passwd) <> tbl_secure.passwd
		a_dlg_button = ""
		if errmsg = ""
			errmsg = "Password Entered is Invalid - Click \"Clear\""
		  ELSE
		  	errmsg = errmsg+crlf()+"Password Entered is Invalid - Click \"Clear\""
		end if
		trys = trys+1
		IF trys <4 THEN
			'OK now
	  	  ELSE
	  	  	a_dlg_button = "&Exit"
			ui_msg_box(aa.bcbss.agency+" - Security Error","Too many tries, Application Closing")
			:A5.Close()
		END IF
	ui_dlg_ctl_goto(aa.bcbss.agency+" - Security",passwd)
	end if
	'tbl_secure.close()
end if
%code%)

'place this after a dialog box to see if the user clicked on the "X"
'rslt is the name of the variable created by the dialog 
'if it is created by the dialog genie, it is called varC_result
if rslt =""
	ui_msg_box(aa.bcbss.agency+" - Security","Action Cancelled at user request")
	:A5.Close()
end if

Hope it helps.

Tom

[Scott Kurimski]

Re: Add an Exit button to a logon Dialog

Thanks guys, Here is what I ended up with....

    exit_button_label = "Exit"
    ok_button_label = "Log On"
    vLogonDialog = ui_dlg_box(" Title",<<%dlg%
    {toolcaption}
    {font=Arial,9}
    {frame=1,1: Enter your Username and Password }
    {region}
    {lf};
    Username:| [.40gvUserName];
    Password:| [%p%.40vUserPassword];
    {lf};
    {endregion};
    {lf};
    {region}
    {justify=right}
    <15=exit_button_label>
    <*15=ok_button_label>
    {endregion};
    %dlg%)

I did not end up needing the spacing tag and removed the "*" on the exit button so the "Log On" buttton had focus.

I would like to have the OnFlyover and OnFlyoverLeave colors match everything else within the app. How do I do that?