Xdialog a_dlg_button

[Ronald Anusiewicz]

I know I've done this once before, but I can't remember how I did this.

I trap an event and then I want to jump to a specific line of code in my xdialog. I've included a example of code to demonstrate what I'm trying to do.

When the user double clicks on a color, I want to go to startover and restart the xdialog.

Again, this example is only to figure out how to get the line goto startover within the <<%code% %code%) not to create an error message.

I'm 99% certain there is a way to do this, I just do not remember how.

Ron

startover:

DIM SHARED vlist as C
DIM SHARED varC_result as C
DELETE a_vlist		
colors = "Red,Green,Blue,Yellow,Orange,Pink,Grey"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C

a_colors.initialize(colors)
a_colors.sort("ab")
ui_dlg_box("Pick a Color",<<%dlg%

Double click on a color.;
[.25,10color_selected^#a_colors!color_*];
{lf};
<15Close>
%dlg%,<<%code%

if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then
    a_dlg_button = ""
    ui_msg_box("Notice","User picked: "+color_selected)
    goto startover
else
    a_dlg_button = ""
end if

%code%)

[Stan Mathews]

Re: Xdialog a_dlg_button

UI_DLG_REFRESH("Pick a Color")

IM SHARED vlist as C
DIM SHARED varC_result as C
DELETE a_vlist		
colors = "Red,Green,Blue,Yellow,Orange,Pink,Grey"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C

a_colors.initialize(colors)
a_colors.sort("ab")
ui_dlg_box("Pick a Color",<<%dlg%

Double click on a color.;
[.25,10color_selected^#a_colors!color_*];
{lf};
<15Close>
%dlg%,<<%code%

if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then
    a_dlg_button = ""
    ui_msg_box("Notice","User picked: "+color_selected)
    UI_DLG_REFRESH("Pick a Color") 
else
    a_dlg_button = ""
end if

%code%)

[Ronald Anusiewicz]

Re: Xdialog a_dlg_button

Thank you Stan. But your code really doesn't do what I was looking for.
Let me try this again.

'when the user double clicks on a color, I want to rerun this script from here if possible
msgbox("hello")

DIM SHARED vlist as C
DIM SHARED varC_result as C
DELETE a_vlist		
colors = "Red,Green,Blue,Yellow,Orange,Pink,Grey"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C

a_colors.initialize(colors)
a_colors.sort("ab")
ui_dlg_box("Pick a Color",<<%dlg%

Double click on a color.;
[.25,10color_selected^#a_colors!color_*];
{lf};
<15Close>
%dlg%,<<%code%

if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then
    a_dlg_button = ""
    ui_msg_box("Notice","User picked: "+color_selected)
    ui_dlg_refresh("pick a color")
else
    a_dlg_button = ""
end if

%code%)

[Peter.Greulich]

Re: Xdialog a_dlg_button

Is this what you want, Ron?

'when the user double clicks on a color, I want to rerun this script from here if possible
startover:

msgbox("hello")

DIM SHARED vlist as C
DIM SHARED varC_result as C
DELETE a_vlist		
colors = "Red,Green,Blue,Yellow,Orange,Pink,Grey"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C

a_colors.initialize(colors)
a_colors.sort("ab")
ui_dlg_box("Pick a Color",<<%dlg%

Double click on a color.;
[.25,10color_selected^#a_colors!color_*];
{lf};
<15Close>
%dlg%,<<%code%

if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then   
    ui_msg_box("Notice","User picked: "+color_selected)
else
    a_dlg_button = ""
end if

%code%)


If color_selected > ""
	delete color_selected
	goto startover
End If

[G Gabriel]

Re: Xdialog a_dlg_button

Have you considered using a modeless xdlg instead?

[Finian Lennon]

Re: Xdialog a_dlg_button

Ron:

Move your startup label to just before where the %code% ends. As in:

DIM SHARED vlist as C
DIM SHARED varC_result as C
DELETE a_vlist		
colors = "Red,Green,Blue,Yellow,Orange,Pink,Grey"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C

a_colors.initialize(colors)
a_colors.sort("ab")
ui_dlg_box("Pick a Color",<<%dlg%

Double click on a color.;
[.25,10color_selected^#a_colors!color_*];
{lf};
<15Close>
%dlg%,<<%code%

if a_dlg_button = "Close" then
    'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then
    a_dlg_button = ""
    ui_msg_box("Notice","User picked: "+color_selected)
    goto startover
else
    a_dlg_button = ""
end if
startover:
%code%)

That does it.

[johnkoh]

Re: Xdialog a_dlg_button

Ron,

This ?

if a_dlg_button = "Close" then
'do nothing - the dialog will close
else if a_dlg_button = "color_dblclick" then
a_dlg_button = ""
ui_msg_box("Notice","User picked: "+color_selected)
'goto startover
color_selected=""
else
a_dlg_button = ""
end if
'startover:

[Ronald Anusiewicz]

Re: Xdialog a_dlg_button

Thank you for your responses.

I have a very large script. Within the script are numerous ui_dlg_box's. As one navigates through the script, various ui_dlg_box's are opened and closed.

What I'm trying to do is to trap the results of the dblclick event, and then using "goto continue" I will move to the appropriate part of the script to continue with the process. The continue: (or in my first example, startover:) could be located either before the ui_dlg_box or after the ui_dlg_box.

There seems to be a restriction with what alpha sees with code that is written between the <<%code% %code%) delimiters.

I thought I found a way around this, but I cannot remember what I did and of course, I never documented this for my future reference. I do remember that I found the answer by accident while doing something totally unrelated. I seem to recall that it was a function or something in {}, but I'm probably wrong.


Peter,

I just looked at your code again and while it's not what I was looking for, it seems to do what I want.

Thanks

[Finian Lennon]

Re: Xdialog a_dlg_button

Maybe this is something like what you were thinking of. The only way that I can keep multiple xdialogs straight in a large script, is to embed each xdialog in a function. Then it's easy to trap return values. I usually define those functions as C" or "L" for that purpose. Also, once the xdialogs are inside functions, it's easy to use labels.

In this example, the user gets to select from 3 xdialogs (basically the same as the original one you submitted) but if they choose a green color at any time they are sent back to the beginning.

dim lv as p = local_variables()
dim selected_colors as c = ""
dim color_selected as c = ""
start_over:
'if you pick green, you have to start over

dim col1 as c = Color1(lv)

	if alltrim(col1) <> "" then
		selected_colors = selected_colors + col1 + Crlf()
		if "green" $ col1 then
			selected_colors = ""
			ui_msg_box("","No green selections permitted. Please start over.")
			goto start_over
		end if
			ui_msg_box("Selected Colors",selected_colors)
		else
			END
	end if
	'add logic to branch here

dim col2 as c = Color2(lv)
	if alltrim(col2) <> "" then
		selected_colors = selected_colors + col2 + Crlf()
		if "green" $ col2 then
			selected_colors = ""
			ui_msg_box("","No green selections permitted. Please start over.")
			goto start_over
		end if
			ui_msg_box("Selected Colors",selected_colors)
		else
			END
	end if
	'add logic to branch here

dim col3 as c = Color3(lv)
	if alltrim(col3) <> "" then
		if "green" $ col3 then
			selected_colors = ""
			ui_msg_box("","No green selections permitted. Please start over.")
			goto start_over
		end if
		selected_colors = selected_colors + col3 + Crlf()
			ui_msg_box("Selected Colors",selected_colors)
		else
			END
	end if
	'add logic to branch here
END
'======================================
Function Color1 as C(lv as p)
with lv
DIM varC_result as C
dim colors as c = "Red1,Green1,Blue1,Yellow1,Orange1,Pink1,Grey1"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C
a_colors.initialize(colors)
a_colors.sort("ab")
close_button_label = "&Close"
dlg_code = <<%dlg%
{region}
Double click on a color:;
[.25,10color_selected^#a_colors!colors_*];
{endregion};
{line=1,0};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%

event_code = <<%code%
if left(a_dlg_button,6) = "colors" then
	if a_dlg_button = "Colors_dblclick" then
		ui_msg_box("Notice","User picked: "+color_selected)
		color1 = color_selected
		else
			a_dlg_button = ""
			color1 = ""
	end if
end if
if a_dlg_button = "Close" then
	'end
	color1 = ""
end if	
%code%
varC_result = ui_dlg_box("Select Color1",dlg_code,event_code)

end with
End Function
'==============================
Function Color2 as C(lv as p)
with lv
DIM varC_result as C
dim colors as c = "Red2,Green2,Blue2,Yellow2,Orange2,Pink2,Grey2"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C
a_colors.initialize(colors)
a_colors.sort("ab")
close_button_label = "&Close"
dlg_code = <<%dlg%
{region}
Double click on a color:;
[.25,10color_selected^#a_colors!colors_*];
{endregion};
{line=1,0};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%

event_code = <<%code%
if left(a_dlg_button,6) = "colors" then
	if a_dlg_button = "Colors_dblclick" then
		ui_msg_box("Notice","User picked: "+color_selected)
		color2 = color_selected
		else
			a_dlg_button = ""
			color2 = ""
	end if
end if
if a_dlg_button = "Close" then
	'end
	color2 = ""
end if	
%code%
varC_result = ui_dlg_box("Select Color2",dlg_code,event_code)

end with
End Function
'==============================
Function Color3 as C(lv as p)
with lv
DIM varC_result as C
dim colors as c = "Red3,Green3,Blue3,Yellow3,Orange3,Pink3,Grey3"
colors = stritran(colors,",",crlf())
dim a_colors[10] as C
a_colors.initialize(colors)
a_colors.sort("ab")
close_button_label = "&Close"
dlg_code = <<%dlg%
{region}
Double click on a color:;
[.25,10color_selected^#a_colors!colors_*];
{endregion};
{line=1,0};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%

event_code = <<%code%
if left(a_dlg_button,6) = "colors" then
	if a_dlg_button = "Colors_dblclick" then
		ui_msg_box("Notice","User picked: "+color_selected)
		color3 = color_selected
		else
			a_dlg_button = ""
			color3 = ""
	end if
end if
if a_dlg_button = "Close" then
	'end
	color3 = ""
end if	
%code%
varC_result = ui_dlg_box("Select Color",dlg_code,event_code)

end with
End Function

I use the local_variables() and with .. end with to avoid having to declare any variable as other than as local.

[Ronald Anusiewicz]

Re: Xdialog a_dlg_button

Thank you Finian,

It's looks like you put a lot of effort into your reply. I'm sorry but it's still not what I'm looking for so let me try just one more time.

I have an xdialog with a list. I have an event on the list where I want to trap the dblclick.
When I trap the dblclick, I want to use the goto command to exit the xdialog and move to a particular location in the script.

The "goto startover" line will fail with an error message "Can't locate that symbol".

startover:
msgbox("Hello")

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vChoice as C
DIM SHARED varC_result as C
DELETE a_vChoice		
DIM a_vChoice[4] as c
dim temp_list as c 
temp_list = <<%list%
Apple
Grape
Orange
Peach
%list%

a_vChoice.initialize(temp_list)
close_button_label = "Close"
varC_result = ui_dlg_box("Pick a Fruit",<<%dlg%
{region}
[.40,5vChoice^#a_vChoice!vchoice_*];
{endregion};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%,<<%code%

if a_dlg_button = "close" then
	'
else if	a_dlg_button = "vChoice_dblClick" then
	'a_dlg_button = ""
	msgbox(vChoice)
	goto startover	'this line will generate an error message, "Can't locate that symbol".
	'I'm so certain that I discovered a very simple work around so I could use the "goto"
	'statement and exit the xdialog from here
else
	a_dlg_button = ""
end if

%code%)

end

I'm so certain that I found a very simple way to do this in the help files some place, but I can't remember where.

[Finian Lennon]

Re: Xdialog a_dlg_button

I can't even save the script you posted above because the compiler reports "unable to locate that symbol" which should tell us something.

Sometimes I use a goto inside (at the end of) the xdialog code section just to be sure that it ends when/where I want it to. An unnecessary crutch, you might say. Otherwise I have only ever been able to combine multiple goto's and multiple xdialogs in the same script the way that I showed in the example.

[Tim Kiebert]

Re: Xdialog a_dlg_button

The 'result' of the xDialog that gets assigned to varC_result is the last value that was contained in a_dlg_button.
a_dlg_button needs to have a value in order to close the dialog (since this is a modal dialog.) Or if you use ui_modeless_dlg_close("Pick a Fruit")
So just assign some value to a_dlg_button that you can check for after the dialog closes and and run your goto if varC_result contains that value
In this case you could just leave the value of a_dlg_button as "vChoice_dblClick" and check for that.

startover:
msgbox("Hello")

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vChoice as C
DIM SHARED varC_result as C
DELETE a_vChoice		
DIM a_vChoice[4] as c
dim temp_list as c 
temp_list = <<%list%
Apple
Grape
Orange
Peach
%list%

a_vChoice.initialize(temp_list)
close_button_label = "Close"
varC_result = ui_dlg_box("Pick a Fruit",<<%dlg%
{region}
[.40,5vChoice^#a_vChoice!vchoice_*];
{endregion};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%,<<%code%

if a_dlg_button = "close" then
	'
else if a_dlg_button = "vChoice_dblClick" then
	msgbox(vChoice)
else
	a_dlg_button = ""
end if

%code%)

[COLOR="#FF0000"]if varC_result = "vChoice_dblClick" then
	goto startover
end if

msgbox("went past goto startover instruction",varC_result)[/COLOR]

end

I think the error message is a result of the dialog code running in a separate session to the main script code and therefore cannot find the startover: tag referred to in the goto instruction.

[Ronald Anusiewicz]

Re: Xdialog a_dlg_button

Tim,

The results of your script give me the results I'm looking for. I was thinking I did it a different way, but your scripting works fine.

Thank you,

Ron

[G Gabriel]

Re: Xdialog a_dlg_button

I was thinking I did it a different way,

Sure. There is more than one way. Here is another:

startover:
msgbox("Hello")

'Create an XDialog dialog box to prompt for parameters.
DIM SHARED vChoice as C=""
DIM SHARED varC_result as C
DELETE a_vChoice		
DIM a_vChoice[4] as c
dim temp_list as c 
temp_list = <<%list%
Apple
Grape
Orange
Peach
%list%

a_vChoice.initialize(temp_list)
close_button_label = "Close"
ui_dlg_box("Pick a Fruit",<<%dlg%
{region}
[.40,5vChoice^#a_vChoice!vchoice_*];
{endregion};
{region}
<*15=close_button_label!Close>
{endregion};
%dlg%,<<%code%

if a_dlg_button = "close" then
	'
else if a_dlg_button = "vChoice_dblClick" then
	msgbox(vChoice)
else
	a_dlg_button = ""
end if

%code%)

if vChoice <>"" then
	goto startover
end if

end

That said, here are few comments:
1-The error you were getting means alpha cannot locate the label. And it couldn't because it was outside the xdlg code.
2-You placed the label at the very top of the script. I do not know if you did that in purpose or just by way of example. Being way at the top meant to me you want to either keep the xdlg open or re-open it after the redirection, hence I suggested a modeless as opposed to a modal xdlg.
3-This is really not the best way to do what you want. And by this, I mean using goto. If I am understanding your objectives correctly, let me know and I will post a better solution.

[Ronald Anusiewicz]

Re: Xdialog a_dlg_button

1-The error you were getting means alpha cannot locate the label. And it couldn't because it was outside the xdlg code.

That was pretty much the conclusion that I was coming to.

2-You placed the label at the very top of the script. I do not know if you did that in purpose or just by way of example. Being way at the top meant to me you want to either keep the xdlg open or re-open it after the redirection, hence I suggested a modeless as opposed to a modal xdlg.

Your correct, I just did this as an example. However; in the past I have wanted to go to both the top or somewhere else in the script.

3-This is really not the best way to do what you want. And by this, I mean using goto. If I am understanding your objectives correctly, let me know and I will post a better solution.

In this case I developed tunnel vision just trying to make something work. I sincerely believe that I did this in the past. Anyways, I have since moved on using different methods some of which the generous contributors here have given me.

Thank you.