Xdialog: double click selection in list and add to another list

[MoGrace]

We really need a forum just for Xdialog...

I have a rollup progressive search list box where the user can type in a fileno or a first or last name to filter the list then make his selection and open a form and go to that record - works swell.

But now I have a need to create another listbox whereby a doubleclick event can be trapped from the first and add that selection to the 2nd list so when used in rollup mode, the user can go back to a previous selection without having to do the search again. This is the old version without the rollup feature cause I didn't want to upload another pic - the new version added a rollup button.

Basically a smaller listbox would appear below the main list with room for maybe 5 selections. Then hopefully doubleclicking in that list will do the same as the first list does with buttons.

My question is: how to get the 2nd list populated?

[Mike Wilson]

Re: Xdialog: double click selection in list and add to another list

Robin,
This I believe would be relative to the code and method you are using to produce the first progressive look up. Saying you have a "rollup progressive search list box" doesn't completely define that, at least for me. It appears to me you are using a List View Control or maybe a keylist_build method for that. Since those two methods are beyond my coding skills, I don't use them, I roll my own using table.external_record_content_get, filter_string_smatch(), and xdialog events and have been able to make pretty much any ultra specialty dialog needed, like the one you are describing. But maybe if you share what method you have going, then maybe that's a start to your endpoint.

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

Mike,
I am using the genie created keylist build. I got my test XD to work, but am having a few problems integrating the new feature into the original script. Will post back when it starts working again...that is if I don't mess them both up in the meantime.

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

One small problem, it seems a click in the list box also triggers the dblclick event- should that be the case? I am only using specified events, ie. No event_*. Can a click be trapped so it does nothing?

[Allen Klimeck]

Re: Xdialog: double click selection in list and add to another list

Robin when you add events all of the events will fire. So if you name your event "pick_dblclick" it will assign that event name to a_dlg_button whatever event fires. So you must use "pick_*" and trap for it. Here are two scrips "Event_viewer" and "Select_city" taken from Xdialog lessons and modified. Select_city has double click added to the list.


Event Viewer

