waitdialog cancel

[Bill Parker]

I am hoping to get a Cancel button working on my PleaseWait() dialog. Some time ago Selwyn suggested that quickdraw should solve this in v7. In testing with the following script I don't get consistent results, and I hope to move whatever technique works into my own dialog.

First time after a reboot, run script, and press cancel button, the 'are you sure' msg box displays at the same time as the waitdialog - good. Subsequently they do not display at the same time, it may take multiple presses of the waitdialog Cancel button to display the 'are you sure', and the whole thing might require a ctl-alt-delete.

is quickdraw my solution? don't find any info on that in webhelp.

Bill.

colors = a5.Color_Enum()
colors = replicate(colors,5)
'dim x as waitdialogQD ' error 1 in v7
'dim x as {waitdialogQD} ' error on x.create()
dim x as {waitdialog}
x.Create(3,"percent")
x.AllowCancel(.t.)
dim i as n 
dim count as n 
i = 0 
count = line_count(colors)
for each c in colors

    i = i + 1 
    x.set_percent(i,count)
    x.set_bottom_message(c.value)
    y = x.user_canceled()
    'if x.usercanceled then
    if y
        q = ui_msg_box("Notice","Are you sure?",UI_YES_NO_CANCEL) 
        if q = ui_yes_selected then 
            goto next2 
        else
            x.Cancel_Cancel()
        end if 
    end if 
next 
next2:
x.close()

[CALocklin]

Bill,