dim events[100] as C 
colors = "Red,Green,Blue,Yellow,Orange,Pink" 
colors = stritran(colors,",",crlf()) 
item_selected = "Shirt" 
dim a_colors[10] as C 
a_colors.initialize(colors) 
a_colors.sort("ab") 
ui_dlg_box("Pick a Color",<<%dlg% 
Item: [.18item_selected^={Shirt,Tie,Pants,Jacket}!item_*]; 
Double click on a color. |Event Name; 
[.25,10color_selected^#a_colors!color_*] |[.25,20^#events]; 
{text=50,1:txt}; 
{lf}; 
<15Close!close> |<15Clear Events!clear> 
%dlg%,<<%code% 
events[events.first_empty()] = a_dlg_button 
'trace.writeln(a_dlg_button) 
if a_dlg_button = "Clear" 
               events.clear() 
               a_dlg_button = "" 
else if a_dlg_button = "Close" then 
               'do nothing - the dialog will close 
else 
               a_dlg_button = "" 
end if 
%code%)

Select City

list1 = "Boston,New York,Chicago,London,Cape Town,Sydney,Toronto,Los Angeles,Tokyo,Johannesburg,Bulawayo,"
list1 = list1 + "Washington,Denver,Atlanta,Paris,Rome"
list1 = stritran(list1,",",crlf())
dim a_list1[100] as C
a_list1.initialize(list1)
a_list1.sort("ab")
dim a_list2[100] as C
dim list1_selected as N
dim list2_selected as N
list1_selected = 1
list2_selected = 1
flag_add = .t.
flag_remove = .f.
ui_dlg_box("List Picker",<<%dlg%
{region0}
Select the cities you would like to visit on your Grand World Tour.;
Choose the cities in the order in which you would like to visit them.;
{region1}
{lf};
{region2}
Available Cities;
[.25,15list1_selected^#a_list1!city_*];
{endregion2}|
{region20}{sp};{endregion20}|
{region3}
{lf};
{lf};
{lf};
<15Add?flag_add>;
<15Add all?flag_add>  ;
<15Remove?flag_remove>;
<15Remove all?flag_remove>
{endregion3}|
{region20}{sp};{endregion20}|
{region4}
Selected Cities;
[.25,15list2_selected^#a_list2] ;
{text=20text1};
{text=20text_prev};
<10Up?flag_remove> <10Down?flag_remove>
{endregion4}
{endregion1}
{endregion0}
|
{region5}
 <15&OK>;
 <15&Cancel>
{endregion5}
%dlg%,<<%code%
if left(a_dlg_button,5) = "city_" 'check for double click!!!
	vcbutton = a_dlg_button ' save a_dlg_button
	a_dlg_button = "" 'clear a_dlg_button hold box open
	if vcbutton = "city_dblclick"
			if list1_selected > 0 then
			first_empty_on_list2 = a_list2.first_empty()
			a_list2[first_empty_on_list2] = a_list1[list1_selected]
			a_list1.delete(list1_selected,1)
			list2_selected = first_empty_on_list2
			'after adding an entry, move the focus up to previous city,
			'unless you were already on the first city.
			if a_list1[list1_selected] = "" .and. list1_selected > 1 then
				list1_selected = list1_selected-1
			else
				list1_selected = list1_selected
			end if
			'turn on the Remove flags
			flag_remove = .t.
			'if there are no more entries in list1, turn off Add flags
			if a_list1[list1_selected] = "" then
				flag_add = .f.
			end if
		end if
	end if
end if
if a_dlg_button = "Add" then
    a_dlg_button = ""
    if list1_selected > 0 then
        first_empty_on_list2 = a_list2.first_empty()
        a_list2[first_empty_on_list2] = a_list1[list1_selected]
        a_list1.delete(list1_selected,1)
        list2_selected = first_empty_on_list2
        'after adding an entry, move the focus up to previous city,
        'unless you were already on the first city.
        if a_list1[list1_selected] = "" .and. list1_selected > 1 then
            list1_selected = list1_selected-1
        else
            list1_selected = list1_selected
        end if
        'turn on the Remove flags
        flag_remove = .t.
        'if there are no more entries in list1, turn off Add flags
        if a_list1[list1_selected] = "" then
            flag_add = .f.
        end if
    end if
end if
if a_dlg_button = "Remove" then
    a_dlg_button = ""
    if list2_selected > 0 then
        first_empty_on_list1 = a_list1.first_empty()
        value_to_remove = a_list2[list2_selected]
        a_list1[first_empty_on_list1] = a_list2[list2_selected]
        a_list2.delete(list2_selected,1)
        a_list1.sort("ab")
        list1_selected = a_list1.find(value_to_remove)
        if list2_selected > 1 then
            list2_selected = list2_selected-1
        else
            list2_selected = 1
        end if
        if a_list2[list2_selected] = "" then
            flag_remove = .f.
        end if
        flag_add = .t.
    end if
end if
if a_dlg_button = "Up" then
    a_dlg_button = ""
    if list2_selected <> 1 then
        a_list2.move(list2_selected,list2_selected-1)
        list2_selected = list2_selected - 1
    end if
End if
if a_dlg_button = "Down" then
    a_dlg_button = ""
    if list2_selected < a_list2.first_empty()-1 then
        a_list2.move(list2_selected,list2_selected+1)
        list2_selected = list2_selected + 1
    end if
end if
If a_dlg_button = "Add all" then
    a_dlg_button = ""
    tempstring = a_list2.dump("r")+a_list1.dump("r")
    a_list2.clear()
    a_list2.initialize(tempstring)
    a_list1.clear()
    list2_selected = 1
    flag_remove = .t.
    flag_add = .f.
end if
If a_dlg_button = "Remove all" then
    a_dlg_button = ""
    tempstring = a_list1.dump("r")+a_list2.dump("r")
    a_list2.clear()
    a_list1.initialize(tempstring)
    list1_selected = 1
    a_list1.sort("ab")
    flag_remove = .f.
    flag_add = .t.
end if
%code%)

[johnkoh]

Re: Xdialog: double click selection in list and add to another list

Robin,

I am using the genie created keylist build.

Did you know the "Keylist Build" will not accept typical Events (dblclick, killfocus, change... ) .
If you are trying

If  left(a_dlg_button,5) = "List_" then
      
     if a_dlg_button = "list_dblclick"            'It will not work with KeyList Build. 
             'event here.... 
             'open 2nd xdialog

     end if
end if

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

Thanks Allen,

I have seen this example but did not understand it:

if left(a_dlg_button,5) = "city_" 'check for double click!!!
	vcbutton = a_dlg_button ' save a_dlg_button
	a_dlg_button = "" 'clear a_dlg_button hold box open
	if vcbutton = "city_dblclick"
....

Now I think I understand why I am getting more results that I wanted because of other untrapped events in the script - I will try this and see if it helps me.

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

John, (and Mike)
I did not know that about keylist build - problem is the genie creates that code and puts in the code to refresh the list. If I use table.external_record_content_get() I've also increased my problems cause now I have to figure out how to do that too!

But I will try not to be too big a baby about it...

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

I got it!

Let me know what you think

[Allen Klimeck]

Re: Xdialog: double click selection in list and add to another list

Very nice well done!!!

[Tim Kiebert]

Re: Xdialog: double click selection in list and add to another list

Nice Job. I like it.

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

Thanks guys,
Notice the keylist build was not the problem, once I was only trapping the event I needed like Allen showed. The type in box however did not work with that method - only the list boxes.

I like using XD, if only there was more info. Hopefully this will be an example that helps do that. Like I said at the start - it would be great to have a forum section that was only about xdialog.

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

Just thought I'd show what the final version for my live data looks like. In the rolled up xd, I shortened the displayed title using {title=Search EE} since it fits the smaller xd box better. Besides adding the header area, I also put {position=remember=test_dialog) in both so if either the expanded or contracted xd is moved the location is remembered. I tried to use {dockable=float} so I could open as floating but optionally dock the toolbar on the right, but couldn't get it to work right.

If I get really ambitious, perhaps I could make one of these search bars that is dockable and reads the table of the currently open form...

[Tim Kiebert]

Re: Xdialog: double click selection in list and add to another list

...... If I get really ambitious, perhaps I could make one of these search bars that is dockable and reads the table of the currently open form...

Funny you should say that 'cause I experimented with your previous sample and did just that. Its not hard. take you five minutes. :-)

[MoGrace]

Re: Xdialog: double click selection in list and add to another list

Tim, could you give me a clue...please

Edit: btw, I found the XD example using table.external_record_content_get() in the 'plain' Listbox genie - haven't tried it yet tho.