I'm not sure if you are talking about the new 'waitdialog' function or the PleaseWait function from the Code Archive. I also don't know if this will meet your requirements but here's what I've been doing since shortly after the original PleaseWait was posted. There is no 'close' button but clicking the red X to close it presents a dialog to help the user decide whether or not it should really be closed. (There have been a few changes along the way and I don't remember the original reason for the two regions that are now the same.) Without this capability, I would not be using this function.

FUNCTION PleaseWait_fnc as C ( Show=.F. as L, info_msg="" as C )
 'Description:Shows "Please Wait" Xdialog with optional sub-message.  Run function with Show=.T. to show the message. Use no arguments (or .F.) to turn off the message.
 DIM box_code as C
 DIM box_event as C
 DIM close_result as C
 DIM mlen as N
 DIM PleaseWait as C
 DIM wait_txt as C
 DIM show as L
 DIM info_msg as C
 PleaseWait = "" 'Just so it can return something.
 IF show = .F.
  IF ui_modeless_dlg_exist( "Processing" )
   ui_modeless_dlg_close( "Processing" )
  END IF
  EXIT FUNCTION
 END IF
 info_msg = alltrim( info_msg )
 mlen = len( info_msg )
 'Skip the first line if the message is shorter than 28 characters.
 IF mlen < 28
  'If less than 28, we will use a fixed font to center the text.
  info_msg = crlf() + space( ( 28 - mlen ) / 2 ) + info_msg
 ELSEIF mlen < 4500
  info_msg = crlf() + info_msg
 END IF
 wait_txt = "Please Wait"
 dlg_text = <<%dlg%
{can_exit=closeit}
{background=Dirty White}
{font=Arial,16,bi}
{sp=9}{text=35,2:wait_txt};
{line=1,0};
{condition=(mlen<28)}
{region}
{font=Courier,10,n}{text=45,4:Info_msg};
{endregion}
{condition=(mlen>=28)}
{start_pos}
{region}
{font=Courier,10,n}{text=45,4:Info_msg};
{endregion};
%dlg%
 box_event = <<%code%
IF a_dlg_button = "Closeit"
 close_result = Close_warning()
 IF close_result = "Yes"
  ui_modeless_dlg_close( "Processing" )
 END IF
END IF
%code%
 ui_modeless_dlg_box( "Processing", dlg_text, box_event )
 ui_modeless_dlg_setfocus( "Processing" )
 ui_modeless_dlg_refresh( "Processing" )
END FUNCTION
'@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
'@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
FUNCTION Close_warning as C()
 DIM Close_warning as C
 DIM msg as C
 DIM msg1 as C
 DIM msg2 as C
 DIM msg3 as C
 DIM hdr1 as C
 DIM hdr2 as C
 msg = "You have attempted to close the 'Please Wait' message manually. This should not be done unless "
 msg = msg + "the program has stopped running"
 hdr1 = msg
 msg = "PLEASE VERIFY THAT THE PROGRAM HAS STOPPED BY CHECKING THE FOLLOWING"
 hdr2 = msg
 msg = "The status bar at the lower left corner of the database window has stopped changing"
 msg1 = msg
 msg = "The hard drive light has gone off and/or any writes to the hard drive should have "
 msg = msg + "been finished long ago"
 msg2 = msg
 msg = "ARE YOU SURE YOU WANT TO CLOSE THIS 'Please Wait' MESSAGE"
 msg3 = msg
 DIM dlg_result as C
 dlg_text = <<%dlg%
{ysize=.3}{units=F}{font=Time New Roman,9,n}{sp};
{text=105,2:hdr1};{sp};
{font=Time New Roman,9,b}{text=90,1:hdr2}{font=Time New Roman,9,n};{sp};
{region}
  - |{text=100,1:msg1};
  - |{text=100,1:msg2};
{endregion};{sp};
{justify=center}{font=Time New Roman,9,b}{text=69,2:msg3}{font=Time New Roman,9,n};
{justify=center}<*15Yes> <15No>
%dlg%

 DIM dlg_result as C
 dlg_result = ui_dlg_box( "*** WARNING ***", dlg_text, <<%code%
%code% )
 Close_warning = dlg_result
END FUNCTION 'Close-warning

Bummer - I see the message board is changing double quotes to the HTML tag for a quote. I tried to edit them but if it doesn't work, I guess you'll have to change them back yourself.

Cal Locklin
www.aimsdc.net

[Bill Parker]

Cal,

The first code I posted was a bit misleading since I am just trying to get something to work. I also allow closing my please_wait by clicking the X. My problem is being able to stop another running process. This started when I wanted to be able to interrupt my bulk email script after only part of the emails had been sent. I wanted to set a global variable, p_pleasewait_cancel, that a running script could check to see if it should terminate.

Below is my pleasewait function. p_pleasewait_cancel does not get set until the calling script finishes. Selwyn explained why to me once, but I forget the details.

Bill.

FUNCTION p_PleaseWait AS V (Show=.t., Msg="", Justify="center", AllowCancel=.f., MinWidth=50)
'DESCRIPTION:Show (def.=.t.) .f. to close, Msg (def.="") crlf() string to display, AllowCancel (def.=.f.) sets p_PleaseWait_cancel (global var.), MinWidth (def.=50).
'	font size used on StatusBar is 10, so that is used here.  dlg default is 8.
'	Parameter options:
'	  Justify - left, center. would use left if rapidly showing consecutive values.
'	  AllowCancel - does not work.  Selwyn talked about new approach.
'	03-04-05 add AllowCancel, Justify, MinWidth parameters.

IF AllowCancel
	DIM Global p_PleaseWait_cancel as L
	if .not.eval_valid("p_PleaseWait_cancel_set")
		p_PleaseWait_cancel = .f.
	end if
	DIM Global p_PleaseWait_cancel_set as L	' so p_PleaseWait_cancel is only set on first call.
	p_PleaseWait_cancel_set = .t.
END IF

'	***** Close the dlg box ******************************************************************
if show = .F.
	if ui_modeless_dlg_exist("Processing")
		ui_modeless_dlg_close("Processing")
	end if 
	delete p_PleaseWait_cancel
	delete p_PleaseWait_cancel_set
	exit function
end if

'	***** Define parts of the box format code ************************************************
vText = stritran(Msg,crlf(), ";" +crlf())

vPleaseWait = "Please Wait"
vLen = len(vPleaseWait)
vPleaseWait = space(MinWidth/2 -vLen/2) +vPleaseWait +space(MinWidth/2 -vLen/2)

vDlg_format = <<%dlg%
{can_exit=Exit}
{font=arial,10,b}
{justify=center}
{text=minwidthvPleaseWait};
{font=arial,10}
{justify=left}
_line_
{justify=_justify_}
Text_Msg;
_cancel_code_
%dlg%

'{line=1};
vCancel_format = <<%dlg%
{condition=(allowcancel=.t.)}
{justify=left}

{region=a}
{justify=center}
<*Cancel!cancel>
{endregion};
%dlg%

vDlg_event = <<%code%
IF a_dlg_button = "exit"	' helpful if dislog is hung open, press X
	ui_modeless_dlg_close("Processing")
	delete p_PleaseWait_cancel
	delete p_PleaseWait_cancel_set
END IF
IF a_dlg_button = "cancel"
	xbasic_wait_for_idle()	' does not seem to help w/ processing of cancel button
	p_PleaseWait_cancel = .t.	' set global variable
'	debug(1) this shows that cancel from p_email_client is not processed until after all emails are sent.
END IF
%code%

'	***** Build the desired box format code ******************************************************
vDlg_format = stritran(vDlg_format, "Text_Msg", vText)
vDlg_format = stritran(vDlg_format, "minwidth", alltrim(str(MinWidth)))

IF Justify = "center"
	vDlg_format = stritran(vDlg_format, "_justify_", "center")
ELSE
	vDlg_format = stritran(vDlg_format, "_justify_", "left")
END IF

IF msg = ""
	vDlg_format = stritran(vDlg_format, "_line_", "")
ELSE
	vDlg_format = stritran(vDlg_format, "_line_", "{line=1};")
END IF

if AllowCancel
	vDlg_format = stritran(vDlg_format, "_cancel_code_", vCancel_format)
else
	vDlg_format = stritran(vDlg_format, "_cancel_code_", "")
end if

'	***** Show the dlg box ***********************************************************************
ui_modeless_dlg_box("Processing",vDlg_format,vDlg_event)
ui_modeless_dlg_setfocus("Processing")
ui_modeless_dlg_refresh("Processing")

END FUNCTION

[Selwyn Rabins]

this is fixed in the next beta. it will always respond on the first click now.

the waitdialogQD class in V6 (which was for internal use only, and was never documented), no longer exists in V7.

the waitdialog class in V7 has been rewritten and now internally uses the same logic that the waitdialogQD class in v6 uses.

[Bill Parker]

Selwyn, are there techniques that I could use in my own please_wait function so a running script can detect if a modeless dialog button is pushed. I wanted to add formatting control for centering or left justifying text, and a few other things.

Bill.

[Selwyn Rabins]

the technique that you would use would be to use the

ui_modeless_dlg_button() command in the running script. This command will let you test if the user has pressed a button in the 'wait dialog'.\

you might also want to use the ui_yield() function in looping script to give a5 time to 'breathe'.

[Bill Parker]

I had looked at ui_modeless_dlg_button() before, but since the example used it in a {watch} expression and I am calling from xbasic script, I lost the forest for the trees.

ui_yeild() seems to be the key for me. but I did find an issue with mouse clicking the button, and one with ui...button().

--- add ui_yeild() as first line in my please_wait function
calling script sees my global variable with [enter] but not mouse click.
ui...button() in calling script does not trap either [enter] or mouse click

--- add ui_yeild() to loop in calling script.
calling script sees my global variable with [enter] but not mouse click.
ui...button() in calling script traps [enter] to press button, but not mouse click.

there is nothing on ui_yeild() in the web help yet.

Bill.